Merge branch 'upstream' into stable
[gnulib.git] / m4 / poll.m4
1 # poll.m4 serial 12
2 dnl Copyright (c) 2003, 2005, 2006, 2007, 2009, 2010 Free Software Foundation,
3 dnl Inc.
4 dnl This file is free software; the Free Software Foundation
5 dnl gives unlimited permission to copy and/or distribute it,
6 dnl with or without modifications, as long as this notice is preserved.
7
8 AC_DEFUN([gl_FUNC_POLL],
9 [
10   AC_REQUIRE([gl_POLL_H])
11   if test "$ac_cv_header_poll_h" = no; then
12     ac_cv_func_poll=no
13     gl_cv_func_poll=no
14   else
15     AC_CHECK_FUNC([poll],
16       [# Check whether poll() works on special files (like /dev/null) and
17        # and ttys (like /dev/tty). On MacOS X 10.4.0 and AIX 5.3, it doesn't.
18        AC_RUN_IFELSE([AC_LANG_SOURCE([[
19 #include <fcntl.h>
20 #include <poll.h>
21          int main()
22          {
23            int result = 0;
24            struct pollfd ufd;
25            /* Try /dev/null for reading.  */
26            ufd.fd = open ("/dev/null", O_RDONLY);
27            /* If /dev/null does not exist, it's not MacOS X nor AIX. */
28            if (ufd.fd >= 0)
29              {
30                ufd.events = POLLIN;
31                ufd.revents = 0;
32                if (!(poll (&ufd, 1, 0) == 1 && ufd.revents == POLLIN))
33                  result |= 1;
34              }
35            /* Try /dev/null for writing.  */
36            ufd.fd = open ("/dev/null", O_WRONLY);
37            /* If /dev/null does not exist, it's not MacOS X nor AIX. */
38            if (ufd.fd >= 0)
39              {
40                ufd.events = POLLOUT;
41                ufd.revents = 0;
42                if (!(poll (&ufd, 1, 0) == 1 && ufd.revents == POLLOUT))
43                  result |= 2;
44              }
45            /* Trying /dev/tty may be too environment dependent.  */
46            return result;
47          }]])],
48          [gl_cv_func_poll=yes],
49          [gl_cv_func_poll=no],
50          [# When cross-compiling, assume that poll() works everywhere except on
51           # MacOS X or AIX, regardless of its version.
52           AC_EGREP_CPP([MacOSX], [
53 #if (defined(__APPLE__) && defined(__MACH__)) || defined(_AIX)
54 This is MacOSX or AIX
55 #endif
56 ], [gl_cv_func_poll=no], [gl_cv_func_poll=yes])])])
57   fi
58   if test $gl_cv_func_poll != yes; then
59     AC_CHECK_FUNC([poll], [ac_cv_func_poll=yes], [ac_cv_func_poll=no])
60     if test $ac_cv_func_poll = no; then
61       HAVE_POLL=0
62     else
63       REPLACE_POLL=1
64     fi
65   fi
66   if test $HAVE_POLL = 0 || test $REPLACE_POLL = 1; then
67     gl_REPLACE_POLL_H
68     AC_LIBOBJ([poll])
69     gl_PREREQ_POLL
70   else
71     AC_DEFINE([HAVE_POLL], [1],
72       [Define to 1 if you have the 'poll' function and it works.])
73   fi
74 ])
75
76 # Prerequisites of lib/poll.c.
77 AC_DEFUN([gl_PREREQ_POLL],
78 [
79   AC_CHECK_HEADERS_ONCE([sys/ioctl.h sys/filio.h])
80 ])