m4/locale-zh.m4

   1 # locale-zh.m4 serial 3
   2 dnl Copyright (C) 2003, 2005-2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Bruno Haible.
   8
   9 dnl Determine the name of a chinese locale with GB18030 encoding.
  10 AC_DEFUN([gt_LOCALE_ZH_CN],
  11 [
  12   AC_REQUIRE([AC_CANONICAL_HOST])
  13   AC_REQUIRE([AM_LANGINFO_CODESET])
  14   AC_CACHE_CHECK([for a transitional chinese locale], gt_cv_locale_zh_CN, [
  15     macosx=
  16 changequote(,)dnl
  17     case "$host_os" in
  18       darwin[56]*) ;;
  19       darwin*) macosx=yes;;
  20     esac
  21 changequote([,])dnl
  22     if test -n "$macosx"; then
  23       # On Darwin 7 (MacOS X), the libc supports some locales in non-UTF-8
  24       # encodings, but the kernel does not support them. The documentation
  25       # says:
  26       #   "... all code that calls BSD system routines should ensure
  27       #    that the const *char parameters of these routines are in UTF-8
  28       #    encoding. All BSD system functions expect their string
  29       #    parameters to be in UTF-8 encoding and nothing else."
  30       # See the comments in config.charset. Therefore we bypass the test.
  31       gt_cv_locale_zh_CN=none
  32     else
  33       AC_LANG_CONFTEST([AC_LANG_SOURCE([
  34 changequote(,)dnl
  35 #include <locale.h>
  36 #include <stdlib.h>
  37 #include <time.h>
  38 #if HAVE_LANGINFO_CODESET
  39 # include <langinfo.h>
  40 #endif
  41 #include <stdlib.h>
  42 #include <string.h>
  43 struct tm t;
  44 char buf[16];
  45 int main ()
  46 {
  47   const char *p;
  48   /* Check whether the given locale name is recognized by the system.  */
  49   if (setlocale (LC_ALL, "") == NULL) return 1;
  50   /* Check whether nl_langinfo(CODESET) is nonempty.
  51      On MacOS X 10.3.5 (Darwin 7.5) in the fr_FR locale, nl_langinfo(CODESET)
  52      is empty, and the behaviour of Tcl 8.4 in this locale is not useful.  */
  53 #if HAVE_LANGINFO_CODESET
  54   if (nl_langinfo (CODESET) [0] == '\0') return 1;
  55 #endif
  56 #ifdef __CYGWIN__
  57   /* On Cygwin, avoid locale names without encoding suffix, because the
  58      locale_charset() function relies on the encoding suffix.  Note that
  59      LC_ALL is set on the command line.  */
  60   if (strchr (getenv ("LC_ALL"), '.') == NULL) return 1;
  61 #endif
  62   /* Check whether in a month name, no byte in the range 0x80..0x9F occurs.
  63      This excludes the UTF-8 encoding.  */
  64   t.tm_year = 1975 - 1900; t.tm_mon = 2 - 1; t.tm_mday = 4;
  65   if (strftime (buf, sizeof (buf), "%B", &t) < 2) return 1;
  66   for (p = buf; *p != '\0'; p++)
  67     if ((unsigned char) *p >= 0x80 && (unsigned char) *p < 0xa0)
  68       return 1;
  69   /* Check whether a typical GB18030 multibyte sequence is recognized as a
  70      single wide character.  This excludes the GB2312 and GBK encodings.  */
  71   if (mblen ("\203\062\332\066", 5) != 4)
  72     return 1;
  73   return 0;
  74 }
  75 changequote([,])dnl
  76         ])])
  77       if AC_TRY_EVAL([ac_link]) && test -s conftest$ac_exeext; then
  78         # Setting LC_ALL is not enough. Need to set LC_TIME to empty, because
  79         # otherwise on MacOS X 10.3.5 the LC_TIME=C from the beginning of the
  80         # configure script would override the LC_ALL setting. Likewise for
  81         # LC_CTYPE, which is also set at the beginning of the configure script.
  82         # Test for the locale name without encoding suffix.
  83         if (LC_ALL=zh_CN LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  84           gt_cv_locale_zh_CN=zh_CN
  85         else
  86           # Test for the locale name with explicit encoding suffix.
  87           if (LC_ALL=zh_CN.GB18030 LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  88             gt_cv_locale_zh_CN=zh_CN.GB18030
  89           else
  90             # None found.
  91             gt_cv_locale_zh_CN=none
  92           fi
  93         fi
  94       else
  95         # If there was a link error, due to mblen(), the system is so old that
  96         # it certainly doesn't have a chinese locale.
  97         gt_cv_locale_zh_CN=none
  98       fi
  99       rm -fr conftest*
 100     fi
 101   ])
 102   LOCALE_ZH_CN=$gt_cv_locale_zh_CN
 103   AC_SUBST([LOCALE_ZH_CN])
 104 ])