m4/pthread.m4

   1 # pthread.m4 serial 3
   2 dnl Copyright (C) 2009-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_PTHREAD_CHECK],
   8 [
   9    AC_REQUIRE([gl_PTHREAD_DEFAULTS])
  10    gl_CHECK_NEXT_HEADERS([pthread.h])
  11    if test $ac_cv_header_pthread_h = yes; then
  12      HAVE_PTHREAD_H=1
  13    else
  14      HAVE_PTHREAD_H=0
  15    fi
  16
  17    AC_CHECK_TYPES([pthread_t, pthread_spinlock_t], [], [],
  18      [AC_INCLUDES_DEFAULT[
  19       #if HAVE_PTHREAD_H
  20        #include <pthread.h>
  21       #endif]])
  22    if test $ac_cv_type_pthread_t != yes; then
  23      HAVE_PTHREAD_T=0
  24    fi
  25    if test $ac_cv_type_pthread_spinlock_t != yes; then
  26      HAVE_PTHREAD_SPINLOCK_T=0
  27    fi
  28
  29    if test $ac_cv_header_pthread_h != yes ||
  30       test $ac_cv_type_pthread_t != yes ||
  31       test $ac_cv_type_pthread_spinlock_t != yes; then
  32      PTHREAD_H='pthread.h'
  33    else
  34      PTHREAD_H=
  35    fi
  36    AC_SUBST([PTHREAD_H])
  37    AM_CONDITIONAL([GL_GENERATE_PTHREAD_H], [test -n "$PTHREAD_H"])
  38
  39    LIB_PTHREAD=
  40    if test $ac_cv_header_pthread_h = yes; then
  41      dnl We cannot use AC_SEARCH_LIBS here, because on OSF/1 5.1 pthread_join
  42      dnl is defined as a macro which expands to __phread_join, and libpthread
  43      dnl contains a definition for __phread_join but none for pthread_join.
  44      AC_CACHE_CHECK([for library containing pthread_join],
  45        [gl_cv_search_pthread_join],
  46        [gl_saved_libs="$LIBS"
  47         gl_cv_search_pthread_join=
  48         AC_LINK_IFELSE(
  49           [AC_LANG_PROGRAM(
  50              [[#include <pthread.h>]],
  51              [[pthread_join (pthread_self (), (void **) 0);]])],
  52           [gl_cv_search_pthread_join="none required"])
  53         if test -z "$gl_cv_search_pthread_join"; then
  54           LIBS="-lpthread $gl_saved_libs"
  55           AC_LINK_IFELSE(
  56             [AC_LANG_PROGRAM(
  57                [[#include <pthread.h>]],
  58                [[pthread_join (pthread_self (), (void **) 0);]])],
  59             [gl_cv_search_pthread_join="-lpthread"])
  60         fi
  61         LIBS="$gl_saved_libs"
  62        ])
  63      if test "$gl_cv_search_pthread_join" != "none required"; then
  64        LIB_PTHREAD="$gl_cv_search_pthread_join"
  65      fi
  66    fi
  67    AC_SUBST([LIB_PTHREAD])
  68
  69    AC_REQUIRE([AC_C_INLINE])
  70    AC_REQUIRE([AC_C_RESTRICT])
  71 ])
  72
  73 AC_DEFUN([gl_PTHREAD_DEFAULTS],
  74 [
  75   dnl Assume proper GNU behavior unless another module says otherwise.
  76   HAVE_PTHREAD_H=1;              AC_SUBST([HAVE_PTHREAD_H])
  77   HAVE_PTHREAD_T=1;              AC_SUBST([HAVE_PTHREAD_T])
  78   HAVE_PTHREAD_SPINLOCK_T=1;     AC_SUBST([HAVE_PTHREAD_SPINLOCK_T])
  79 ])