m4/mbsrtowcs.m4

   1 # mbsrtowcs.m4 serial 6
   2 dnl Copyright (C) 2008-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_MBSRTOWCS],
   8 [
   9   AC_REQUIRE([gl_WCHAR_H_DEFAULTS])
  10
  11   AC_REQUIRE([AC_TYPE_MBSTATE_T])
  12   gl_MBSTATE_T_BROKEN
  13
  14   AC_CHECK_FUNCS_ONCE([mbsrtowcs])
  15   if test $ac_cv_func_mbsrtowcs = no; then
  16     HAVE_MBSRTOWCS=0
  17   else
  18     if test $REPLACE_MBSTATE_T = 1; then
  19       REPLACE_MBSRTOWCS=1
  20     else
  21       gl_MBSRTOWCS_WORKS
  22       case "$gl_cv_func_mbsrtowcs_works" in
  23         *yes) ;;
  24         *) REPLACE_MBSRTOWCS=1 ;;
  25       esac
  26     fi
  27   fi
  28   if test $HAVE_MBSRTOWCS = 0 || test $REPLACE_MBSRTOWCS = 1; then
  29     gl_REPLACE_WCHAR_H
  30     AC_LIBOBJ([mbsrtowcs])
  31     AC_LIBOBJ([mbsrtowcs-state])
  32     gl_PREREQ_MBSRTOWCS
  33   fi
  34 ])
  35
  36 dnl Test whether mbsrtowcs works.
  37 dnl Result is gl_cv_func_mbsrtowcs_works.
  38
  39 AC_DEFUN([gl_MBSRTOWCS_WORKS],
  40 [
  41   AC_REQUIRE([AC_PROG_CC])
  42   AC_REQUIRE([gt_LOCALE_FR_UTF8])
  43   AC_REQUIRE([gt_LOCALE_JA])
  44   AC_REQUIRE([gt_LOCALE_ZH_CN])
  45   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  46   AC_CACHE_CHECK([whether mbsrtowcs works],
  47     [gl_cv_func_mbsrtowcs_works],
  48     [
  49       dnl Initial guess, used when cross-compiling or when no suitable locale
  50       dnl is present.
  51 changequote(,)dnl
  52       case "$host_os" in
  53                           # Guess no on HP-UX and Solaris.
  54         hpux* | solaris*) gl_cv_func_mbsrtowcs_works="guessing no" ;;
  55                           # Guess yes otherwise.
  56         *)                gl_cv_func_mbsrtowcs_works="guessing yes" ;;
  57       esac
  58 changequote([,])dnl
  59       if test $LOCALE_FR_UTF8 != none || test $LOCALE_JA != none || test $LOCALE_ZH_CN != none; then
  60         AC_TRY_RUN([
  61 #include <locale.h>
  62 #include <string.h>
  63 #include <wchar.h>
  64 int main ()
  65 {
  66   /* Test whether the function works when started with a conversion state
  67      in non-initial state.  This fails on HP-UX 11.11 and Solaris 10.  */
  68   if (setlocale (LC_ALL, "$LOCALE_FR_UTF8") != NULL)
  69     {
  70       const char input[] = "B\303\274\303\237er";
  71       mbstate_t state;
  72
  73       memset (&state, '\0', sizeof (mbstate_t));
  74       if (mbrtowc (NULL, input + 1, 1, &state) == (size_t)(-2))
  75         if (!mbsinit (&state))
  76           {
  77             const char *src = input + 2;
  78             if (mbsrtowcs (NULL, &src, 10, &state) != 4)
  79               return 1;
  80           }
  81     }
  82   if (setlocale (LC_ALL, "$LOCALE_JA") != NULL)
  83     {
  84       const char input[] = "<\306\374\313\334\270\354>";
  85       mbstate_t state;
  86
  87       memset (&state, '\0', sizeof (mbstate_t));
  88       if (mbrtowc (NULL, input + 3, 1, &state) == (size_t)(-2))
  89         if (!mbsinit (&state))
  90           {
  91             const char *src = input + 4;
  92             if (mbsrtowcs (NULL, &src, 10, &state) != 3)
  93               return 1;
  94           }
  95     }
  96   if (setlocale (LC_ALL, "$LOCALE_ZH_CN") != NULL)
  97     {
  98       const char input[] = "B\250\271\201\060\211\070er";
  99       mbstate_t state;
 100
 101       memset (&state, '\0', sizeof (mbstate_t));
 102       if (mbrtowc (NULL, input + 1, 1, &state) == (size_t)(-2))
 103         if (!mbsinit (&state))
 104           {
 105             const char *src = input + 2;
 106             if (mbsrtowcs (NULL, &src, 10, &state) != 4)
 107               return 1;
 108           }
 109     }
 110   return 0;
 111 }],
 112           [gl_cv_func_mbsrtowcs_works=yes],
 113           [gl_cv_func_mbsrtowcs_works=no],
 114           [:])
 115       fi
 116     ])
 117 ])
 118
 119 # Prerequisites of lib/mbsrtowcs.c.
 120 AC_DEFUN([gl_PREREQ_MBSRTOWCS], [
 121   :
 122 ])