m4/prereq.m4

   1 #serial 15
   2
   3 dnl These are the prerequisite macros for files in the lib/
   4 dnl directories of the fileutils, sh-utils, and textutils packages.
   5
   6 AC_DEFUN(jm_PREREQ,
   7 [
   8   jm_PREREQ_ADDEXT
   9   jm_PREREQ_CANON_HOST
  10   jm_PREREQ_DIRNAME
  11   jm_PREREQ_ERROR
  12   jm_PREREQ_GETPAGESIZE
  13   jm_PREREQ_HASH
  14   jm_PREREQ_HUMAN
  15   jm_PREREQ_MBSWIDTH
  16   jm_PREREQ_MEMCHR
  17   jm_PREREQ_QUOTEARG
  18   jm_PREREQ_READUTMP
  19   jm_PREREQ_REGEX
  20 ])
  21
  22 AC_DEFUN(jm_PREREQ_ADDEXT,
  23 [
  24   dnl For addext.c.
  25   AC_SYS_LONG_FILE_NAMES
  26   AC_CHECK_FUNCS(pathconf)
  27   AC_CHECK_HEADERS(limits.h string.h unistd.h)
  28 ])
  29
  30 AC_DEFUN(jm_PREREQ_CANON_HOST,
  31 [
  32   dnl Add any libraries as early as possible.
  33   dnl In particular, inet_ntoa needs -lnsl at least on Solaris5.5.1,
  34   dnl so we have to add -lnsl to LIBS before checking for that function.
  35   AC_SEARCH_LIBS(gethostbyname, [inet nsl])
  36
  37   dnl These come from -lnsl on Solaris5.5.1.
  38   AC_CHECK_FUNCS(gethostbyname gethostbyaddr inet_ntoa)
  39
  40   AC_CHECK_FUNCS(gethostbyname gethostbyaddr inet_ntoa)
  41   AC_CHECK_HEADERS(unistd.h string.h netdb.h sys/socket.h \
  42                    netinet/in.h arpa/inet.h)
  43 ])
  44
  45 AC_DEFUN(jm_PREREQ_DIRNAME,
  46 [
  47   AC_HEADER_STDC
  48   AC_CHECK_HEADERS(string.h)
  49 ])
  50
  51 AC_DEFUN(jm_PREREQ_GETPAGESIZE,
  52 [
  53   AC_CHECK_FUNCS(getpagesize)
  54   AC_CHECK_HEADERS(OS.h unistd.h)
  55 ])
  56
  57 AC_DEFUN(jm_PREREQ_HASH,
  58 [
  59   AC_CHECK_HEADERS(stdlib.h stdbool.h)
  60   AC_REQUIRE([jm_CHECK_DECLS])
  61 ])
  62
  63 # If you use human.c, you need the following files:
  64 # uintmax_t.m4 inttypes_h.m4 ulonglong.m4
  65 AC_DEFUN(jm_PREREQ_HUMAN,
  66 [
  67   AC_CHECK_HEADERS(limits.h stdlib.h string.h)
  68   AC_CHECK_DECLS([getenv])
  69   AC_REQUIRE([jm_AC_HEADER_INTTYPES_H])
  70   AC_REQUIRE([jm_AC_TYPE_UINTMAX_T])
  71 ])
  72
  73 AC_DEFUN(jm_PREREQ_MEMCHR,
  74 [
  75   AC_CHECK_HEADERS(limits.h stdlib.h bp-sym.h)
  76 ])
  77
  78 AC_DEFUN(jm_PREREQ_QUOTEARG,
  79 [
  80   AC_CHECK_FUNCS(isascii iswprint mbrtowc)
  81   AC_CHECK_HEADERS(limits.h stdlib.h string.h wchar.h wctype.h)
  82   AC_HEADER_STDC
  83   AC_C_BACKSLASH_A
  84   AC_MBSTATE_T
  85   AM_C_PROTOTYPES
  86 ])
  87
  88 AC_DEFUN(jm_PREREQ_READUTMP,
  89 [
  90   AC_HEADER_STDC
  91   AC_CHECK_HEADERS(string.h utmp.h utmpx.h sys/param.h)
  92   AC_CHECK_FUNCS(utmpname)
  93   AC_CHECK_FUNCS(utmpxname)
  94   AM_C_PROTOTYPES
  95
  96   if test $ac_cv_header_utmp_h = yes || test $ac_cv_header_utmpx_h = yes; then
  97     utmp_includes="\
  98 $ac_includes_default
  99 #ifdef HAVE_UTMPX_H
 100 # include <utmpx.h>
 101 #endif
 102 #ifdef HAVE_UTMP_H
 103 # include <utmp.h>
 104 #endif
 105 "
 106     AC_CHECK_MEMBERS([struct utmpx.ut_user],,,[$utmp_includes])
 107     AC_CHECK_MEMBERS([struct utmp.ut_user],,,[$utmp_includes])
 108     AC_CHECK_MEMBERS([struct utmpx.ut_name],,,[$utmp_includes])
 109     AC_CHECK_MEMBERS([struct utmp.ut_name],,,[$utmp_includes])
 110     AC_LIBOBJ(readutmp)
 111   fi
 112 ])
 113
 114 AC_DEFUN(jm_PREREQ_REGEX,
 115 [
 116   dnl FIXME: Maybe provide a btowc replacement someday: solaris-2.5.1 lacks it.
 117   dnl FIXME: Check for wctype and iswctype, and and add -lw if necessary
 118   dnl to get them.
 119   AC_CHECK_FUNCS(bzero bcopy isascii btowc)
 120   AC_CHECK_HEADERS(alloca.h libintl.h wctype.h wchar.h)
 121   AC_HEADER_STDC
 122   AC_FUNC_ALLOCA
 123 ])