m4/netdb_h.m4

   1 # netdb_h.m4 serial 6
   2 dnl Copyright (C) 2008, 2009, 2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_HEADER_NETDB],
   8 [
   9   AC_REQUIRE([gl_NETDB_H_DEFAULTS])
  10   AC_CHECK_HEADERS_ONCE([netdb.h])
  11   gl_CHECK_NEXT_HEADERS([netdb.h])
  12   if test $ac_cv_header_netdb_h = yes; then
  13     AC_COMPILE_IFELSE(
  14       [AC_LANG_PROGRAM([[
  15          #include <netdb.h>
  16          struct addrinfo a;
  17          int b = EAI_OVERFLOW;
  18          int c = AI_NUMERICSERV;
  19        ]])],
  20       [NETDB_H=''], [NETDB_H='netdb.h'])
  21     HAVE_NETDB_H=1
  22   else
  23     NETDB_H='netdb.h'
  24     HAVE_NETDB_H=0
  25   fi
  26   AC_SUBST([HAVE_NETDB_H])
  27   AC_SUBST([NETDB_H])
  28 ])
  29
  30 AC_DEFUN([gl_NETDB_MODULE_INDICATOR],
  31 [
  32   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  33   AC_REQUIRE([gl_NETDB_H_DEFAULTS])
  34   GNULIB_[]m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=1
  35 ])
  36
  37 AC_DEFUN([gl_NETDB_H_DEFAULTS],
  38 [
  39   GNULIB_GETADDRINFO=0; AC_SUBST([GNULIB_GETADDRINFO])
  40   dnl Assume proper GNU behavior unless another module says otherwise.
  41   HAVE_STRUCT_ADDRINFO=1;   AC_SUBST([HAVE_STRUCT_ADDRINFO])
  42   HAVE_DECL_FREEADDRINFO=1; AC_SUBST([HAVE_DECL_FREEADDRINFO])
  43   HAVE_DECL_GAI_STRERROR=1; AC_SUBST([HAVE_DECL_GAI_STRERROR])
  44   HAVE_DECL_GETADDRINFO=1;  AC_SUBST([HAVE_DECL_GETADDRINFO])
  45   HAVE_DECL_GETNAMEINFO=1;  AC_SUBST([HAVE_DECL_GETNAMEINFO])
  46 ])