m4/locale-tr.m4

   1 # locale-tr.m4 serial 3
   2 dnl Copyright (C) 2003, 2005-2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Bruno Haible.
   8
   9 dnl Determine the name of a turkish locale with UTF-8 encoding.
  10 AC_DEFUN([gt_LOCALE_TR_UTF8],
  11 [
  12   AC_REQUIRE([AM_LANGINFO_CODESET])
  13   AC_CACHE_CHECK([for a turkish Unicode locale], gt_cv_locale_tr_utf8, [
  14     AC_LANG_CONFTEST([AC_LANG_SOURCE([
  15 changequote(,)dnl
  16 #include <locale.h>
  17 #include <time.h>
  18 #if HAVE_LANGINFO_CODESET
  19 # include <langinfo.h>
  20 #endif
  21 #include <stdlib.h>
  22 #include <string.h>
  23 struct tm t;
  24 char buf[16];
  25 int main () {
  26   /* On BeOS, locales are not implemented in libc.  Rather, libintl
  27      imitates locale dependent behaviour by looking at the environment
  28      variables, and all locales use the UTF-8 encoding.  */
  29 #if !defined(__BEOS__)
  30   /* Check whether the given locale name is recognized by the system.  */
  31   if (setlocale (LC_ALL, "") == NULL) return 1;
  32   /* Check whether nl_langinfo(CODESET) is nonempty.
  33      On MacOS X 10.3.5 (Darwin 7.5) in the tr_TR locale, nl_langinfo(CODESET)
  34      is empty, and the behaviour of Tcl 8.4 in this locale is not useful.  */
  35 # if HAVE_LANGINFO_CODESET
  36   if (nl_langinfo (CODESET) [0] == '\0') return 1;
  37 # endif
  38 # ifdef __CYGWIN__
  39   /* On Cygwin, avoid locale names  without encoding suffix, because the
  40      locale_charset() function relies on the encoding suffix.  */
  41   if (strchr (getenv ("LC_ALL"), '.') == NULL) return 1;
  42 # endif
  43   /* Check whether in the abbreviation of the eighth month, the second
  44      character (should be U+011F: LATIN SMALL LETTER G WITH BREVE) is
  45      two bytes long, with UTF-8 encoding.  */
  46   t.tm_year = 1992 - 1900; t.tm_mon = 8 - 1; t.tm_mday = 19;
  47   if (strftime (buf, sizeof (buf), "%b", &t) < 4
  48       || buf[1] != (char) 0xc4 || buf[2] != (char) 0x9f)
  49     return 1;
  50   /* Check whether the upper-/lowercase mappings are as expected for
  51      Turkish.  */
  52   if (towupper ('i') != 0x0130 || towlower (0x0130) != 'i'
  53       || towupper(0x0131) != 'I' || towlower ('I') != 0x0131)
  54     return 1;
  55 #endif
  56   return 0;
  57 }
  58 changequote([,])dnl
  59       ])])
  60     if AC_TRY_EVAL([ac_link]) && test -s conftest$ac_exeext; then
  61       # Setting LC_ALL is not enough. Need to set LC_TIME to empty, because
  62       # otherwise on MacOS X 10.3.5 the LC_TIME=C from the beginning of the
  63       # configure script would override the LC_ALL setting. Likewise for
  64       # LC_CTYPE, which is also set at the beginning of the configure script.
  65       # Test for the usual locale name.
  66       if (LC_ALL=tr_TR LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  67         gt_cv_locale_tr_utf8=tr_TR
  68       else
  69         # Test for the locale name with explicit encoding suffix.
  70         if (LC_ALL=tr_TR.UTF-8 LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  71           gt_cv_locale_tr_utf8=tr_TR.UTF-8
  72         else
  73           # Test for the Solaris 7 locale name.
  74           if (LC_ALL=tr.UTF-8 LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  75             gt_cv_locale_tr_utf8=tr.UTF-8
  76           else
  77             # None found.
  78             gt_cv_locale_tr_utf8=none
  79           fi
  80         fi
  81       fi
  82     else
  83       gt_cv_locale_tr_utf8=none
  84     fi
  85     rm -fr conftest*
  86   ])
  87   LOCALE_TR_UTF8=$gt_cv_locale_tr_utf8
  88   AC_SUBST([LOCALE_TR_UTF8])
  89 ])