m4/ls-mntd-fs.m4

   1 #serial 11
   2
   3 dnl From Jim Meyering.
   4 dnl
   5 dnl This is not pretty.  I've just taken the autoconf code and wrapped
   6 dnl it in an AC_DEFUN.
   7 dnl
   8
   9 # jm_LIST_MOUNTED_FILESYSTEMS([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
  10 AC_DEFUN([jm_LIST_MOUNTED_FILESYSTEMS],
  11   [
  12 AC_CHECK_FUNCS(listmntent getmntinfo)
  13 AC_CHECK_HEADERS(mntent.h)
  14
  15 # Determine how to get the list of mounted filesystems.
  16 ac_list_mounted_fs=
  17
  18 # If the getmntent function is available but not in the standard library,
  19 # make sure LIBS contains -lsun (on Irix4) or -lseq (on PTX).
  20 AC_FUNC_GETMNTENT
  21
  22 # This test must precede the ones for getmntent because Unicos-9 is
  23 # reported to have the getmntent function, but its support is incompatible
  24 # with other getmntent implementations.
  25
  26 # NOTE: Normally, I wouldn't use a check for system type as I've done for
  27 # `CRAY' below since that goes against the whole autoconf philosophy.  But
  28 # I think there is too great a chance that some non-Cray system has a
  29 # function named listmntent to risk the false positive.
  30
  31 if test -z "$ac_list_mounted_fs"; then
  32   # Cray UNICOS 9
  33   AC_MSG_CHECKING([for listmntent of Cray/Unicos-9])
  34   AC_CACHE_VAL(fu_cv_sys_mounted_cray_listmntent,
  35     [fu_cv_sys_mounted_cray_listmntent=no
  36       AC_EGREP_CPP(yes,
  37         [#ifdef _CRAY
  38 yes
  39 #endif
  40         ], [test $ac_cv_func_listmntent = yes \
  41             && fu_cv_sys_mounted_cray_listmntent=yes]
  42       )
  43     ]
  44   )
  45   AC_MSG_RESULT($fu_cv_sys_mounted_cray_listmntent)
  46   if test $fu_cv_sys_mounted_cray_listmntent = yes; then
  47     ac_list_mounted_fs=found
  48     AC_DEFINE(MOUNTED_LISTMNTENT, 1,
  49       [Define if there is a function named listmntent that can be used to
  50    list all mounted filesystems. (UNICOS)])
  51   fi
  52 fi
  53
  54 if test $ac_cv_func_getmntent = yes; then
  55
  56   # This system has the getmntent function.
  57   # Determine whether it's the one-argument variant or the two-argument one.
  58
  59   if test -z "$ac_list_mounted_fs"; then
  60     # 4.3BSD, SunOS, HP-UX, Dynix, Irix
  61     AC_MSG_CHECKING([for one-argument getmntent function])
  62     AC_CACHE_VAL(fu_cv_sys_mounted_getmntent1,
  63                  [AC_TRY_COMPILE([
  64 /* SunOS 4.1.x /usr/include/mntent.h needs this for FILE */
  65 #include <stdio.h>
  66
  67 #include <mntent.h>
  68 #if !defined MOUNTED
  69 # if defined _PATH_MOUNTED      /* GNU libc  */
  70 #  define MOUNTED _PATH_MOUNTED
  71 # endif
  72 # if defined MNT_MNTTAB /* HP-UX.  */
  73 #  define MOUNTED MNT_MNTTAB
  74 # endif
  75 # if defined MNTTABNAME /* Dynix.  */
  76 #  define MOUNTED MNTTABNAME
  77 # endif
  78 #endif
  79 ],
  80                     [ struct mntent *mnt = 0; char *table = MOUNTED; ],
  81                     fu_cv_sys_mounted_getmntent1=yes,
  82                     fu_cv_sys_mounted_getmntent1=no)])
  83     AC_MSG_RESULT($fu_cv_sys_mounted_getmntent1)
  84     if test $fu_cv_sys_mounted_getmntent1 = yes; then
  85       ac_list_mounted_fs=found
  86       AC_DEFINE(MOUNTED_GETMNTENT1, 1,
  87   [Define if there is a function named getmntent for reading the list
  88    of mounted filesystems, and that function takes a single argument.
  89    (4.3BSD, SunOS, HP-UX, Dynix, Irix)])
  90     fi
  91   fi
  92
  93   if test -z "$ac_list_mounted_fs"; then
  94     # SVR4
  95     AC_MSG_CHECKING([for two-argument getmntent function])
  96     AC_CACHE_VAL(fu_cv_sys_mounted_getmntent2,
  97     [AC_EGREP_HEADER(getmntent, sys/mnttab.h,
  98       fu_cv_sys_mounted_getmntent2=yes,
  99       fu_cv_sys_mounted_getmntent2=no)])
 100     AC_MSG_RESULT($fu_cv_sys_mounted_getmntent2)
 101     if test $fu_cv_sys_mounted_getmntent2 = yes; then
 102       ac_list_mounted_fs=found
 103       AC_DEFINE(MOUNTED_GETMNTENT2, 1,
 104   [Define if there is a function named getmntent for reading the list of
 105    mounted filesystems, and that function takes two arguments.  (SVR4)])
 106     fi
 107   fi
 108
 109 fi
 110
 111 if test -z "$ac_list_mounted_fs"; then
 112   # DEC Alpha running OSF/1.
 113   AC_MSG_CHECKING([for getfsstat function])
 114   AC_CACHE_VAL(fu_cv_sys_mounted_getsstat,
 115   [AC_TRY_LINK([
 116 #include <sys/types.h>
 117 #include <sys/mount.h>
 118 #include <sys/fs_types.h>],
 119   [struct statfs *stats;
 120   int numsys = getfsstat ((struct statfs *)0, 0L, MNT_WAIT); ],
 121     fu_cv_sys_mounted_getsstat=yes,
 122     fu_cv_sys_mounted_getsstat=no)])
 123   AC_MSG_RESULT($fu_cv_sys_mounted_getsstat)
 124   if test $fu_cv_sys_mounted_getsstat = yes; then
 125     ac_list_mounted_fs=found
 126     AC_DEFINE(MOUNTED_GETFSSTAT, 1,
 127               [Define if there is a function named getfsstat for reading the
 128    list of mounted filesystems.  (DEC Alpha running OSF/1)])
 129   fi
 130 fi
 131
 132 if test -z "$ac_list_mounted_fs"; then
 133   # AIX.
 134   AC_MSG_CHECKING([for mntctl function and struct vmount])
 135   AC_CACHE_VAL(fu_cv_sys_mounted_vmount,
 136   [AC_TRY_CPP([#include <fshelp.h>],
 137     fu_cv_sys_mounted_vmount=yes,
 138     fu_cv_sys_mounted_vmount=no)])
 139   AC_MSG_RESULT($fu_cv_sys_mounted_vmount)
 140   if test $fu_cv_sys_mounted_vmount = yes; then
 141     ac_list_mounted_fs=found
 142     AC_DEFINE(MOUNTED_VMOUNT, 1,
 143         [Define if there is a function named mntctl that can be used to read
 144    the list of mounted filesystems, and there is a system header file
 145    that declares `struct vmount.'  (AIX)])
 146   fi
 147 fi
 148
 149 if test -z "$ac_list_mounted_fs"; then
 150   # SVR3
 151   AC_MSG_CHECKING([for FIXME existence of three headers])
 152   AC_CACHE_VAL(fu_cv_sys_mounted_fread_fstyp,
 153     [AC_TRY_CPP([
 154 #include <sys/statfs.h>
 155 #include <sys/fstyp.h>
 156 #include <mnttab.h>],
 157                 fu_cv_sys_mounted_fread_fstyp=yes,
 158                 fu_cv_sys_mounted_fread_fstyp=no)])
 159   AC_MSG_RESULT($fu_cv_sys_mounted_fread_fstyp)
 160   if test $fu_cv_sys_mounted_fread_fstyp = yes; then
 161     ac_list_mounted_fs=found
 162     AC_DEFINE(MOUNTED_FREAD_FSTYP, 1,
 163 [Define if (like SVR2) there is no specific function for reading the
 164    list of mounted filesystems, and your system has these header files:
 165    <sys/fstyp.h> and <sys/statfs.h>.  (SVR3)])
 166   fi
 167 fi
 168
 169 if test -z "$ac_list_mounted_fs"; then
 170   # 4.4BSD and DEC OSF/1.
 171   AC_MSG_CHECKING([for getmntinfo function])
 172   AC_CACHE_VAL(fu_cv_sys_mounted_getmntinfo,
 173     [
 174       ok=
 175       if test $ac_cv_func_getmntinfo = yes; then
 176         AC_EGREP_HEADER(f_type;, sys/mount.h,
 177                         ok=yes)
 178       fi
 179       test -n "$ok" \
 180           && fu_cv_sys_mounted_getmntinfo=yes \
 181           || fu_cv_sys_mounted_getmntinfo=no
 182     ])
 183   AC_MSG_RESULT($fu_cv_sys_mounted_getmntinfo)
 184   if test $fu_cv_sys_mounted_getmntinfo = yes; then
 185     ac_list_mounted_fs=found
 186     AC_DEFINE(MOUNTED_GETMNTINFO, 1,
 187               [Define if there is a function named getmntinfo for reading the
 188    list of mounted filesystems.  (4.4BSD)])
 189   fi
 190 fi
 191
 192 if test -z "$ac_list_mounted_fs"; then
 193   # Ultrix
 194   AC_MSG_CHECKING([for getmnt function])
 195   AC_CACHE_VAL(fu_cv_sys_mounted_getmnt,
 196     [AC_TRY_CPP([
 197 #include <sys/fs_types.h>
 198 #include <sys/mount.h>],
 199                 fu_cv_sys_mounted_getmnt=yes,
 200                 fu_cv_sys_mounted_getmnt=no)])
 201   AC_MSG_RESULT($fu_cv_sys_mounted_getmnt)
 202   if test $fu_cv_sys_mounted_getmnt = yes; then
 203     ac_list_mounted_fs=found
 204     AC_DEFINE(MOUNTED_GETMNT, 1,
 205       [Define if there is a function named getmnt for reading the list of
 206    mounted filesystems.  (Ultrix)])
 207   fi
 208 fi
 209
 210 if test -z "$ac_list_mounted_fs"; then
 211   # BeOS
 212   AC_CHECK_FUNCS(next_dev fs_stat_dev)
 213   AC_CHECK_HEADERS(fs_info.h)
 214   AC_MSG_CHECKING([for BEOS mounted file system support functions])
 215   if test $ac_cv_header_fs_info_h = yes \
 216       && test $ac_cv_func_next_dev = yes \
 217         && test $ac_cv_func_fs_stat_dev = yes; then
 218     fu_result=yes
 219   else
 220     fu_result=no
 221   fi
 222   AC_MSG_RESULT($fu_result)
 223   if test $fu_result = yes; then
 224     ac_list_mounted_fs=found
 225     AC_DEFINE(MOUNTED_FS_STAT_DEV, 1,
 226       [Define if there are functions named next_dev and fs_stat_dev for
 227    reading the list of mounted filesystems.  (BeOS)])
 228   fi
 229 fi
 230
 231 if test -z "$ac_list_mounted_fs"; then
 232   # SVR2
 233   AC_MSG_CHECKING([whether it is possible to resort to fread on /etc/mnttab])
 234   AC_CACHE_VAL(fu_cv_sys_mounted_fread,
 235     [AC_TRY_CPP([#include <mnttab.h>],
 236                 fu_cv_sys_mounted_fread=yes,
 237                 fu_cv_sys_mounted_fread=no)])
 238   AC_MSG_RESULT($fu_cv_sys_mounted_fread)
 239   if test $fu_cv_sys_mounted_fread = yes; then
 240     ac_list_mounted_fs=found
 241     AC_DEFINE(MOUNTED_FREAD, 1,
 242               [Define if there is no specific function for reading the list of
 243    mounted filesystems.  fread will be used to read /etc/mnttab.  (SVR2) ])
 244   fi
 245 fi
 246
 247 if test -z "$ac_list_mounted_fs"; then
 248   AC_MSG_ERROR([could not determine how to read list of mounted filesystems])
 249   # FIXME -- no need to abort building the whole package
 250   # Can't build mountlist.c or anything that needs its functions
 251 fi
 252
 253 AS_IF([test $ac_list_mounted_fs = found], [$1], [$2])
 254
 255   ])