m4/mktime.m4

   1 dnl From Jim Meyering.
   2 dnl FIXME: this should migrate into libit.
   3
   4 AC_DEFUN(AM_FUNC_MKTIME,
   5 [AC_REQUIRE([AC_HEADER_TIME])dnl
   6  AC_CHECK_HEADERS(sys/time.h)
   7  AC_CACHE_CHECK([for working mktime], am_cv_func_working_mktime,
   8   [AC_TRY_RUN([/* Test program from Tony Leneis (tony@plaza.ds.adp.com).  */
   9 #if TIME_WITH_SYS_TIME
  10 # include <sys/time.h>
  11 # include <time.h>
  12 #else
  13 # if HAVE_SYS_TIME_H
  14 #  include <sys/time.h>
  15 # else
  16 #  include <time.h>
  17 # endif
  18 #endif
  19 int
  20 main ()
  21 {
  22   time_t today = time (0);
  23   struct tm *local = localtime (&today);
  24   exit (mktime (local) != today);
  25 }
  26               ],
  27              am_cv_func_working_mktime=yes, am_cv_func_working_mktime=no,
  28              dnl When crosscompiling, assume mktime is missing or broken.
  29              am_cv_func_working_mktime=no)
  30   ])
  31   if test $am_cv_func_working_mktime = no; then
  32     LIBOBJS="$LIBOBJS mktime.o"
  33   fi
  34 ])