m4/prereq.m4

   1 #serial 23
   2
   3 dnl These are the prerequisite macros for files in the lib/
   4 dnl directories of the fileutils, sh-utils, and textutils packages.
   5
   6 AC_DEFUN([jm_PREREQ],
   7 [
   8   jm_PREREQ_ADDEXT
   9   jm_PREREQ_CANON_HOST
  10   jm_PREREQ_DIRNAME
  11   jm_PREREQ_ERROR
  12   jm_PREREQ_EXCLUDE
  13   jm_PREREQ_GETPAGESIZE
  14   jm_PREREQ_HASH
  15   jm_PREREQ_HUMAN
  16   jm_PREREQ_MBSWIDTH
  17   jm_PREREQ_MEMCHR
  18   jm_PREREQ_PHYSMEM
  19   jm_PREREQ_POSIXVER
  20   jm_PREREQ_QUOTEARG
  21   jm_PREREQ_READUTMP
  22   jm_PREREQ_REGEX
  23   jm_PREREQ_TEMPNAME # called by mkstemp
  24   jm_PREREQ_XGETCWD
  25   jm_PREREQ_XREADLINK
  26 ])
  27
  28 AC_DEFUN([jm_PREREQ_ADDEXT],
  29 [
  30   dnl For addext.c.
  31   AC_SYS_LONG_FILE_NAMES
  32   AC_CHECK_FUNCS(pathconf)
  33   AC_CHECK_HEADERS(limits.h string.h unistd.h)
  34 ])
  35
  36 AC_DEFUN([jm_PREREQ_CANON_HOST],
  37 [
  38   dnl Add any libraries as early as possible.
  39   dnl In particular, inet_ntoa needs -lnsl at least on Solaris5.5.1,
  40   dnl so we have to add -lnsl to LIBS before checking for that function.
  41   AC_SEARCH_LIBS(gethostbyname, [inet nsl])
  42
  43   dnl These come from -lnsl on Solaris5.5.1.
  44   AC_CHECK_FUNCS(gethostbyname gethostbyaddr inet_ntoa)
  45
  46   AC_CHECK_FUNCS(gethostbyname gethostbyaddr inet_ntoa)
  47   AC_CHECK_HEADERS(unistd.h string.h netdb.h sys/socket.h \
  48                    netinet/in.h arpa/inet.h)
  49 ])
  50
  51 AC_DEFUN([jm_PREREQ_DIRNAME],
  52 [
  53   AC_HEADER_STDC
  54   AC_CHECK_HEADERS(string.h)
  55 ])
  56
  57 AC_DEFUN([jm_PREREQ_EXCLUDE],
  58 [
  59   jm_FUNC_FNMATCH
  60   AC_CHECK_HEADERS(stdbool.h)
  61 ])
  62
  63 AC_DEFUN([jm_PREREQ_GETPAGESIZE],
  64 [
  65   AC_CHECK_FUNCS(getpagesize)
  66   AC_CHECK_HEADERS(OS.h unistd.h)
  67 ])
  68
  69 AC_DEFUN([jm_PREREQ_HASH],
  70 [
  71   AC_CHECK_HEADERS(stdlib.h stdbool.h)
  72   AC_REQUIRE([jm_CHECK_DECLS])
  73 ])
  74
  75 # If you use human.c, you need the following files:
  76 # inttypes.m4 ulonglong.m4
  77 AC_DEFUN([jm_PREREQ_HUMAN],
  78 [
  79   AC_CHECK_HEADERS(limits.h stdlib.h string.h)
  80   AC_CHECK_DECLS([getenv])
  81   AC_REQUIRE([jm_AC_TYPE_UINTMAX_T])
  82 ])
  83
  84 AC_DEFUN([jm_PREREQ_MEMCHR],
  85 [
  86   AC_CHECK_HEADERS(limits.h stdlib.h bp-sym.h)
  87 ])
  88
  89 AC_DEFUN([jm_PREREQ_PHYSMEM],
  90 [
  91   AC_CHECK_HEADERS(sys/pstat.h unistd.h)
  92   AC_CHECK_FUNCS(pstat_getstatic pstat_getdynamic)
  93 ])
  94
  95 AC_DEFUN([jm_PREREQ_POSIXVER],
  96 [
  97   AC_CHECK_HEADERS(unistd.h)
  98   AC_CHECK_DECLS([getenv])
  99 ])
 100
 101 AC_DEFUN([jm_PREREQ_QUOTEARG],
 102 [
 103   AC_CHECK_FUNCS(isascii iswprint)
 104   jm_FUNC_MBRTOWC
 105   AC_CHECK_HEADERS(limits.h stddef.h stdlib.h string.h wchar.h wctype.h)
 106   AC_HEADER_STDC
 107   AC_C_BACKSLASH_A
 108   AC_MBSTATE_T
 109   AM_C_PROTOTYPES
 110 ])
 111
 112 AC_DEFUN([jm_PREREQ_READUTMP],
 113 [
 114   AC_HEADER_STDC
 115   AC_CHECK_HEADERS(string.h utmp.h utmpx.h sys/param.h)
 116   AC_CHECK_FUNCS(utmpname)
 117   AC_CHECK_FUNCS(utmpxname)
 118   AM_C_PROTOTYPES
 119
 120   if test $ac_cv_header_utmp_h = yes || test $ac_cv_header_utmpx_h = yes; then
 121     utmp_includes="\
 122 $ac_includes_default
 123 #ifdef HAVE_UTMPX_H
 124 # include <utmpx.h>
 125 #endif
 126 #ifdef HAVE_UTMP_H
 127 # include <utmp.h>
 128 #endif
 129 "
 130     AC_CHECK_MEMBERS([struct utmpx.ut_user],,,[$utmp_includes])
 131     AC_CHECK_MEMBERS([struct utmp.ut_user],,,[$utmp_includes])
 132     AC_CHECK_MEMBERS([struct utmpx.ut_name],,,[$utmp_includes])
 133     AC_CHECK_MEMBERS([struct utmp.ut_name],,,[$utmp_includes])
 134     AC_CHECK_MEMBERS([struct utmpx.ut_type],,,[$utmp_includes])
 135     AC_CHECK_MEMBERS([struct utmp.ut_type],,,[$utmp_includes])
 136     AC_CHECK_MEMBERS([struct utmpx.ut_pid],,,[$utmp_includes])
 137     AC_CHECK_MEMBERS([struct utmp.ut_pid],,,[$utmp_includes])
 138     AC_CHECK_MEMBERS([struct utmpx.ut_id],,,[$utmp_includes])
 139     AC_CHECK_MEMBERS([struct utmp.ut_id],,,[$utmp_includes])
 140     AC_CHECK_MEMBERS([struct utmpx.ut_exit],,,[$utmp_includes])
 141     AC_CHECK_MEMBERS([struct utmp.ut_exit],,,[$utmp_includes])
 142     AC_LIBOBJ(readutmp)
 143   fi
 144 ])
 145
 146 AC_DEFUN([jm_PREREQ_REGEX],
 147 [
 148   dnl FIXME: Maybe provide a btowc replacement someday: solaris-2.5.1 lacks it.
 149   dnl FIXME: Check for wctype and iswctype, and and add -lw if necessary
 150   dnl to get them.
 151   AC_CHECK_FUNCS(bzero bcopy isascii btowc)
 152   AC_CHECK_HEADERS(alloca.h libintl.h wctype.h wchar.h)
 153   AC_HEADER_STDC
 154   AC_FUNC_ALLOCA
 155 ])
 156
 157 AC_DEFUN([jm_PREREQ_TEMPNAME],
 158 [
 159   AC_HEADER_STDC
 160   AC_HEADER_STAT
 161   AC_CHECK_HEADERS(fcntl.h sys/time.h stdint.h unistd.h)
 162   AC_CHECK_FUNCS(__secure_getenv gettimeofday)
 163   AC_CHECK_DECLS([getenv])
 164 ])
 165
 166 AC_DEFUN([jm_PREREQ_XGETCWD],
 167 [
 168   AC_C_PROTOTYPES
 169   AC_CHECK_HEADERS(limits.h stdlib.h sys/param.h unistd.h)
 170   AC_CHECK_FUNCS(getcwd)
 171   AC_FUNC_GETCWD_NULL
 172 ])
 173
 174 AC_DEFUN([jm_PREREQ_XREADLINK],
 175 [
 176   AC_C_PROTOTYPES
 177   AC_CHECK_HEADERS(limits.h stdlib.h sys/types.h unistd.h)
 178 ])