m4/memmem.m4

   1 # memmem.m4 serial 7
   2 dnl Copyright (C) 2002, 2003, 2004, 2007, 2008 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_MEMMEM],
   8 [
   9   dnl Persuade glibc <string.h> to declare memmem().
  10   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  11
  12   AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
  13   AC_REPLACE_FUNCS(memmem)
  14   AC_CHECK_DECLS_ONCE(memmem)
  15   if test $ac_cv_have_decl_memmem = no; then
  16     HAVE_DECL_MEMMEM=0
  17   else
  18     AC_CACHE_CHECK([whether memmem works in linear time],
  19       [gl_cv_func_memmem_works],
  20       [AC_RUN_IFELSE([AC_LANG_PROGRAM([
  21 #include <string.h> /* for memmem */
  22 #include <stdlib.h> /* for malloc */
  23 #include <unistd.h> /* for alarm */
  24 ], [[size_t m = 1000000;
  25     char *haystack = (char *) malloc (2 * m + 1);
  26     char *needle = (char *) malloc (m + 1);
  27     void *result = 0;
  28     /* Failure to compile this test due to missing alarm is okay,
  29        since all such platforms (mingw) also lack memmem.  */
  30     alarm (5);
  31     if (haystack && needle)
  32       {
  33         memset (haystack, 'A', 2 * m);
  34         haystack[2 * m] = 'B';
  35         memset (needle, 'A', m);
  36         needle[m] = 'B';
  37         result = memmem (haystack, 2 * m + 1, needle, m + 1);
  38       }
  39     return !result || !memmem ("a", 1, 0, 0);]])],
  40         [gl_cv_func_memmem_works=yes], [gl_cv_func_memmem_works=no],
  41         [dnl pessimistically assume the worst, since even glibc 2.6.1
  42          dnl has quadratic complexity in its memmem
  43          gl_cv_func_memmem_works=no])])
  44     if test $gl_cv_func_memmem_works = no; then
  45       REPLACE_MEMMEM=1
  46       AC_LIBOBJ([memmem])
  47     fi
  48   fi
  49   gl_PREREQ_MEMMEM
  50 ])
  51
  52 # Prerequisites of lib/memmem.c.
  53 AC_DEFUN([gl_PREREQ_MEMMEM], [:])