m4/logf.m4

   1 # logf.m4 serial 4
   2 dnl Copyright (C) 2011-2012 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_LOGF],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_logf_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   AC_REQUIRE([gl_FUNC_LOG])
  12
  13   dnl Persuade glibc <math.h> to declare logf().
  14   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  15
  16   dnl Test whether logf() exists. Assume that logf(), if it exists, is
  17   dnl defined in the same library as log().
  18   save_LIBS="$LIBS"
  19   LIBS="$LIBS $LOG_LIBM"
  20   AC_CHECK_FUNCS([logf])
  21   LIBS="$save_LIBS"
  22   if test $ac_cv_func_logf = yes; then
  23     LOGF_LIBM="$LOG_LIBM"
  24
  25     save_LIBS="$LIBS"
  26     LIBS="$LIBS $LOGF_LIBM"
  27     gl_FUNC_LOGF_WORKS
  28     LIBS="$save_LIBS"
  29     case "$gl_cv_func_logf_works" in
  30       *yes) ;;
  31       *) REPLACE_LOGF=1 ;;
  32     esac
  33
  34     m4_ifdef([gl_FUNC_LOGF_IEEE], [
  35       if test $gl_logf_required = ieee && test $REPLACE_LOGF = 0; then
  36         AC_CACHE_CHECK([whether logf works according to ISO C 99 with IEC 60559],
  37           [gl_cv_func_logf_ieee],
  38           [
  39             save_LIBS="$LIBS"
  40             LIBS="$LIBS $LOGF_LIBM"
  41             AC_RUN_IFELSE(
  42               [AC_LANG_SOURCE([[
  43 #ifndef __NO_MATH_INLINES
  44 # define __NO_MATH_INLINES 1 /* for glibc */
  45 #endif
  46 #include <math.h>
  47 /* Compare two numbers with ==.
  48    This is a separate function because IRIX 6.5 "cc -O" miscompiles an
  49    'x == x' test.  */
  50 static int
  51 numeric_equal (float x, float y)
  52 {
  53   return x == y;
  54 }
  55 static float dummy (float x) { return 0; }
  56 int main (int argc, char *argv[])
  57 {
  58   float (*my_log) (float) = argc ? logf : dummy;
  59   /* Test logf(negative).
  60      This test fails on NetBSD 5.1.  */
  61   float y = my_logf (-1.0f);
  62   if (numeric_equal (y, y))
  63     return 1;
  64   return 0;
  65 }
  66               ]])],
  67               [gl_cv_func_logf_ieee=yes],
  68               [gl_cv_func_logf_ieee=no],
  69               [gl_cv_func_logf_ieee="guessing no"])
  70             LIBS="$save_LIBS"
  71           ])
  72         case "$gl_cv_func_logf_ieee" in
  73           *yes) ;;
  74           *) REPLACE_LOGF=1 ;;
  75         esac
  76       fi
  77     ])
  78   else
  79     HAVE_LOGF=0
  80   fi
  81   if test $HAVE_LOGF = 0 || test $REPLACE_LOGF = 1; then
  82     dnl Find libraries needed to link lib/logf.c.
  83     if test $HAVE_LOGF = 0; then
  84       LOGF_LIBM="$LOG_LIBM"
  85     fi
  86   fi
  87   AC_SUBST([LOGF_LIBM])
  88 ])
  89
  90 dnl Test whether logf() works.
  91 dnl On OSF/1 5.1, logf(-0.0f) is NaN.
  92 AC_DEFUN([gl_FUNC_LOGF_WORKS],
  93 [
  94   AC_REQUIRE([AC_PROG_CC])
  95   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  96   AC_CACHE_CHECK([whether logf works], [gl_cv_func_logf_works],
  97     [
  98       AC_RUN_IFELSE(
  99         [AC_LANG_SOURCE([[
 100 #include <math.h>
 101 volatile float x;
 102 float y;
 103 int main ()
 104 {
 105   x = -0.0f;
 106   y = logf (x);
 107   if (!(y + y == y))
 108     return 1;
 109   return 0;
 110 }
 111 ]])],
 112         [gl_cv_func_logf_works=yes],
 113         [gl_cv_func_logf_works=no],
 114         [case "$host_os" in
 115            osf*) gl_cv_func_logf_works="guessing no";;
 116            *)    gl_cv_func_logf_works="guessing yes";;
 117          esac
 118         ])
 119     ])
 120 ])