m4/math_h.m4

   1 # math_h.m4 serial 18
   2 dnl Copyright (C) 2007-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_MATH_H],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   gl_CHECK_NEXT_HEADERS([math.h])
  11   AC_REQUIRE([AC_C_INLINE])
  12
  13   AC_CACHE_CHECK([whether NAN macro works], [gl_cv_header_math_nan_works],
  14     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@%:@include <math.h>]],
  15       [[/* Solaris 10 has a broken definition of NAN.  Other platforms
  16         fail to provide NAN, or provide it only in C99 mode; this
  17         test only needs to fail when NAN is provided but wrong.  */
  18          float f = 1.0f;
  19 #ifdef NAN
  20          f = NAN;
  21 #endif
  22          return f == 0;]])],
  23       [gl_cv_header_math_nan_works=yes],
  24       [gl_cv_header_math_nan_works=no])])
  25   if test $gl_cv_header_math_nan_works = no; then
  26     REPLACE_NAN=1
  27   fi
  28   AC_CACHE_CHECK([whether HUGE_VAL works], [gl_cv_header_math_huge_val_works],
  29     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@%:@include <math.h>]],
  30       [[/* Solaris 10 has a broken definition of HUGE_VAL.  */
  31          double d = HUGE_VAL;
  32          return d == 0;]])],
  33       [gl_cv_header_math_huge_val_works=yes],
  34       [gl_cv_header_math_huge_val_works=no])])
  35   if test $gl_cv_header_math_huge_val_works = no; then
  36     REPLACE_HUGE_VAL=1
  37   fi
  38
  39   dnl Check for declarations of anything we want to poison if the
  40   dnl corresponding gnulib module is not in use.
  41   gl_WARN_ON_USE_PREPARE([[#include <math.h>
  42     ]], [acosl asinl atanl ceilf ceill cosl expl floorf floorl frexpl
  43     ldexpl logb logl round roundf roundl sinl sqrtl tanl trunc truncf truncl])
  44 ])
  45
  46 AC_DEFUN([gl_MATH_MODULE_INDICATOR],
  47 [
  48   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  49   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  50   GNULIB_[]m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=1
  51 ])
  52
  53 AC_DEFUN([gl_MATH_H_DEFAULTS],
  54 [
  55   GNULIB_ACOSL=0;    AC_SUBST([GNULIB_ACOSL])
  56   GNULIB_ASINL=0;    AC_SUBST([GNULIB_ASINL])
  57   GNULIB_ATANL=0;    AC_SUBST([GNULIB_ATANL])
  58   GNULIB_CEILF=0;    AC_SUBST([GNULIB_CEILF])
  59   GNULIB_CEILL=0;    AC_SUBST([GNULIB_CEILL])
  60   GNULIB_COSL=0;     AC_SUBST([GNULIB_COSL])
  61   GNULIB_EXPL=0;     AC_SUBST([GNULIB_EXPL])
  62   GNULIB_FLOORF=0;   AC_SUBST([GNULIB_FLOORF])
  63   GNULIB_FLOORL=0;   AC_SUBST([GNULIB_FLOORL])
  64   GNULIB_FREXP=0;    AC_SUBST([GNULIB_FREXP])
  65   GNULIB_FREXPL=0;   AC_SUBST([GNULIB_FREXPL])
  66   GNULIB_ISFINITE=0; AC_SUBST([GNULIB_ISFINITE])
  67   GNULIB_ISINF=0;    AC_SUBST([GNULIB_ISINF])
  68   GNULIB_ISNAN=0;    AC_SUBST([GNULIB_ISNAN])
  69   GNULIB_ISNANF=0;   AC_SUBST([GNULIB_ISNANF])
  70   GNULIB_ISNAND=0;   AC_SUBST([GNULIB_ISNAND])
  71   GNULIB_ISNANL=0;   AC_SUBST([GNULIB_ISNANL])
  72   GNULIB_LDEXPL=0;   AC_SUBST([GNULIB_LDEXPL])
  73   GNULIB_LOGB=0;     AC_SUBST([GNULIB_LOGB])
  74   GNULIB_LOGL=0;     AC_SUBST([GNULIB_LOGL])
  75   GNULIB_ROUND=0;    AC_SUBST([GNULIB_ROUND])
  76   GNULIB_ROUNDF=0;   AC_SUBST([GNULIB_ROUNDF])
  77   GNULIB_ROUNDL=0;   AC_SUBST([GNULIB_ROUNDL])
  78   GNULIB_SIGNBIT=0;  AC_SUBST([GNULIB_SIGNBIT])
  79   GNULIB_SINL=0;     AC_SUBST([GNULIB_SINL])
  80   GNULIB_SQRTL=0;    AC_SUBST([GNULIB_SQRTL])
  81   GNULIB_TANL=0;     AC_SUBST([GNULIB_TANL])
  82   GNULIB_TRUNC=0;    AC_SUBST([GNULIB_TRUNC])
  83   GNULIB_TRUNCF=0;   AC_SUBST([GNULIB_TRUNCF])
  84   GNULIB_TRUNCL=0;   AC_SUBST([GNULIB_TRUNCL])
  85   dnl Assume proper GNU behavior unless another module says otherwise.
  86   HAVE_ACOSL=1;                AC_SUBST([HAVE_ACOSL])
  87   HAVE_ASINL=1;                AC_SUBST([HAVE_ASINL])
  88   HAVE_ATANL=1;                AC_SUBST([HAVE_ATANL])
  89   HAVE_COSL=1;                 AC_SUBST([HAVE_COSL])
  90   HAVE_EXPL=1;                 AC_SUBST([HAVE_EXPL])
  91   HAVE_ISNANF=1;               AC_SUBST([HAVE_ISNANF])
  92   HAVE_ISNAND=1;               AC_SUBST([HAVE_ISNAND])
  93   HAVE_ISNANL=1;               AC_SUBST([HAVE_ISNANL])
  94   HAVE_LOGL=1;                 AC_SUBST([HAVE_LOGL])
  95   HAVE_SINL=1;                 AC_SUBST([HAVE_SINL])
  96   HAVE_SQRTL=1;                AC_SUBST([HAVE_SQRTL])
  97   HAVE_TANL=1;                 AC_SUBST([HAVE_TANL])
  98   HAVE_DECL_ACOSL=1;           AC_SUBST([HAVE_DECL_ACOSL])
  99   HAVE_DECL_ASINL=1;           AC_SUBST([HAVE_DECL_ASINL])
 100   HAVE_DECL_ATANL=1;           AC_SUBST([HAVE_DECL_ATANL])
 101   HAVE_DECL_COSL=1;            AC_SUBST([HAVE_DECL_COSL])
 102   HAVE_DECL_EXPL=1;            AC_SUBST([HAVE_DECL_EXPL])
 103   HAVE_DECL_FREXPL=1;          AC_SUBST([HAVE_DECL_FREXPL])
 104   HAVE_DECL_LDEXPL=1;          AC_SUBST([HAVE_DECL_LDEXPL])
 105   HAVE_DECL_LOGB=1;            AC_SUBST([HAVE_DECL_LOGB])
 106   HAVE_DECL_LOGL=1;            AC_SUBST([HAVE_DECL_LOGL])
 107   HAVE_DECL_SINL=1;            AC_SUBST([HAVE_DECL_SINL])
 108   HAVE_DECL_SQRTL=1;           AC_SUBST([HAVE_DECL_SQRTL])
 109   HAVE_DECL_TANL=1;            AC_SUBST([HAVE_DECL_TANL])
 110   HAVE_DECL_TRUNC=1;           AC_SUBST([HAVE_DECL_TRUNC])
 111   HAVE_DECL_TRUNCF=1;          AC_SUBST([HAVE_DECL_TRUNCF])
 112   REPLACE_CEILF=0;             AC_SUBST([REPLACE_CEILF])
 113   REPLACE_CEILL=0;             AC_SUBST([REPLACE_CEILL])
 114   REPLACE_FLOORF=0;            AC_SUBST([REPLACE_FLOORF])
 115   REPLACE_FLOORL=0;            AC_SUBST([REPLACE_FLOORL])
 116   REPLACE_FREXP=0;             AC_SUBST([REPLACE_FREXP])
 117   REPLACE_FREXPL=0;            AC_SUBST([REPLACE_FREXPL])
 118   REPLACE_HUGE_VAL=0;          AC_SUBST([REPLACE_HUGE_VAL])
 119   REPLACE_ISFINITE=0;          AC_SUBST([REPLACE_ISFINITE])
 120   REPLACE_ISINF=0;             AC_SUBST([REPLACE_ISINF])
 121   REPLACE_ISNAN=0;             AC_SUBST([REPLACE_ISNAN])
 122   REPLACE_LDEXPL=0;            AC_SUBST([REPLACE_LDEXPL])
 123   REPLACE_NAN=0;               AC_SUBST([REPLACE_NAN])
 124   REPLACE_ROUND=0;             AC_SUBST([REPLACE_ROUND])
 125   REPLACE_ROUNDF=0;            AC_SUBST([REPLACE_ROUNDF])
 126   REPLACE_ROUNDL=0;            AC_SUBST([REPLACE_ROUNDL])
 127   REPLACE_SIGNBIT=0;           AC_SUBST([REPLACE_SIGNBIT])
 128   REPLACE_SIGNBIT_USING_GCC=0; AC_SUBST([REPLACE_SIGNBIT_USING_GCC])
 129   REPLACE_TRUNCL=0;            AC_SUBST([REPLACE_TRUNCL])
 130 ])