m4/regex.m4

   1 # serial 57
   2
   3 # Copyright (C) 1996-2001, 2003-2011 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; the Free Software Foundation
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 dnl Initially derived from code in GNU grep.
  10 dnl Mostly written by Jim Meyering.
  11
  12 AC_PREREQ([2.50])
  13
  14 AC_DEFUN([gl_REGEX],
  15 [
  16   AC_CHECK_HEADERS_ONCE([locale.h])
  17
  18   AC_ARG_WITH([included-regex],
  19     [AS_HELP_STRING([--without-included-regex],
  20                     [don't compile regex; this is the default on systems
  21                      with recent-enough versions of the GNU C Library
  22                      (use with caution on other systems).])])
  23
  24   case $with_included_regex in #(
  25   yes|no) ac_use_included_regex=$with_included_regex
  26         ;;
  27   '')
  28     # If the system regex support is good enough that it passes the
  29     # following run test, then default to *not* using the included regex.c.
  30     # If cross compiling, assume the test would fail and use the included
  31     # regex.c.
  32     AC_CACHE_CHECK([for working re_compile_pattern],
  33                    [gl_cv_func_re_compile_pattern_working],
  34       [AC_RUN_IFELSE(
  35         [AC_LANG_PROGRAM(
  36           [AC_INCLUDES_DEFAULT[
  37            #if HAVE_LOCALE_H
  38             #include <locale.h>
  39            #endif
  40            #include <limits.h>
  41            #include <regex.h>
  42            ]],
  43           [[int result = 0;
  44             static struct re_pattern_buffer regex;
  45             unsigned char folded_chars[UCHAR_MAX + 1];
  46             int i;
  47             const char *s;
  48             struct re_registers regs;
  49
  50             #if HAVE_LOCALE_H
  51               /* http://sourceware.org/ml/libc-hacker/2006-09/msg00008.html
  52                  This test needs valgrind to catch the bug on Debian
  53                  GNU/Linux 3.1 x86, but it might catch the bug better
  54                  on other platforms and it shouldn't hurt to try the
  55                  test here.  */
  56               if (setlocale (LC_ALL, "en_US.UTF-8"))
  57                 {
  58                   static char const pat[] = "insert into";
  59                   static char const data[] =
  60                     "\xFF\0\x12\xA2\xAA\xC4\xB1,K\x12\xC4\xB1*\xACK";
  61                   re_set_syntax (RE_SYNTAX_GREP | RE_HAT_LISTS_NOT_NEWLINE
  62                                  | RE_ICASE);
  63                   memset (&regex, 0, sizeof regex);
  64                   s = re_compile_pattern (pat, sizeof pat - 1, &regex);
  65                   if (s)
  66                     result |= 1;
  67                   else if (re_search (&regex, data, sizeof data - 1,
  68                                       0, sizeof data - 1, &regs)
  69                            != -1)
  70                     result |= 1;
  71                   if (! setlocale (LC_ALL, "C"))
  72                     return 1;
  73                 }
  74             #endif
  75
  76             /* This test is from glibc bug 3957, reported by Andrew Mackey.  */
  77             re_set_syntax (RE_SYNTAX_EGREP | RE_HAT_LISTS_NOT_NEWLINE);
  78             memset (&regex, 0, sizeof regex);
  79             s = re_compile_pattern ("a[^x]b", 6, &regex);
  80             if (s)
  81               result |= 2;
  82             /* This should fail, but succeeds for glibc-2.5.  */
  83             else if (re_search (&regex, "a\nb", 3, 0, 3, &regs) != -1)
  84               result |= 2;
  85
  86             /* This regular expression is from Spencer ere test number 75
  87                in grep-2.3.  */
  88             re_set_syntax (RE_SYNTAX_POSIX_EGREP);
  89             memset (&regex, 0, sizeof regex);
  90             for (i = 0; i <= UCHAR_MAX; i++)
  91               folded_chars[i] = i;
  92             regex.translate = folded_chars;
  93             s = re_compile_pattern ("a[[:@:>@:]]b\n", 11, &regex);
  94             /* This should fail with _Invalid character class name_ error.  */
  95             if (!s)
  96               result |= 4;
  97
  98             /* Ensure that [b-a] is diagnosed as invalid, when
  99                using RE_NO_EMPTY_RANGES. */
 100             re_set_syntax (RE_SYNTAX_POSIX_EGREP | RE_NO_EMPTY_RANGES);
 101             memset (&regex, 0, sizeof regex);
 102             s = re_compile_pattern ("a[b-a]", 6, &regex);
 103             if (s == 0)
 104               result |= 8;
 105
 106             /* This should succeed, but does not for glibc-2.1.3.  */
 107             memset (&regex, 0, sizeof regex);
 108             s = re_compile_pattern ("{1", 2, &regex);
 109             if (s)
 110               result |= 8;
 111
 112             /* The following example is derived from a problem report
 113                against gawk from Jorge Stolfi <stolfi@ic.unicamp.br>.  */
 114             memset (&regex, 0, sizeof regex);
 115             s = re_compile_pattern ("[an\371]*n", 7, &regex);
 116             if (s)
 117               result |= 8;
 118             /* This should match, but does not for glibc-2.2.1.  */
 119             else if (re_match (&regex, "an", 2, 0, &regs) != 2)
 120               result |= 8;
 121
 122             memset (&regex, 0, sizeof regex);
 123             s = re_compile_pattern ("x", 1, &regex);
 124             if (s)
 125               result |= 8;
 126             /* glibc-2.2.93 does not work with a negative RANGE argument.  */
 127             else if (re_search (&regex, "wxy", 3, 2, -2, &regs) != 1)
 128               result |= 8;
 129
 130             /* The version of regex.c in older versions of gnulib
 131                ignored RE_ICASE.  Detect that problem too.  */
 132             re_set_syntax (RE_SYNTAX_EMACS | RE_ICASE);
 133             memset (&regex, 0, sizeof regex);
 134             s = re_compile_pattern ("x", 1, &regex);
 135             if (s)
 136               result |= 16;
 137             else if (re_search (&regex, "WXY", 3, 0, 3, &regs) < 0)
 138               result |= 16;
 139
 140             /* Catch a bug reported by Vin Shelton in
 141                http://lists.gnu.org/archive/html/bug-coreutils/2007-06/msg00089.html
 142                */
 143             re_set_syntax (RE_SYNTAX_POSIX_BASIC
 144                            & ~RE_CONTEXT_INVALID_DUP
 145                            & ~RE_NO_EMPTY_RANGES);
 146             memset (&regex, 0, sizeof regex);
 147             s = re_compile_pattern ("[[:alnum:]_-]\\\\+$", 16, &regex);
 148             if (s)
 149               result |= 32;
 150
 151             /* REG_STARTEND was added to glibc on 2004-01-15.
 152                Reject older versions.  */
 153             if (! REG_STARTEND)
 154               result |= 64;
 155
 156 #if 0
 157             /* It would be nice to reject hosts whose regoff_t values are too
 158                narrow (including glibc on hosts with 64-bit ptrdiff_t and
 159                32-bit int), but we should wait until glibc implements this
 160                feature.  Otherwise, support for equivalence classes and
 161                multibyte collation symbols would always be broken except
 162                when compiling --without-included-regex.   */
 163             if (sizeof (regoff_t) < sizeof (ptrdiff_t)
 164                 || sizeof (regoff_t) < sizeof (ssize_t))
 165               result |= 64;
 166 #endif
 167
 168             return result;
 169           ]])],
 170        [gl_cv_func_re_compile_pattern_working=yes],
 171        [gl_cv_func_re_compile_pattern_working=no],
 172        dnl When crosscompiling, assume it is not working.
 173        [gl_cv_func_re_compile_pattern_working=no])])
 174     case $gl_cv_func_re_compile_pattern_working in #(
 175     yes) ac_use_included_regex=no;; #(
 176     no) ac_use_included_regex=yes;;
 177     esac
 178     ;;
 179   *) AC_MSG_ERROR([Invalid value for --with-included-regex: $with_included_regex])
 180     ;;
 181   esac
 182
 183   if test $ac_use_included_regex = yes; then
 184     AC_DEFINE([_REGEX_LARGE_OFFSETS], [1],
 185       [Define if you want regoff_t to be at least as wide POSIX requires.])
 186     AC_DEFINE([re_syntax_options], [rpl_re_syntax_options],
 187       [Define to rpl_re_syntax_options if the replacement should be used.])
 188     AC_DEFINE([re_set_syntax], [rpl_re_set_syntax],
 189       [Define to rpl_re_set_syntax if the replacement should be used.])
 190     AC_DEFINE([re_compile_pattern], [rpl_re_compile_pattern],
 191       [Define to rpl_re_compile_pattern if the replacement should be used.])
 192     AC_DEFINE([re_compile_fastmap], [rpl_re_compile_fastmap],
 193       [Define to rpl_re_compile_fastmap if the replacement should be used.])
 194     AC_DEFINE([re_search], [rpl_re_search],
 195       [Define to rpl_re_search if the replacement should be used.])
 196     AC_DEFINE([re_search_2], [rpl_re_search_2],
 197       [Define to rpl_re_search_2 if the replacement should be used.])
 198     AC_DEFINE([re_match], [rpl_re_match],
 199       [Define to rpl_re_match if the replacement should be used.])
 200     AC_DEFINE([re_match_2], [rpl_re_match_2],
 201       [Define to rpl_re_match_2 if the replacement should be used.])
 202     AC_DEFINE([re_set_registers], [rpl_re_set_registers],
 203       [Define to rpl_re_set_registers if the replacement should be used.])
 204     AC_DEFINE([re_comp], [rpl_re_comp],
 205       [Define to rpl_re_comp if the replacement should be used.])
 206     AC_DEFINE([re_exec], [rpl_re_exec],
 207       [Define to rpl_re_exec if the replacement should be used.])
 208     AC_DEFINE([regcomp], [rpl_regcomp],
 209       [Define to rpl_regcomp if the replacement should be used.])
 210     AC_DEFINE([regexec], [rpl_regexec],
 211       [Define to rpl_regexec if the replacement should be used.])
 212     AC_DEFINE([regerror], [rpl_regerror],
 213       [Define to rpl_regerror if the replacement should be used.])
 214     AC_DEFINE([regfree], [rpl_regfree],
 215       [Define to rpl_regfree if the replacement should be used.])
 216     AC_LIBOBJ([regex])
 217     gl_PREREQ_REGEX
 218   fi
 219 ])
 220
 221 # Prerequisites of lib/regex.c and lib/regex_internal.c.
 222 AC_DEFUN([gl_PREREQ_REGEX],
 223 [
 224   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
 225   AC_REQUIRE([AC_C_INLINE])
 226   AC_REQUIRE([AC_C_RESTRICT])
 227   AC_REQUIRE([AC_TYPE_MBSTATE_T])
 228   AC_CHECK_HEADERS([libintl.h])
 229   AC_CHECK_FUNCS_ONCE([isblank iswctype wcscoll])
 230   AC_CHECK_DECLS([isblank], [], [], [#include <ctype.h>])
 231 ])