m4/relocatable.m4

   1 # relocatable.m4 serial 9
   2 dnl Copyright (C) 2003, 2005-2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Bruno Haible.
   8
   9 dnl gl_RELOCATABLE([RELOCWRAPPER-DIR])
  10 dnl ----------------------------------------------------------
  11 dnl Support for relocatable programs.
  12 dnl Supply RELOCWRAPPER-DIR as the directory where relocwrapper.c may be found.
  13 AC_DEFUN([gl_RELOCATABLE],
  14 [
  15   AC_REQUIRE([gl_RELOCATABLE_BODY])
  16   if test $RELOCATABLE = yes; then
  17     AC_LIBOBJ([relocatable])
  18   fi
  19   : ${RELOCATABLE_CONFIG_H_DIR='$(top_builddir)'}
  20   RELOCATABLE_SRC_DIR="\$(top_srcdir)/$gl_source_base"
  21   RELOCATABLE_BUILD_DIR="\$(top_builddir)/$gl_source_base"
  22 ])
  23 dnl The guts of gl_RELOCATABLE. Needs to be expanded only once.
  24 AC_DEFUN([gl_RELOCATABLE_BODY],
  25 [
  26   AC_REQUIRE([AC_PROG_INSTALL])
  27   dnl This AC_BEFORE invocation leads to unjustified autoconf warnings
  28   dnl when gl_RELOCATABLE_BODY is invoked more than once.
  29   dnl We need this AC_BEFORE because AC_PROG_INSTALL is documented to
  30   dnl overwrite earlier settings of INSTALL and INSTALL_PROGRAM (even
  31   dnl though in autoconf-2.52..2.60 it doesn't do so), but we want this
  32   dnl macro's setting of INSTALL_PROGRAM to persist.
  33   AC_BEFORE([AC_PROG_INSTALL],[gl_RELOCATABLE_BODY])
  34   AC_REQUIRE([AC_LIB_LIBPATH])
  35   AC_REQUIRE([gl_RELOCATABLE_LIBRARY])
  36   is_noop=no
  37   use_elf_origin_trick=no
  38   if test $RELOCATABLE = yes; then
  39     # --enable-relocatable implies --disable-rpath
  40     enable_rpath=no
  41     AC_CHECK_HEADERS([mach-o/dyld.h])
  42     AC_CHECK_FUNCS([_NSGetExecutablePath])
  43     case "$host_os" in
  44       mingw*) is_noop=yes ;;
  45       linux*) use_elf_origin_trick=yes ;;
  46     esac
  47     if test $is_noop = yes; then
  48       RELOCATABLE_LDFLAGS=:
  49       AC_SUBST([RELOCATABLE_LDFLAGS])
  50     else
  51       if test $use_elf_origin_trick = yes; then
  52         dnl Use the dynamic linker's support for relocatable programs.
  53         case "$ac_aux_dir" in
  54           /*) reloc_ldflags="$ac_aux_dir/reloc-ldflags" ;;
  55           *) reloc_ldflags="\$(top_builddir)/$ac_aux_dir/reloc-ldflags" ;;
  56         esac
  57         RELOCATABLE_LDFLAGS="\"$reloc_ldflags\" \"\$(host)\" \"\$(RELOCATABLE_LIBRARY_PATH)\""
  58         AC_SUBST([RELOCATABLE_LDFLAGS])
  59       else
  60         dnl Unfortunately we cannot define INSTALL_PROGRAM to a command
  61         dnl consisting of more than one word - libtool doesn't support this.
  62         dnl So we abuse the INSTALL_PROGRAM_ENV hook, originally meant for the
  63         dnl 'install-strip' target.
  64         INSTALL_PROGRAM_ENV="RELOC_LIBRARY_PATH_VAR=\"$shlibpath_var\" RELOC_LIBRARY_PATH_VALUE=\"\$(RELOCATABLE_LIBRARY_PATH)\" RELOC_PREFIX=\"\$(prefix)\" RELOC_COMPILE_COMMAND=\"\$(CC) \$(CPPFLAGS) \$(CFLAGS) \$(LDFLAGS)\" RELOC_SRCDIR=\"\$(RELOCATABLE_SRC_DIR)\" RELOC_BUILDDIR=\"\$(RELOCATABLE_BUILD_DIR)\" RELOC_CONFIG_H_DIR=\"\$(RELOCATABLE_CONFIG_H_DIR)\" RELOC_EXEEXT=\"\$(EXEEXT)\" RELOC_INSTALL_PROG=\"$INSTALL_PROGRAM\""
  65         AC_SUBST([INSTALL_PROGRAM_ENV])
  66         case "$ac_aux_dir" in
  67           /*) INSTALL_PROGRAM="$ac_aux_dir/install-reloc" ;;
  68           *) INSTALL_PROGRAM="\$(top_builddir)/$ac_aux_dir/install-reloc" ;;
  69         esac
  70       fi
  71     fi
  72   fi
  73   AM_CONDITIONAL([RELOCATABLE_VIA_LD],
  74     [test $is_noop = yes || test $use_elf_origin_trick = yes])
  75
  76   dnl RELOCATABLE_LIBRARY_PATH can be set in configure.ac. Default is empty.
  77   AC_SUBST([RELOCATABLE_LIBRARY_PATH])
  78   AC_SUBST([RELOCATABLE_CONFIG_H_DIR])
  79   AC_SUBST([RELOCATABLE_SRC_DIR])
  80   AC_SUBST([RELOCATABLE_BUILD_DIR])
  81 ])
  82
  83 dnl Determine the platform dependent parameters needed to use relocatability:
  84 dnl shlibpath_var.
  85 AC_DEFUN([AC_LIB_LIBPATH],
  86 [
  87   AC_REQUIRE([AC_LIB_PROG_LD])            dnl we use $LD
  88   AC_REQUIRE([AC_CANONICAL_HOST])         dnl we use $host
  89   AC_REQUIRE([AC_CONFIG_AUX_DIR_DEFAULT]) dnl we use $ac_aux_dir
  90   AC_CACHE_CHECK([for shared library path variable], acl_cv_libpath, [
  91     LD="$LD" \
  92     ${CONFIG_SHELL-/bin/sh} "$ac_aux_dir/config.libpath" "$host" > conftest.sh
  93     . ./conftest.sh
  94     rm -f ./conftest.sh
  95     acl_cv_libpath=${acl_cv_shlibpath_var:-none}
  96   ])
  97   shlibpath_var="$acl_cv_shlibpath_var"
  98 ])