m4/memmem.m4

   1 # memmem.m4 serial 20
   2 dnl Copyright (C) 2002, 2003, 2004, 2007, 2008, 2009, 2010 Free Software
   3 dnl Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl Check that memmem is present.
   9 AC_DEFUN([gl_FUNC_MEMMEM_SIMPLE],
  10 [
  11   dnl Persuade glibc <string.h> to declare memmem().
  12   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  13
  14   AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
  15   AC_REPLACE_FUNCS([memmem])
  16   AC_CHECK_DECLS_ONCE([memmem])
  17   if test $ac_cv_have_decl_memmem = no; then
  18     HAVE_DECL_MEMMEM=0
  19   else
  20     dnl Detect http://sourceware.org/bugzilla/show_bug.cgi?id=12092.
  21     AC_CACHE_CHECK([whether memmem works],
  22       [gl_cv_func_memmem_works_always],
  23       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  24 #include <string.h> /* for memmem */
  25 #define P "_EF_BF_BD"
  26 #define HAYSTACK "F_BD_CE_BD" P P P P "_C3_88_20" P P P "_C3_A7_20" P
  27 #define NEEDLE P P P P P
  28 ]], [[return !!memmem (HAYSTACK, strlen (HAYSTACK), NEEDLE, strlen (NEEDLE));
  29     ]])],
  30         [gl_cv_func_memmem_works_always=yes],
  31         [gl_cv_func_memmem_works_always=no],
  32         [dnl glibc 2.12 and cygwin 1.7.7 have a known bug.  Assume that it
  33          dnl works on all other platforms, even if it is not linear.
  34          AC_EGREP_CPP([Lucky user],
  35            [
  36 #ifdef __GNU_LIBRARY__
  37  #include <features.h>
  38  #if ((__GLIBC__ == 2 && __GLIBC_MINOR__ > 12) || (__GLIBC__ > 2)) \
  39      && !defined __UCLIBC__
  40   Lucky user
  41  #endif
  42 #elif defined __CYGWIN__
  43  #include <cygwin/version.h>
  44  #if CYGWIN_VERSION_DLL_COMBINED > CYGWIN_VERSION_DLL_MAKE_COMBINED (1007, 7)
  45   Lucky user
  46  #endif
  47 #else
  48   Lucky user
  49 #endif
  50            ],
  51            [gl_cv_func_memmem_works_always=yes],
  52            [gl_cv_func_memmem_works_always="guessing no"])
  53         ])
  54       ])
  55     if test "$gl_cv_func_memmem_works_always" != yes; then
  56       REPLACE_MEMMEM=1
  57       AC_LIBOBJ([memmem])
  58     fi
  59   fi
  60   gl_PREREQ_MEMMEM
  61 ]) # gl_FUNC_MEMMEM_SIMPLE
  62
  63 dnl Additionally, check that memmem is efficient and handles empty needles.
  64 AC_DEFUN([gl_FUNC_MEMMEM],
  65 [
  66   AC_REQUIRE([gl_FUNC_MEMMEM_SIMPLE])
  67   if test $HAVE_DECL_MEMMEM = 1 && test $REPLACE_MEMMEM = 0; then
  68     AC_CACHE_CHECK([whether memmem works in linear time],
  69       [gl_cv_func_memmem_works_fast],
  70       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  71 #include <signal.h> /* for signal */
  72 #include <string.h> /* for memmem */
  73 #include <stdlib.h> /* for malloc */
  74 #include <unistd.h> /* for alarm */
  75 static void quit (int sig) { exit (sig + 128); }
  76 ]], [[
  77     int result = 0;
  78     size_t m = 1000000;
  79     char *haystack = (char *) malloc (2 * m + 1);
  80     char *needle = (char *) malloc (m + 1);
  81     /* Failure to compile this test due to missing alarm is okay,
  82        since all such platforms (mingw) also lack memmem.  */
  83     signal (SIGALRM, quit);
  84     alarm (5);
  85     /* Check for quadratic performance.  */
  86     if (haystack && needle)
  87       {
  88         memset (haystack, 'A', 2 * m);
  89         haystack[2 * m] = 'B';
  90         memset (needle, 'A', m);
  91         needle[m] = 'B';
  92         if (!memmem (haystack, 2 * m + 1, needle, m + 1))
  93           result |= 1;
  94       }
  95     /* Check for empty needle behavior.  */
  96     if (!memmem ("a", 1, 0, 0))
  97       result |= 2;
  98     return result;
  99     ]])],
 100         [gl_cv_func_memmem_works_fast=yes], [gl_cv_func_memmem_works_fast=no],
 101         [dnl Only glibc > 2.12 and cygwin > 1.7.7 are known to have a
 102          dnl bug-free memmem that works in linear time.
 103          AC_EGREP_CPP([Lucky user],
 104            [
 105 #include <features.h>
 106 #ifdef __GNU_LIBRARY__
 107  #if ((__GLIBC__ == 2 && __GLIBC_MINOR__ > 12) || (__GLIBC__ > 2)) \
 108      && !defined __UCLIBC__
 109   Lucky user
 110  #endif
 111 #endif
 112 #ifdef __CYGWIN__
 113  #include <cygwin/version.h>
 114  #if CYGWIN_VERSION_DLL_COMBINED > CYGWIN_VERSION_DLL_MAKE_COMBINED (1007, 7)
 115   Lucky user
 116  #endif
 117 #endif
 118            ],
 119            [gl_cv_func_memmem_works_fast=yes],
 120            [gl_cv_func_memmem_works_fast="guessing no"])
 121         ])
 122       ])
 123     if test "$gl_cv_func_memmem_works_fast" != yes; then
 124       REPLACE_MEMMEM=1
 125       AC_LIBOBJ([memmem])
 126     fi
 127   fi
 128 ]) # gl_FUNC_MEMMEM
 129
 130 # Prerequisites of lib/memmem.c.
 131 AC_DEFUN([gl_PREREQ_MEMMEM], [:])