m4/memmem.m4

   1 # memmem.m4 serial 14
   2 dnl Copyright (C) 2002, 2003, 2004, 2007, 2008, 2009 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl Check that memmem is present.
   8 AC_DEFUN([gl_FUNC_MEMMEM_SIMPLE],
   9 [
  10   dnl Persuade glibc <string.h> to declare memmem().
  11   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  12
  13   AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
  14   AC_REPLACE_FUNCS([memmem])
  15   AC_CHECK_DECLS_ONCE([memmem])
  16   if test $ac_cv_have_decl_memmem = no; then
  17     HAVE_DECL_MEMMEM=0
  18   fi
  19   gl_PREREQ_MEMMEM
  20 ]) # gl_FUNC_MEMMEM_SIMPLE
  21
  22 dnl Additionally, check that memmem is efficient and handles empty needles.
  23 AC_DEFUN([gl_FUNC_MEMMEM],
  24 [
  25   AC_REQUIRE([gl_FUNC_MEMMEM_SIMPLE])
  26   if test $ac_cv_have_decl_memmem = yes; then
  27     AC_CACHE_CHECK([whether memmem works in linear time],
  28       [gl_cv_func_memmem_works],
  29       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  30 #include <signal.h> /* for signal */
  31 #include <string.h> /* for memmem */
  32 #include <stdlib.h> /* for malloc */
  33 #include <unistd.h> /* for alarm */
  34 ]], [[size_t m = 1000000;
  35     char *haystack = (char *) malloc (2 * m + 1);
  36     char *needle = (char *) malloc (m + 1);
  37     void *result = 0;
  38     /* Failure to compile this test due to missing alarm is okay,
  39        since all such platforms (mingw) also lack memmem.  */
  40     signal (SIGALRM, SIG_DFL);
  41     alarm (5);
  42     /* Check for quadratic performance.  */
  43     if (haystack && needle)
  44       {
  45         memset (haystack, 'A', 2 * m);
  46         haystack[2 * m] = 'B';
  47         memset (needle, 'A', m);
  48         needle[m] = 'B';
  49         result = memmem (haystack, 2 * m + 1, needle, m + 1);
  50       }
  51     /* Check for empty needle behavior.  */
  52     return !result || !memmem ("a", 1, 0, 0);]])],
  53         [gl_cv_func_memmem_works=yes], [gl_cv_func_memmem_works=no],
  54         [dnl Only glibc >= 2.9 and cygwin >= 1.7.0 are known to have a
  55          dnl memmem that works in linear time.
  56          AC_EGREP_CPP([Lucky user],
  57            [
  58 #include <features.h>
  59 #ifdef __GNU_LIBRARY__
  60  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 9) || (__GLIBC__ > 2)
  61   Lucky user
  62  #endif
  63 #endif
  64 #ifdef __CYGWIN__
  65  #include <cygwin/version.h>
  66  #if CYGWIN_VERSION_DLL_MAJOR >= 1007
  67   Lucky user
  68  #endif
  69 #endif
  70            ],
  71            [gl_cv_func_memmem_works=yes],
  72            [gl_cv_func_memmem_works="guessing no"])
  73         ])
  74       ])
  75     if test "$gl_cv_func_memmem_works" != yes; then
  76       REPLACE_MEMMEM=1
  77       AC_LIBOBJ([memmem])
  78     fi
  79   fi
  80 ]) # gl_FUNC_MEMMEM
  81
  82 # Prerequisites of lib/memmem.c.
  83 AC_DEFUN([gl_PREREQ_MEMMEM], [:])