m4/readline.m4

   1 # readline.m4 serial 2
   2 dnl Copyright (C) 2005 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl Written by Simon Josefsson, with help from Bruno Haible and Oskar
   8 dnl Liljeblad.
   9
  10 AC_DEFUN([gl_FUNC_READLINE],
  11 [
  12   AC_LIBSOURCES([readline.c, readline.h])
  13
  14   dnl Prerequisites of AC_LIB_LINKFLAGS_BODY.
  15   AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
  16   AC_REQUIRE([AC_LIB_RPATH])
  17
  18   dnl Search for libreadline and define LIBREADLINE, LTLIBREADLINE and
  19   dnl INCREADLINE accordingly.
  20   AC_LIB_LINKFLAGS_BODY([readline])
  21
  22   dnl Add $INCREADLINE to CPPFLAGS before performing the following checks,
  23   dnl because if the user has installed libreadline and not disabled its use
  24   dnl via --without-libreadline-prefix, he wants to use it. The AC_TRY_LINK
  25   dnl will then succeed.
  26   am_save_CPPFLAGS="$CPPFLAGS"
  27   AC_LIB_APPENDTOVAR([CPPFLAGS], [$INCREADLINE])
  28
  29   AC_CACHE_CHECK(for readline, gl_cv_lib_readline, [
  30     gl_cv_lib_readline=no
  31     am_save_LIBS="$LIBS"
  32     for extra_lib in "" termcap curses ncurses; do
  33       LIBS="$am_save_LIBS $LIBREADLINE"
  34       if test -n "$extra_lib"; then
  35         LIBS="$LIBS -l$extra_lib"
  36       fi
  37       AC_TRY_LINK([#include <stdio.h>
  38 #include <readline/readline.h>],
  39         [readline((char*)0);],
  40         gl_cv_lib_readline=yes)
  41       if test "$gl_cv_lib_readline" = yes; then
  42         if test -n "$extra_lib"; then
  43           LIBREADLINE="$LIBREADLINE -l$extra_lib"
  44           LTLIBREADLINE="$LTLIBREADLINE -l$extra_lib"
  45         fi
  46         break
  47       fi
  48     done
  49     LIBS="$am_save_LIBS"
  50   ])
  51
  52   if test "$gl_cv_lib_readline" = yes; then
  53     AC_DEFINE(HAVE_READLINE, 1, [Define if you have the readline library.])
  54   fi
  55
  56   if test "$gl_cv_lib_readline" = yes; then
  57     AC_MSG_CHECKING([how to link with libreadline])
  58     AC_MSG_RESULT([$LIBREADLINE])
  59   else
  60     dnl If $LIBREADLINE didn't lead to a usable library, we don't
  61     dnl need $INCREADLINE either.
  62     CPPFLAGS="$am_save_CPPFLAGS"
  63     LIBREADLINE=
  64     LTLIBREADLINE=
  65   fi
  66   AC_SUBST(LIBREADLINE)
  67   AC_SUBST(LTLIBREADLINE)
  68
  69   AC_CHECK_HEADERS(readline/readline.h)
  70
  71   if test $gl_cv_lib_readline = no; then
  72     AC_LIBOBJ(readline)
  73     gl_PREREQ_READLINE
  74   fi
  75 ])
  76
  77 # Prerequisites of lib/readline.c.
  78 AC_DEFUN([gl_PREREQ_READLINE], [
  79   :
  80 ])