m4/progtest.m4

   1 # Search path for a program which passes the given test.
   2 # Ulrich Drepper <drepper@cygnus.com>, 1996.
   3 #
   4 # This file can be copied and used freely without restrictions.  It can
   5 # be used in projects which are not available under the GNU General Public
   6 # License but which still want to provide support for the GNU gettext
   7 # functionality.
   8 # Please note that the actual code of GNU gettext is covered by the GNU
   9 # General Public License and is *not* in the public domain.
  10
  11 # serial 2
  12
  13 dnl AM_PATH_PROG_WITH_TEST(VARIABLE, PROG-TO-CHECK-FOR,
  14 dnl   TEST-PERFORMED-ON-FOUND_PROGRAM [, VALUE-IF-NOT-FOUND [, PATH]])
  15 AC_DEFUN([AM_PATH_PROG_WITH_TEST],
  16 [# Extract the first word of "$2", so it can be a program name with args.
  17 set dummy $2; ac_word=[$]2
  18 AC_MSG_CHECKING([for $ac_word])
  19 AC_CACHE_VAL(ac_cv_path_$1,
  20 [case "[$]$1" in
  21   /*)
  22   ac_cv_path_$1="[$]$1" # Let the user override the test with a path.
  23   ;;
  24   *)
  25   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
  26   for ac_dir in ifelse([$5], , $PATH, [$5]); do
  27     test -z "$ac_dir" && ac_dir=.
  28     if test -f $ac_dir/$ac_word; then
  29       if [$3]; then
  30         ac_cv_path_$1="$ac_dir/$ac_word"
  31         break
  32       fi
  33     fi
  34   done
  35   IFS="$ac_save_ifs"
  36 dnl If no 4th arg is given, leave the cache variable unset,
  37 dnl so AC_PATH_PROGS will keep looking.
  38 ifelse([$4], , , [  test -z "[$]ac_cv_path_$1" && ac_cv_path_$1="$4"
  39 ])dnl
  40   ;;
  41 esac])dnl
  42 $1="$ac_cv_path_$1"
  43 if test ifelse([$4], , [-n "[$]$1"], ["[$]$1" != "$4"]); then
  44   AC_MSG_RESULT([$]$1)
  45 else
  46   AC_MSG_RESULT(no)
  47 fi
  48 AC_SUBST($1)dnl
  49 ])