m4/log10f.m4

   1 # log10f.m4 serial 3
   2 dnl Copyright (C) 2011-2012 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_LOG10F],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   AC_REQUIRE([gl_FUNC_LOG10])
  11
  12   dnl Persuade glibc <math.h> to declare log10f().
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14
  15   dnl Test whether log10f() exists. Assume that log10f(), if it exists, is
  16   dnl defined in the same library as log10().
  17   save_LIBS="$LIBS"
  18   LIBS="$LIBS $LOG10_LIBM"
  19   AC_CHECK_FUNCS([log10f])
  20   LIBS="$save_LIBS"
  21   if test $ac_cv_func_log10f = yes; then
  22     LOG10F_LIBM="$LOG10_LIBM"
  23
  24     save_LIBS="$LIBS"
  25     LIBS="$LIBS $LOG10F_LIBM"
  26     gl_FUNC_LOG10F_WORKS
  27     LIBS="$save_LIBS"
  28     case "$gl_cv_func_log10f_works" in
  29       *yes) ;;
  30       *) REPLACE_LOG10F=1 ;;
  31     esac
  32   else
  33     HAVE_LOG10F=0
  34   fi
  35   if test $HAVE_LOG10F = 0 || test $REPLACE_LOG10F = 1; then
  36     dnl Find libraries needed to link lib/log10f.c.
  37     if test $HAVE_LOG10F = 0; then
  38       LOG10F_LIBM="$LOG10_LIBM"
  39     fi
  40   fi
  41   AC_SUBST([LOG10F_LIBM])
  42 ])
  43
  44 dnl Test whether log10f() works.
  45 dnl On OSF/1 5.1, log10f(-0.0f) is NaN.
  46 AC_DEFUN([gl_FUNC_LOG10F_WORKS],
  47 [
  48   AC_REQUIRE([AC_PROG_CC])
  49   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  50   AC_CACHE_CHECK([whether log10f works], [gl_cv_func_log10f_works],
  51     [
  52       AC_RUN_IFELSE(
  53         [AC_LANG_SOURCE([[
  54 #include <math.h>
  55 volatile float x;
  56 float y;
  57 int main ()
  58 {
  59   x = -0.0f;
  60   y = log10f (x);
  61   if (!(y + y == y))
  62     return 1;
  63   return 0;
  64 }
  65 ]])],
  66         [gl_cv_func_log10f_works=yes],
  67         [gl_cv_func_log10f_works=no],
  68         [case "$host_os" in
  69            osf*) gl_cv_func_log10f_works="guessing no";;
  70            *)    gl_cv_func_log10f_works="guessing yes";;
  71          esac
  72         ])
  73     ])
  74 ])