m4/mkstemp.m4

   1 #serial 1
   2
   3 # On some systems (e.g., HPUX-10.20), mkstemp has the silly limit that it
   4 # can create no more than 26 files from a given template.  Other systems
   5 # lack mkstemp altogether.  On either type of system, arrange to use the
   6 # replacement function.
   7 AC_DEFUN([UTILS_FUNC_MKSTEMP],
   8 [dnl
   9   AC_REPLACE_FUNCS(mkstemp)
  10   if test $ac_cv_func_mkstemp = no; then
  11     utils_cv_func_mkstemp_limitations=yes
  12   else
  13     AC_CACHE_CHECK([for mkstemp limitations],
  14       utils_cv_func_mkstemp_limitations,
  15       [
  16         utils_tmpdir_mkstemp=mkst-$$$$
  17         # Arrange for deletion-upon-exception of this temporary directory.
  18         ac_clean_files="$ac_clean_files $utils_tmpdir_mkstemp"
  19         mkdir $utils_tmpdir_mkstemp
  20
  21         AC_TRY_RUN([
  22 #         include <stdlib.h>
  23           int main ()
  24           {
  25             int i;
  26             for (i = 0; i < 30; i++)
  27               {
  28                 char template[] = "$utils_tmpdir_mkstemp/aXXXXXX";
  29                 if (mkstemp (template) == -1)
  30                   exit (1);
  31               }
  32             exit (0);
  33           }
  34           ],
  35         utils_cv_func_mkstemp_limitations=no,
  36         utils_cv_func_mkstemp_limitations=yes,
  37         utils_cv_func_mkstemp_limitations=yes
  38         )
  39
  40         rm -rf $utils_tmpdir_mkstemp
  41       ]
  42     )
  43   fi
  44
  45   if test $utils_cv_func_mkstemp_limitations = yes; then
  46     AC_LIBOBJ(mkstemp)
  47     AC_LIBOBJ(tempname)
  48     AC_DEFINE(mkstemp, rpl_mkstemp,
  49       [Define to rpl_mkstemp if the replacement function should be used.])
  50   fi
  51 ])