m4/popen.m4

   1 # popen.m4 serial 2
   2 dnl Copyright (C) 2009, 2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_POPEN],
   8 [
   9   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  10   AC_CACHE_CHECK([whether popen works with closed stdin],
  11     [gl_cv_func_popen_works],
  12     [
  13       AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
  14 ]], [FILE *child;
  15      fclose (stdin);
  16      fclose (stdout);
  17      child = popen ("echo a", "r");
  18      return !(fgetc (child) == 'a' && pclose (child) == 0);
  19 ])], [gl_cv_func_popen_works=yes], [gl_cv_func_popen_works=no],
  20      dnl For now, only cygwin 1.5 or older is known to be broken.
  21      [gl_cv_func_popen_works='guessing yes'])
  22   ])
  23   if test "$gl_cv_func_popen_works" = no; then
  24     REPLACE_POPEN=1
  25     AC_LIBOBJ([popen])
  26     gl_PREREQ_POPEN
  27   fi
  28 ])
  29
  30 # Prerequisites of lib/popen.c.
  31 AC_DEFUN([gl_PREREQ_POPEN],
  32 [
  33   :
  34 ])