m4/netdb_h.m4

   1 # netdb_h.m4 serial 4
   2 dnl Copyright (C) 2008 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_HEADER_NETDB],
   8 [
   9   AC_REQUIRE([gl_NETDB_H_DEFAULTS])
  10   gl_CHECK_NEXT_HEADERS([netdb.h])
  11   if test $ac_cv_header_netdb_h = yes; then
  12     AC_CHECK_TYPES([struct addrinfo], [NETDB_H=''], [NETDB_H='netdb.h'],
  13                    [[#include <netdb.h>]])
  14     HAVE_NETDB_H=1
  15   else
  16     NETDB_H='netdb.h'
  17     HAVE_NETDB_H=0
  18   fi
  19   AC_SUBST([HAVE_NETDB_H])
  20   AC_SUBST([NETDB_H])
  21 ])
  22
  23 AC_DEFUN([gl_NETDB_MODULE_INDICATOR],
  24 [
  25   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  26   AC_REQUIRE([gl_NETDB_H_DEFAULTS])
  27   GNULIB_[]m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=1
  28 ])
  29
  30 AC_DEFUN([gl_NETDB_H_DEFAULTS],
  31 [
  32   GNULIB_GETADDRINFO=0; AC_SUBST([GNULIB_GETADDRINFO])
  33   dnl Assume proper GNU behavior unless another module says otherwise.
  34   HAVE_STRUCT_ADDRINFO=1;   AC_SUBST([HAVE_STRUCT_ADDRINFO])
  35   HAVE_DECL_FREEADDRINFO=1; AC_SUBST([HAVE_DECL_FREEADDRINFO])
  36   HAVE_DECL_GAI_STRERROR=1; AC_SUBST([HAVE_DECL_GAI_STRERROR])
  37   HAVE_DECL_GETADDRINFO=1;  AC_SUBST([HAVE_DECL_GETADDRINFO])
  38   HAVE_DECL_GETNAMEINFO=1;  AC_SUBST([HAVE_DECL_GETNAMEINFO])
  39 ])