m4/printf-frexp.m4

   1 # printf-frexp.m4 serial 4
   2 dnl Copyright (C) 2007, 2009-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl Check how to define printf_frexp() without linking with libm.
   8
   9 AC_DEFUN([gl_FUNC_PRINTF_FREXP],
  10 [
  11   AC_REQUIRE([gl_CHECK_FREXP_NO_LIBM])
  12   if test $gl_cv_func_frexp_no_libm = yes; then
  13     gl_FUNC_FREXP_WORKS
  14     case "$gl_cv_func_frexp_works" in
  15       *yes)
  16         AC_DEFINE([HAVE_FREXP_IN_LIBC], [1],
  17           [Define if the frexp function is available in libc.])
  18         ;;
  19     esac
  20   fi
  21
  22   AC_CACHE_CHECK([whether ldexp can be used without linking with libm],
  23     [gl_cv_func_ldexp_no_libm],
  24     [
  25       AC_TRY_LINK([#include <math.h>
  26                    double x;
  27                    int y;],
  28                   [return ldexp (x, y) < 1;],
  29         [gl_cv_func_ldexp_no_libm=yes],
  30         [gl_cv_func_ldexp_no_libm=no])
  31     ])
  32   if test $gl_cv_func_ldexp_no_libm = yes; then
  33     AC_DEFINE([HAVE_LDEXP_IN_LIBC], [1],
  34       [Define if the ldexp function is available in libc.])
  35   fi
  36 ])