m4/pthread.m4

   1 # pthread.m4 serial 5
   2 dnl Copyright (C) 2009-2012 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_PTHREAD_CHECK],
   8 [
   9    AC_REQUIRE([gl_PTHREAD_DEFAULTS])
  10    gl_CHECK_NEXT_HEADERS([pthread.h])
  11    if test $ac_cv_header_pthread_h = yes; then
  12      HAVE_PTHREAD_H=1
  13    else
  14      HAVE_PTHREAD_H=0
  15    fi
  16
  17    AC_CHECK_TYPES([pthread_t, pthread_spinlock_t], [], [],
  18      [AC_INCLUDES_DEFAULT[
  19       #if HAVE_PTHREAD_H
  20        #include <pthread.h>
  21       #endif]])
  22    if test $ac_cv_type_pthread_t != yes; then
  23      HAVE_PTHREAD_T=0
  24    fi
  25    if test $ac_cv_type_pthread_spinlock_t != yes; then
  26      HAVE_PTHREAD_SPINLOCK_T=0
  27    fi
  28
  29    if test $ac_cv_header_pthread_h != yes ||
  30       test $ac_cv_type_pthread_t != yes ||
  31       test $ac_cv_type_pthread_spinlock_t != yes; then
  32      PTHREAD_H='pthread.h'
  33    else
  34      PTHREAD_H=
  35    fi
  36    AC_SUBST([PTHREAD_H])
  37    AM_CONDITIONAL([GL_GENERATE_PTHREAD_H], [test -n "$PTHREAD_H"])
  38
  39    LIB_PTHREAD=
  40    if test $ac_cv_header_pthread_h = yes; then
  41      dnl We cannot use AC_SEARCH_LIBS here, because on OSF/1 5.1 pthread_join
  42      dnl is defined as a macro which expands to __phread_join, and libpthread
  43      dnl contains a definition for __phread_join but none for pthread_join.
  44      dnl Also, FreeBSD 9 puts pthread_create in libpthread and pthread_join
  45      dnl in libc, whereas on IRIX 6.5 the reverse is true; so check for both.
  46      AC_CACHE_CHECK([for library containing pthread_create and pthread_join],
  47        [gl_cv_lib_pthread],
  48        [gl_saved_libs=$LIBS
  49         gl_cv_lib_pthread=
  50         for gl_lib_prefix in '' '-lpthread'; do
  51           LIBS="$gl_lib_prefix $gl_saved_libs"
  52           AC_LINK_IFELSE(
  53             [AC_LANG_PROGRAM(
  54                [[#include <pthread.h>
  55                  void *noop (void *p) { return p; }]],
  56                [[pthread_t pt;
  57                  void *arg = 0;
  58                  pthread_create (&pt, 0, noop, arg);
  59                  pthread_join (pthread_self (), &arg);]])],
  60             [if test -z "$gl_lib_prefix"; then
  61                gl_cv_lib_pthread="none required"
  62              else
  63                gl_cv_lib_pthread=$gl_lib_prefix
  64              fi])
  65           test -n "$gl_cv_lib_pthread" && break
  66         done
  67         LIBS="$gl_saved_libs"
  68        ])
  69      if test "$gl_cv_lib_pthread" != "none required"; then
  70        LIB_PTHREAD="$gl_cv_lib_pthread"
  71      fi
  72    fi
  73    AC_SUBST([LIB_PTHREAD])
  74
  75    AC_REQUIRE([AC_C_INLINE])
  76    AC_REQUIRE([AC_C_RESTRICT])
  77 ])
  78
  79 AC_DEFUN([gl_PTHREAD_DEFAULTS],
  80 [
  81   dnl Assume proper GNU behavior unless another module says otherwise.
  82   HAVE_PTHREAD_H=1;              AC_SUBST([HAVE_PTHREAD_H])
  83   HAVE_PTHREAD_T=1;              AC_SUBST([HAVE_PTHREAD_T])
  84   HAVE_PTHREAD_SPINLOCK_T=1;     AC_SUBST([HAVE_PTHREAD_SPINLOCK_T])
  85 ])