m4/mathfunc.m4

   1 # mathfunc.m4 serial 7
   2 dnl Copyright (C) 2010-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 # gl_MATHFUNC(FUNC, RETTYPE, PARAMTYPES)
   8 # --------------------------------------------------
   9 # tests whether the function FUNC is available in libc or libm.
  10 # RETTYPE is the return type. PARAMTYPES is a parameter list, with parentheses.
  11 # It sets FUNC_LIBM to empty or "-lm" accordingly.
  12
  13 AC_DEFUN([gl_MATHFUNC],
  14 [
  15   dnl We need the RETTYPE and PARAMTYPES in order to force linking with the
  16   dnl function. With gcc >= 4.3 on glibc/x86_64, calls to the 'fabs' function
  17   dnl are inlined by the compiler, therefore linking of these calls does not
  18   dnl require -lm, but taking the function pointer of 'fabs' does.
  19   m4_pushdef([func], [$1])
  20   m4_pushdef([FUNC], [m4_translit([$1],[abcdefghijklmnopqrstuvwxyz],
  21                                        [ABCDEFGHIJKLMNOPQRSTUVWXYZ])])
  22   FUNC[]_LIBM=
  23   AC_CACHE_CHECK([whether func() can be used without linking with libm],
  24     [gl_cv_func_]func[_no_libm],
  25     [
  26       AC_LINK_IFELSE(
  27         [AC_LANG_PROGRAM(
  28            [[#ifndef __NO_MATH_INLINES
  29              # define __NO_MATH_INLINES 1 /* for glibc */
  30              #endif
  31              #include <math.h>
  32              $2 (*funcptr) $3 = ]func[;
  33              int i_ret;
  34              float f_ret;
  35              double d_ret;
  36              long double l_ret;]],
  37            [[$2 y = funcptr ]m4_bpatsubst([m4_bpatsubst([m4_bpatsubst([m4_bpatsubst([m4_bpatsubst([m4_bpatsubst([m4_bpatsubst([m4_bpatsubst([$3], [int \*], [&i_ret])], [float \*], [&f_ret])], [double \*], [&d_ret])], [long double \*], [&l_ret])], [int], [2])], [float], [1.618034f])], [long double], [1.618033988749894848L])], [double], [1.6180339887])[;
  38              return y < 0.3 || y > 1.7;
  39            ]])],
  40         [gl_cv_func_]func[_no_libm=yes],
  41         [gl_cv_func_]func[_no_libm=no])
  42     ])
  43   if test $gl_cv_func_[]func[]_no_libm = no; then
  44     AC_CACHE_CHECK([whether func() can be used with libm],
  45       [gl_cv_func_]func[_in_libm],
  46       [
  47         save_LIBS="$LIBS"
  48         LIBS="$LIBS -lm"
  49         AC_LINK_IFELSE(
  50           [AC_LANG_PROGRAM(
  51              [[#ifndef __NO_MATH_INLINES
  52                # define __NO_MATH_INLINES 1 /* for glibc */
  53                #endif
  54                #include <math.h>
  55                $2 (*funcptr) $3 = ]func[;
  56                int i_ret;
  57                float f_ret;
  58                double d_ret;
  59                long double l_ret;]],
  60              [[$2 y = funcptr ]m4_bpatsubst([m4_bpatsubst([m4_bpatsubst([m4_bpatsubst([m4_bpatsubst([m4_bpatsubst([m4_bpatsubst([m4_bpatsubst([$3], [int \*], [&i_ret])], [float \*], [&f_ret])], [double \*], [&d_ret])], [long double \*], [&l_ret])], [int], [2])], [float], [1.618034f])], [long double], [1.618033988749894848L])], [double], [1.6180339887])[;
  61                return y < 0.3 || y > 1.7;
  62              ]])],
  63           [gl_cv_func_]func[_in_libm=yes],
  64           [gl_cv_func_]func[_in_libm=no])
  65         LIBS="$save_LIBS"
  66       ])
  67     if test $gl_cv_func_[]func[]_in_libm = yes; then
  68       FUNC[]_LIBM=-lm
  69     fi
  70   fi
  71   AC_SUBST(FUNC[_LIBM])
  72   m4_popdef([FUNC])
  73   m4_popdef([func])
  74 ])
  75
  76 # gl_COMMON_DOUBLE_MATHFUNC(FUNC)
  77 # -------------------------------
  78 # tests whether the function FUNC is available in libc or libm.
  79 # It sets FUNC_LIBM to empty or "-lm" accordingly.
  80 # FUNC must be one of the following functions, that are present on all systems
  81 # and provided by libm on all systems except MacOS X, BeOS, Haiku:
  82 #   acos asin atan atan2 cbrt cos cosh erf erfc exp fmod hypot j0 j1 jn lgamma
  83 #   log log10 log1p pow remainder sin sinh sqrt tan tanh y0 y1 yn
  84
  85 AC_DEFUN([gl_COMMON_DOUBLE_MATHFUNC],
  86 [
  87   AC_REQUIRE([gl_COMMON_DOUBLE_MATHFUNC_TEST])
  88   m4_pushdef([FUNC], [m4_translit([$1],[abcdefghijklmnopqrstuvwxyz],
  89                                        [ABCDEFGHIJKLMNOPQRSTUVWXYZ])])
  90   FUNC[]_LIBM="$POW_LIBM"
  91   AC_SUBST(FUNC[_LIBM])
  92   m4_popdef([FUNC])
  93 ])
  94
  95 AC_DEFUN([gl_COMMON_DOUBLE_MATHFUNC_TEST],
  96 [
  97   dnl We could use any of the following:
  98   dnl gl_MATHFUNC([acos], [double], [(double)])
  99   dnl gl_MATHFUNC([asin], [double], [(double)])
 100   dnl gl_MATHFUNC([atan], [double], [(double)])
 101   dnl gl_MATHFUNC([atan2], [double], [(double, double)])
 102   dnl gl_MATHFUNC([cbrt], [double], [(double)])
 103   dnl gl_MATHFUNC([cos], [double], [(double)])
 104   dnl gl_MATHFUNC([cosh], [double], [(double)])
 105   dnl gl_MATHFUNC([erf], [double], [(double)])
 106   dnl gl_MATHFUNC([erfc], [double], [(double)])
 107   dnl gl_MATHFUNC([exp], [double], [(double)])
 108   dnl gl_MATHFUNC([fmod], [double], [(double, double)])
 109   dnl gl_MATHFUNC([hypot], [double], [(double, double)])
 110   dnl gl_MATHFUNC([j0], [double], [(double)])
 111   dnl gl_MATHFUNC([j1], [double], [(double)])
 112   dnl gl_MATHFUNC([jn], [double], [(int, double)])
 113   dnl gl_MATHFUNC([lgamma], [double], [(double)])
 114   dnl gl_MATHFUNC([log], [double], [(double)])
 115   dnl gl_MATHFUNC([log10], [double], [(double)])
 116   dnl gl_MATHFUNC([log1p], [double], [(double)])
 117   dnl gl_MATHFUNC([pow], [double], [(double, double)])
 118   dnl gl_MATHFUNC([remainder], [double], [(double, double)])
 119   dnl gl_MATHFUNC([sin], [double], [(double)])
 120   dnl gl_MATHFUNC([sinh], [double], [(double)])
 121   dnl gl_MATHFUNC([sqrt], [double], [(double)])
 122   dnl gl_MATHFUNC([tan], [double], [(double)])
 123   dnl gl_MATHFUNC([tanh], [double], [(double)])
 124   dnl gl_MATHFUNC([y0], [double], [(double)])
 125   dnl gl_MATHFUNC([y1], [double], [(double)])
 126   dnl gl_MATHFUNC([yn], [double], [(int, double)])
 127   gl_MATHFUNC([pow], [double], [(double, double)])
 128 ])