m4/locale-tr.m4

   1 # locale-tr.m4 serial 6
   2 dnl Copyright (C) 2003, 2005-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Bruno Haible.
   8
   9 dnl Determine the name of a turkish locale with UTF-8 encoding.
  10 AC_DEFUN([gt_LOCALE_TR_UTF8],
  11 [
  12   AC_REQUIRE([AM_LANGINFO_CODESET])
  13   AC_CACHE_CHECK([for a turkish Unicode locale], [gt_cv_locale_tr_utf8], [
  14     AC_LANG_CONFTEST([AC_LANG_SOURCE([
  15 changequote(,)dnl
  16 #include <locale.h>
  17 #include <time.h>
  18 #if HAVE_LANGINFO_CODESET
  19 # include <langinfo.h>
  20 #endif
  21 #include <stdlib.h>
  22 #include <string.h>
  23 struct tm t;
  24 char buf[16];
  25 int main () {
  26   /* On BeOS, locales are not implemented in libc.  Rather, libintl
  27      imitates locale dependent behaviour by looking at the environment
  28      variables, and all locales use the UTF-8 encoding.  But BeOS does not
  29      implement the Turkish upper-/lowercase mappings.  Therefore, let this
  30      program return 1 on BeOS.  */
  31   /* Check whether the given locale name is recognized by the system.  */
  32   if (setlocale (LC_ALL, "") == NULL) return 1;
  33   /* Check whether nl_langinfo(CODESET) is nonempty and not "ASCII" or "646".
  34      On MacOS X 10.3.5 (Darwin 7.5) in the tr_TR locale, nl_langinfo(CODESET)
  35      is empty, and the behaviour of Tcl 8.4 in this locale is not useful.
  36      On OpenBSD 4.0, when an unsupported locale is specified, setlocale()
  37      succeeds but then nl_langinfo(CODESET) is "646". In this situation,
  38      some unit tests fail.  */
  39 #if HAVE_LANGINFO_CODESET
  40   {
  41     const char *cs = nl_langinfo (CODESET);
  42     if (cs[0] == '\0' || strcmp (cs, "ASCII") == 0 || strcmp (cs, "646") == 0)
  43       return 1;
  44   }
  45 #endif
  46 #ifdef __CYGWIN__
  47   /* On Cygwin, avoid locale names without encoding suffix, because the
  48      locale_charset() function relies on the encoding suffix.  Note that
  49      LC_ALL is set on the command line.  */
  50   if (strchr (getenv ("LC_ALL"), '.') == NULL) return 1;
  51 #endif
  52   /* Check whether in the abbreviation of the eighth month, the second
  53      character (should be U+011F: LATIN SMALL LETTER G WITH BREVE) is
  54      two bytes long, with UTF-8 encoding.  */
  55   t.tm_year = 1992 - 1900; t.tm_mon = 8 - 1; t.tm_mday = 19;
  56   if (strftime (buf, sizeof (buf), "%b", &t) < 4
  57       || buf[1] != (char) 0xc4 || buf[2] != (char) 0x9f)
  58     return 1;
  59   /* Check whether the upper-/lowercase mappings are as expected for
  60      Turkish.  */
  61   if (towupper ('i') != 0x0130 || towlower (0x0130) != 'i'
  62       || towupper(0x0131) != 'I' || towlower ('I') != 0x0131)
  63     return 1;
  64   return 0;
  65 }
  66 changequote([,])dnl
  67       ])])
  68     if AC_TRY_EVAL([ac_link]) && test -s conftest$ac_exeext; then
  69       # Setting LC_ALL is not enough. Need to set LC_TIME to empty, because
  70       # otherwise on MacOS X 10.3.5 the LC_TIME=C from the beginning of the
  71       # configure script would override the LC_ALL setting. Likewise for
  72       # LC_CTYPE, which is also set at the beginning of the configure script.
  73       # Test for the usual locale name.
  74       if (LC_ALL=tr_TR LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  75         gt_cv_locale_tr_utf8=tr_TR
  76       else
  77         # Test for the locale name with explicit encoding suffix.
  78         if (LC_ALL=tr_TR.UTF-8 LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  79           gt_cv_locale_tr_utf8=tr_TR.UTF-8
  80         else
  81           # Test for the Solaris 7 locale name.
  82           if (LC_ALL=tr.UTF-8 LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  83             gt_cv_locale_tr_utf8=tr.UTF-8
  84           else
  85             # None found.
  86             gt_cv_locale_tr_utf8=none
  87           fi
  88         fi
  89       fi
  90     else
  91       gt_cv_locale_tr_utf8=none
  92     fi
  93     rm -fr conftest*
  94   ])
  95   LOCALE_TR_UTF8=$gt_cv_locale_tr_utf8
  96   AC_SUBST([LOCALE_TR_UTF8])
  97 ])