m4/remainderl.m4

   1 # remainderl.m4 serial 1
   2 dnl Copyright (C) 2012 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_REMAINDERL],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
  11   AC_REQUIRE([gl_FUNC_REMAINDER])
  12
  13   dnl Test whether remainderl() exists. Assume that remainderl(), if it exists, is
  14   dnl defined in the same library as remainder().
  15   save_LIBS="$LIBS"
  16   LIBS="$LIBS $REMAINDER_LIBM"
  17   AC_CACHE_CHECK([for remainderl],
  18     [gl_cv_func_remainderl],
  19     [
  20       AC_LINK_IFELSE(
  21         [AC_LANG_PROGRAM(
  22            [[#ifndef __NO_MATH_INLINES
  23              # define __NO_MATH_INLINES 1 /* for glibc */
  24              #endif
  25              #include <math.h>
  26              long double (*funcptr) (long double, long double) = remainderl;
  27              long double x;
  28              long double y;]],
  29            [[return funcptr (x, y) > 1
  30                     || remainderl (x, y) > 1;]])],
  31         [gl_cv_func_remainderl=yes],
  32         [gl_cv_func_remainderl=no])
  33     ])
  34   LIBS="$save_LIBS"
  35   if test $gl_cv_func_remainderl = yes; then
  36     REMAINDERL_LIBM="$REMAINDER_LIBM"
  37   else
  38     HAVE_REMAINDERL=0
  39     dnl Find libraries needed to link lib/remainderl.c.
  40     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
  41       REMAINDERL_LIBM="$REMAINDER_LIBM"
  42     else
  43       AC_REQUIRE([gl_FUNC_ROUNDL])
  44       AC_REQUIRE([gl_FUNC_FMAL])
  45       REMAINDERL_LIBM=
  46       dnl Append $ROUNDL_LIBM to REMAINDERL_LIBM, avoiding gratuitous duplicates.
  47       case " $REMAINDERL_LIBM " in
  48         *" $ROUNDL_LIBM "*) ;;
  49         *) REMAINDERL_LIBM="$REMAINDERL_LIBM $ROUNDL_LIBM" ;;
  50       esac
  51       dnl Append $FMAL_LIBM to REMAINDERL_LIBM, avoiding gratuitous duplicates.
  52       case " $REMAINDERL_LIBM " in
  53         *" $FMAL_LIBM "*) ;;
  54         *) REMAINDERL_LIBM="$REMAINDERL_LIBM $FMAL_LIBM" ;;
  55       esac
  56     fi
  57   fi
  58   AC_SUBST([REMAINDERL_LIBM])
  59 ])