m4/netdb_h.m4

   1 # netdb_h.m4 serial 1
   2 dnl Copyright (C) 2008 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_HEADER_NETDB],
   8 [
   9   AC_REQUIRE([gl_NETDB_H_DEFAULTS])
  10   AC_CACHE_CHECK([whether <netdb.h> is self-contained],
  11     [gl_cv_header_netdb_h_selfcontained],
  12     [
  13       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
  14                                          [[struct hostent h;]])],
  15         [gl_cv_header_netdb_h_selfcontained=yes],
  16         [gl_cv_header_netdb_h_selfcontained=no])
  17     ])
  18   if test $gl_cv_header_netdb_h_selfcontained = yes; then
  19     NETDB_H=''
  20   else
  21     NETDB_H='netdb.h'
  22     gl_CHECK_NEXT_HEADERS([netdb.h])
  23     if test $ac_cv_header_netdb_h = yes; then
  24       HAVE_NETDB_H=1
  25     else
  26       HAVE_NETDB_H=0
  27     fi
  28     AC_SUBST([HAVE_NETDB_H])
  29   fi
  30   AC_SUBST([NETDB_H])
  31 ])
  32
  33 AC_DEFUN([gl_NETDB_MODULE_INDICATOR],
  34 [
  35   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  36   AC_REQUIRE([gl_NETDB_H_DEFAULTS])
  37   GNULIB_[]m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=1
  38 ])
  39
  40 AC_DEFUN([gl_NETDB_H_DEFAULTS],
  41 [
  42   :
  43 ])