m4/mkstemp.m4

   1 #serial 18
   2
   3 # Copyright (C) 2001, 2003-2007, 2009-2010 Free Software Foundation, Inc.
   4 # This file is free software; the Free Software Foundation
   5 # gives unlimited permission to copy and/or distribute it,
   6 # with or without modifications, as long as this notice is preserved.
   7
   8 # On some hosts (e.g., HP-UX 10.20, SunOS 4.1.4, Solaris 2.5.1), mkstemp has a
   9 # silly limit that it can create no more than 26 files from a given template.
  10 # Other systems lack mkstemp altogether.
  11 # On OSF1/Tru64 V4.0F, the system-provided mkstemp function can create
  12 # only 32 files per process.
  13 # On systems like the above, arrange to use the replacement function.
  14 AC_DEFUN([gl_FUNC_MKSTEMP],
  15 [
  16   AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
  17   AC_REQUIRE([AC_SYS_LARGEFILE])
  18
  19   AC_CHECK_FUNCS_ONCE([mkstemp])
  20   if test $ac_cv_func_mkstemp = yes; then
  21     AC_CACHE_CHECK([for working mkstemp],
  22       [gl_cv_func_working_mkstemp],
  23       [
  24         mkdir conftest.mkstemp
  25         AC_RUN_IFELSE(
  26           [AC_LANG_PROGRAM(
  27             [AC_INCLUDES_DEFAULT],
  28             [[int i;
  29               off_t large = (off_t) 4294967295u;
  30               if (large < 0)
  31                 large = 2147483647;
  32               for (i = 0; i < 70; i++)
  33                 {
  34                   char templ[] = "conftest.mkstemp/coXXXXXX";
  35                   int (*mkstemp_function) (char *) = mkstemp;
  36                   int fd = mkstemp_function (templ);
  37                   if (fd < 0 || lseek (fd, large, SEEK_SET) != large)
  38                     return 1;
  39                   close (fd);
  40                 }
  41               return 0;]])],
  42           [gl_cv_func_working_mkstemp=yes],
  43           [gl_cv_func_working_mkstemp=no],
  44           [gl_cv_func_working_mkstemp=no])
  45         rm -rf conftest.mkstemp
  46       ])
  47     if test $gl_cv_func_working_mkstemp != yes; then
  48       REPLACE_MKSTEMP=1
  49       AC_LIBOBJ([mkstemp])
  50       gl_PREREQ_MKSTEMP
  51     fi
  52   else
  53     HAVE_MKSTEMP=0
  54     AC_LIBOBJ([mkstemp])
  55     gl_PREREQ_MKSTEMP
  56   fi
  57 ])
  58
  59 # Prerequisites of lib/mkstemp.c.
  60 AC_DEFUN([gl_PREREQ_MKSTEMP],
  61 [
  62 ])