m4/openat.m4

   1 # serial 24
   2 # See if we need to use our replacement for Solaris' openat et al functions.
   3
   4 dnl Copyright (C) 2004-2009 Free Software Foundation, Inc.
   5 dnl This file is free software; the Free Software Foundation
   6 dnl gives unlimited permission to copy and/or distribute it,
   7 dnl with or without modifications, as long as this notice is preserved.
   8
   9 # Written by Jim Meyering.
  10
  11 AC_DEFUN([gl_FUNC_OPENAT],
  12 [
  13   AC_REQUIRE([gl_FCNTL_H_DEFAULTS])
  14   GNULIB_OPENAT=1
  15
  16   AC_REQUIRE([gl_SYS_STAT_H_DEFAULTS])
  17   GNULIB_FCHMODAT=1
  18   GNULIB_FSTATAT=1
  19   GNULIB_MKDIRAT=1
  20
  21   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  22   GNULIB_FCHOWNAT=1
  23   GNULIB_UNLINKAT=1
  24
  25   AC_LIBOBJ([openat-proc])
  26   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  27   AC_CHECK_FUNCS_ONCE([lchmod])
  28   AC_REPLACE_FUNCS([fchmodat fstatat mkdirat openat unlinkat])
  29   AC_REQUIRE([AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK])
  30   case $ac_cv_func_openat+$ac_cv_func_lstat_dereferences_slashed_symlink in
  31   yes+yes) ;;
  32   yes+*)
  33     # Solaris 9 has *at functions, but uniformly mishandles trailing
  34     # slash in all of them.
  35     AC_LIBOBJ([openat])
  36     REPLACE_OPENAT=1
  37     AC_LIBOBJ([fstatat])
  38     REPLACE_FSTATAT=1
  39     AC_LIBOBJ([unlinkat])
  40     REPLACE_UNLINKAT=1
  41     ;;
  42   *)
  43     HAVE_OPENAT=0
  44     HAVE_UNLINKAT=0 # No known system with unlinkat but not openat
  45     HAVE_FSTATAT=0 # No known system with fstatat but not openat
  46     gl_PREREQ_OPENAT;;
  47   esac
  48   if test $ac_cv_func_fchmodat != yes; then
  49     HAVE_FCHMODAT=0
  50   fi
  51   if test $ac_cv_func_mkdirat != yes; then
  52     HAVE_MKDIRAT=0
  53   fi
  54   gl_FUNC_FCHOWNAT
  55 ])
  56
  57 # gl_FUNC_FCHOWNAT_DEREF_BUG([ACTION-IF-BUGGY[, ACTION-IF-NOT_BUGGY]])
  58 AC_DEFUN([gl_FUNC_FCHOWNAT_DEREF_BUG],
  59 [
  60   AC_CACHE_CHECK([whether fchownat works with AT_SYMLINK_NOFOLLOW],
  61     gl_cv_func_fchownat_nofollow_works,
  62     [
  63      gl_dangle=conftest.dangle
  64      # Remove any remnants of a previous test.
  65      rm -f $gl_dangle
  66      # Arrange for deletion of the temporary file this test creates.
  67      ac_clean_files="$ac_clean_files $gl_dangle"
  68      ln -s conftest.no-such $gl_dangle
  69      AC_RUN_IFELSE(
  70        [AC_LANG_SOURCE(
  71           [[
  72 #include <fcntl.h>
  73 #include <unistd.h>
  74 #include <stdlib.h>
  75 #include <errno.h>
  76 #include <sys/types.h>
  77 int
  78 main ()
  79 {
  80   return (fchownat (AT_FDCWD, "$gl_dangle", -1, getgid (),
  81                     AT_SYMLINK_NOFOLLOW) != 0
  82           && errno == ENOENT);
  83 }
  84           ]])],
  85     [gl_cv_func_fchownat_nofollow_works=yes],
  86     [gl_cv_func_fchownat_nofollow_works=no],
  87     [gl_cv_func_fchownat_nofollow_works=no],
  88     )
  89   ])
  90   AS_IF([test $gl_cv_func_fchownat_nofollow_works = no], [$1], [$2])
  91 ])
  92
  93 # If we have the fchownat function, and it has the bug (in glibc-2.4)
  94 # that it dereferences symlinks even with AT_SYMLINK_NOFOLLOW, then
  95 # use the replacement function.
  96 # Also use the replacement function if fchownat is simply not available.
  97 AC_DEFUN([gl_FUNC_FCHOWNAT],
  98 [
  99   AC_CHECK_FUNC([fchownat],
 100     [gl_FUNC_FCHOWNAT_DEREF_BUG([REPLACE_FCHOWNAT=1])],
 101     [HAVE_FCHOWNAT=0])
 102   if test $HAVE_FCHOWNAT = 0 || test $REPLACE_FCHOWNAT = 1; then
 103     AC_LIBOBJ([fchownat])
 104   fi
 105 ])
 106
 107 AC_DEFUN([gl_PREREQ_OPENAT],
 108 [
 109   AC_REQUIRE([gl_PROMOTED_TYPE_MODE_T])
 110   :
 111 ])