m4/math_h.m4

   1 # math_h.m4 serial 50
   2 dnl Copyright (C) 2007-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_MATH_H],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   gl_CHECK_NEXT_HEADERS([math.h])
  11   AC_REQUIRE([AC_C_INLINE])
  12
  13   AC_CACHE_CHECK([whether NAN macro works], [gl_cv_header_math_nan_works],
  14     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@%:@include <math.h>]],
  15       [[/* Solaris 10 has a broken definition of NAN.  Other platforms
  16         fail to provide NAN, or provide it only in C99 mode; this
  17         test only needs to fail when NAN is provided but wrong.  */
  18          float f = 1.0f;
  19 #ifdef NAN
  20          f = NAN;
  21 #endif
  22          return f == 0;]])],
  23       [gl_cv_header_math_nan_works=yes],
  24       [gl_cv_header_math_nan_works=no])])
  25   if test $gl_cv_header_math_nan_works = no; then
  26     REPLACE_NAN=1
  27   fi
  28   AC_CACHE_CHECK([whether HUGE_VAL works], [gl_cv_header_math_huge_val_works],
  29     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@%:@include <math.h>]],
  30       [[/* Solaris 10 has a broken definition of HUGE_VAL.  */
  31          double d = HUGE_VAL;
  32          return d == 0;]])],
  33       [gl_cv_header_math_huge_val_works=yes],
  34       [gl_cv_header_math_huge_val_works=no])])
  35   if test $gl_cv_header_math_huge_val_works = no; then
  36     REPLACE_HUGE_VAL=1
  37   fi
  38
  39   dnl Check for declarations of anything we want to poison if the
  40   dnl corresponding gnulib module is not in use.
  41   gl_WARN_ON_USE_PREPARE([[#include <math.h>]],
  42     [acosf acosl asinf asinl atanf atanl
  43      ceilf ceill copysign copysignf copysignl cosf cosl coshf
  44      expf expl fabsf floorf floorl fmodf frexpf frexpl
  45      ldexpf ldexpl logb logf logl log10f modff powf
  46      round roundf roundl sinf sinl sinhf sqrtf sqrtl
  47      tanf tanl tanhf trunc truncf truncl])
  48 ])
  49
  50 AC_DEFUN([gl_MATH_MODULE_INDICATOR],
  51 [
  52   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  53   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  54   gl_MODULE_INDICATOR_SET_VARIABLE([$1])
  55   dnl Define it also as a C macro, for the benefit of the unit tests.
  56   gl_MODULE_INDICATOR_FOR_TESTS([$1])
  57 ])
  58
  59 AC_DEFUN([gl_MATH_H_DEFAULTS],
  60 [
  61   GNULIB_ACOSF=0;     AC_SUBST([GNULIB_ACOSF])
  62   GNULIB_ACOSL=0;     AC_SUBST([GNULIB_ACOSL])
  63   GNULIB_ASINF=0;     AC_SUBST([GNULIB_ASINF])
  64   GNULIB_ASINL=0;     AC_SUBST([GNULIB_ASINL])
  65   GNULIB_ATANF=0;     AC_SUBST([GNULIB_ATANF])
  66   GNULIB_ATANL=0;     AC_SUBST([GNULIB_ATANL])
  67   GNULIB_ATAN2F=0;    AC_SUBST([GNULIB_ATAN2F])
  68   GNULIB_CEIL=0;      AC_SUBST([GNULIB_CEIL])
  69   GNULIB_CEILF=0;     AC_SUBST([GNULIB_CEILF])
  70   GNULIB_CEILL=0;     AC_SUBST([GNULIB_CEILL])
  71   GNULIB_COPYSIGN=0;  AC_SUBST([GNULIB_COPYSIGN])
  72   GNULIB_COPYSIGNF=0; AC_SUBST([GNULIB_COPYSIGNF])
  73   GNULIB_COPYSIGNL=0; AC_SUBST([GNULIB_COPYSIGNL])
  74   GNULIB_COSF=0;      AC_SUBST([GNULIB_COSF])
  75   GNULIB_COSL=0;      AC_SUBST([GNULIB_COSL])
  76   GNULIB_COSHF=0;     AC_SUBST([GNULIB_COSHF])
  77   GNULIB_EXPF=0;      AC_SUBST([GNULIB_EXPF])
  78   GNULIB_EXPL=0;      AC_SUBST([GNULIB_EXPL])
  79   GNULIB_FABSF=0;     AC_SUBST([GNULIB_FABSF])
  80   GNULIB_FLOOR=0;     AC_SUBST([GNULIB_FLOOR])
  81   GNULIB_FLOORF=0;    AC_SUBST([GNULIB_FLOORF])
  82   GNULIB_FLOORL=0;    AC_SUBST([GNULIB_FLOORL])
  83   GNULIB_FMODF=0;     AC_SUBST([GNULIB_FMODF])
  84   GNULIB_FREXPF=0;    AC_SUBST([GNULIB_FREXPF])
  85   GNULIB_FREXP=0;     AC_SUBST([GNULIB_FREXP])
  86   GNULIB_FREXPL=0;    AC_SUBST([GNULIB_FREXPL])
  87   GNULIB_ISFINITE=0;  AC_SUBST([GNULIB_ISFINITE])
  88   GNULIB_ISINF=0;     AC_SUBST([GNULIB_ISINF])
  89   GNULIB_ISNAN=0;     AC_SUBST([GNULIB_ISNAN])
  90   GNULIB_ISNANF=0;    AC_SUBST([GNULIB_ISNANF])
  91   GNULIB_ISNAND=0;    AC_SUBST([GNULIB_ISNAND])
  92   GNULIB_ISNANL=0;    AC_SUBST([GNULIB_ISNANL])
  93   GNULIB_LDEXPF=0;    AC_SUBST([GNULIB_LDEXPF])
  94   GNULIB_LDEXPL=0;    AC_SUBST([GNULIB_LDEXPL])
  95   GNULIB_LOGB=0;      AC_SUBST([GNULIB_LOGB])
  96   GNULIB_LOGF=0;      AC_SUBST([GNULIB_LOGF])
  97   GNULIB_LOGL=0;      AC_SUBST([GNULIB_LOGL])
  98   GNULIB_LOG10F=0;    AC_SUBST([GNULIB_LOG10F])
  99   GNULIB_MODFF=0;     AC_SUBST([GNULIB_MODFF])
 100   GNULIB_POWF=0;      AC_SUBST([GNULIB_POWF])
 101   GNULIB_ROUND=0;     AC_SUBST([GNULIB_ROUND])
 102   GNULIB_ROUNDF=0;    AC_SUBST([GNULIB_ROUNDF])
 103   GNULIB_ROUNDL=0;    AC_SUBST([GNULIB_ROUNDL])
 104   GNULIB_SIGNBIT=0;   AC_SUBST([GNULIB_SIGNBIT])
 105   GNULIB_SINF=0;      AC_SUBST([GNULIB_SINF])
 106   GNULIB_SINL=0;      AC_SUBST([GNULIB_SINL])
 107   GNULIB_SINHF=0;     AC_SUBST([GNULIB_SINHF])
 108   GNULIB_SQRTF=0;     AC_SUBST([GNULIB_SQRTF])
 109   GNULIB_SQRTL=0;     AC_SUBST([GNULIB_SQRTL])
 110   GNULIB_TANF=0;      AC_SUBST([GNULIB_TANF])
 111   GNULIB_TANL=0;      AC_SUBST([GNULIB_TANL])
 112   GNULIB_TANHF=0;     AC_SUBST([GNULIB_TANHF])
 113   GNULIB_TRUNC=0;     AC_SUBST([GNULIB_TRUNC])
 114   GNULIB_TRUNCF=0;    AC_SUBST([GNULIB_TRUNCF])
 115   GNULIB_TRUNCL=0;    AC_SUBST([GNULIB_TRUNCL])
 116   dnl Assume proper GNU behavior unless another module says otherwise.
 117   HAVE_ACOSF=1;                AC_SUBST([HAVE_ACOSF])
 118   HAVE_ACOSL=1;                AC_SUBST([HAVE_ACOSL])
 119   HAVE_ASINF=1;                AC_SUBST([HAVE_ASINF])
 120   HAVE_ASINL=1;                AC_SUBST([HAVE_ASINL])
 121   HAVE_ATANF=1;                AC_SUBST([HAVE_ATANF])
 122   HAVE_ATANL=1;                AC_SUBST([HAVE_ATANL])
 123   HAVE_ATAN2F=1;               AC_SUBST([HAVE_ATAN2F])
 124   HAVE_COPYSIGN=1;             AC_SUBST([HAVE_COPYSIGN])
 125   HAVE_COPYSIGNF=1;            AC_SUBST([HAVE_COPYSIGNF])
 126   HAVE_COPYSIGNL=1;            AC_SUBST([HAVE_COPYSIGNL])
 127   HAVE_COSF=1;                 AC_SUBST([HAVE_COSF])
 128   HAVE_COSL=1;                 AC_SUBST([HAVE_COSL])
 129   HAVE_COSHF=1;                AC_SUBST([HAVE_COSHF])
 130   HAVE_EXPF=1;                 AC_SUBST([HAVE_EXPF])
 131   HAVE_EXPL=1;                 AC_SUBST([HAVE_EXPL])
 132   HAVE_FABSF=1;                AC_SUBST([HAVE_FABSF])
 133   HAVE_FMODF=1;                AC_SUBST([HAVE_FMODF])
 134   HAVE_FREXPF=1;               AC_SUBST([HAVE_FREXPF])
 135   HAVE_ISNANF=1;               AC_SUBST([HAVE_ISNANF])
 136   HAVE_ISNAND=1;               AC_SUBST([HAVE_ISNAND])
 137   HAVE_ISNANL=1;               AC_SUBST([HAVE_ISNANL])
 138   HAVE_LDEXPF=1;               AC_SUBST([HAVE_LDEXPF])
 139   HAVE_LOGF=1;                 AC_SUBST([HAVE_LOGF])
 140   HAVE_LOGL=1;                 AC_SUBST([HAVE_LOGL])
 141   HAVE_LOG10F=1;               AC_SUBST([HAVE_LOG10F])
 142   HAVE_MODFF=1;                AC_SUBST([HAVE_MODFF])
 143   HAVE_POWF=1;                 AC_SUBST([HAVE_POWF])
 144   HAVE_SINF=1;                 AC_SUBST([HAVE_SINF])
 145   HAVE_SINL=1;                 AC_SUBST([HAVE_SINL])
 146   HAVE_SINHF=1;                AC_SUBST([HAVE_SINHF])
 147   HAVE_SQRTF=1;                AC_SUBST([HAVE_SQRTF])
 148   HAVE_SQRTL=1;                AC_SUBST([HAVE_SQRTL])
 149   HAVE_TANF=1;                 AC_SUBST([HAVE_TANF])
 150   HAVE_TANL=1;                 AC_SUBST([HAVE_TANL])
 151   HAVE_TANHF=1;                AC_SUBST([HAVE_TANHF])
 152   HAVE_DECL_ACOSL=1;           AC_SUBST([HAVE_DECL_ACOSL])
 153   HAVE_DECL_ASINL=1;           AC_SUBST([HAVE_DECL_ASINL])
 154   HAVE_DECL_ATANL=1;           AC_SUBST([HAVE_DECL_ATANL])
 155   HAVE_DECL_CEILF=1;           AC_SUBST([HAVE_DECL_CEILF])
 156   HAVE_DECL_CEILL=1;           AC_SUBST([HAVE_DECL_CEILL])
 157   HAVE_DECL_COSL=1;            AC_SUBST([HAVE_DECL_COSL])
 158   HAVE_DECL_EXPL=1;            AC_SUBST([HAVE_DECL_EXPL])
 159   HAVE_DECL_FLOORF=1;          AC_SUBST([HAVE_DECL_FLOORF])
 160   HAVE_DECL_FLOORL=1;          AC_SUBST([HAVE_DECL_FLOORL])
 161   HAVE_DECL_FREXPL=1;          AC_SUBST([HAVE_DECL_FREXPL])
 162   HAVE_DECL_LDEXPL=1;          AC_SUBST([HAVE_DECL_LDEXPL])
 163   HAVE_DECL_LOGB=1;            AC_SUBST([HAVE_DECL_LOGB])
 164   HAVE_DECL_LOGL=1;            AC_SUBST([HAVE_DECL_LOGL])
 165   HAVE_DECL_ROUND=1;           AC_SUBST([HAVE_DECL_ROUND])
 166   HAVE_DECL_ROUNDF=1;          AC_SUBST([HAVE_DECL_ROUNDF])
 167   HAVE_DECL_ROUNDL=1;          AC_SUBST([HAVE_DECL_ROUNDL])
 168   HAVE_DECL_SINL=1;            AC_SUBST([HAVE_DECL_SINL])
 169   HAVE_DECL_SQRTL=1;           AC_SUBST([HAVE_DECL_SQRTL])
 170   HAVE_DECL_TANL=1;            AC_SUBST([HAVE_DECL_TANL])
 171   HAVE_DECL_TRUNC=1;           AC_SUBST([HAVE_DECL_TRUNC])
 172   HAVE_DECL_TRUNCF=1;          AC_SUBST([HAVE_DECL_TRUNCF])
 173   HAVE_DECL_TRUNCL=1;          AC_SUBST([HAVE_DECL_TRUNCL])
 174   REPLACE_CEIL=0;              AC_SUBST([REPLACE_CEIL])
 175   REPLACE_CEILF=0;             AC_SUBST([REPLACE_CEILF])
 176   REPLACE_CEILL=0;             AC_SUBST([REPLACE_CEILL])
 177   REPLACE_FLOOR=0;             AC_SUBST([REPLACE_FLOOR])
 178   REPLACE_FLOORF=0;            AC_SUBST([REPLACE_FLOORF])
 179   REPLACE_FLOORL=0;            AC_SUBST([REPLACE_FLOORL])
 180   REPLACE_FREXPF=0;            AC_SUBST([REPLACE_FREXPF])
 181   REPLACE_FREXP=0;             AC_SUBST([REPLACE_FREXP])
 182   REPLACE_FREXPL=0;            AC_SUBST([REPLACE_FREXPL])
 183   REPLACE_HUGE_VAL=0;          AC_SUBST([REPLACE_HUGE_VAL])
 184   REPLACE_ISFINITE=0;          AC_SUBST([REPLACE_ISFINITE])
 185   REPLACE_ISINF=0;             AC_SUBST([REPLACE_ISINF])
 186   REPLACE_ISNAN=0;             AC_SUBST([REPLACE_ISNAN])
 187   REPLACE_LDEXPL=0;            AC_SUBST([REPLACE_LDEXPL])
 188   REPLACE_NAN=0;               AC_SUBST([REPLACE_NAN])
 189   REPLACE_ROUND=0;             AC_SUBST([REPLACE_ROUND])
 190   REPLACE_ROUNDF=0;            AC_SUBST([REPLACE_ROUNDF])
 191   REPLACE_ROUNDL=0;            AC_SUBST([REPLACE_ROUNDL])
 192   REPLACE_SIGNBIT=0;           AC_SUBST([REPLACE_SIGNBIT])
 193   REPLACE_SIGNBIT_USING_GCC=0; AC_SUBST([REPLACE_SIGNBIT_USING_GCC])
 194   REPLACE_TRUNC=0;             AC_SUBST([REPLACE_TRUNC])
 195   REPLACE_TRUNCF=0;            AC_SUBST([REPLACE_TRUNCF])
 196   REPLACE_TRUNCL=0;            AC_SUBST([REPLACE_TRUNCL])
 197 ])
 198
 199 # gl_LONG_DOUBLE_VS_DOUBLE
 200 # determines whether 'long double' and 'double' have the same representation.
 201 # Sets variable HAVE_SAME_LONG_DOUBLE_AS_DOUBLE to 0 or 1, and defines
 202 # HAVE_SAME_LONG_DOUBLE_AS_DOUBLE accordingly.
 203 # The currently known platforms where this is the case are:
 204 # Linux/HPPA, Minix 3.1.8, AIX 5, AIX 6 and 7 with xlc, MSVC 9.
 205 AC_DEFUN([gl_LONG_DOUBLE_VS_DOUBLE],
 206 [
 207   AC_CACHE_CHECK([whether long double and double are the same],
 208     [gl_cv_long_double_equals_double],
 209     [AC_COMPILE_IFELSE(
 210        [AC_LANG_PROGRAM([[#include <float.h>]],
 211           [[typedef int check[sizeof (long double) == sizeof (double)
 212                               && LDBL_MANT_DIG == DBL_MANT_DIG
 213                               && LDBL_MAX_EXP == DBL_MAX_EXP
 214                               && LDBL_MIN_EXP == DBL_MIN_EXP
 215                               ? 1 : -1];
 216           ]])],
 217        [gl_cv_long_double_equals_double=yes],
 218        [gl_cv_long_double_equals_double=no])
 219     ])
 220   if test $gl_cv_long_double_equals_double = yes; then
 221     AC_DEFINE([HAVE_SAME_LONG_DOUBLE_AS_DOUBLE], [1],
 222       [Define to 1 if 'long double' and 'double' have the same representation.])
 223     HAVE_SAME_LONG_DOUBLE_AS_DOUBLE=1
 224   else
 225     HAVE_SAME_LONG_DOUBLE_AS_DOUBLE=0
 226   fi
 227   AC_SUBST([HAVE_SAME_LONG_DOUBLE_AS_DOUBLE])
 228 ])