m4/remove.m4

   1 # remove.m4 serial 3
   2 dnl Copyright (C) 2009-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_REMOVE],
   8 [
   9   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  10   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  11   AC_REQUIRE([gl_FUNC_RMDIR])
  12   AC_REQUIRE([gl_FUNC_UNLINK])
  13   if test "$gl_cv_func_rmdir_works:$gl_cv_func_unlink_works" != yes:yes; then
  14     dnl If either underlying syscall is broken, then remove likely has
  15     dnl the same bug; blindly use our replacement.
  16     REPLACE_REMOVE=1
  17   else
  18     dnl C89 requires remove(), but only POSIX requires it to handle
  19     dnl directories.  On mingw, directories fails with EPERM.
  20     AC_CACHE_CHECK([whether remove handles directories],
  21       [gl_cv_func_remove_dir_works],
  22       [mkdir conftest.dir
  23        AC_RUN_IFELSE(
  24          [AC_LANG_PROGRAM(
  25            [[#include <stdio.h>
  26 ]], [[return remove ("conftest.dir");]])],
  27          [gl_cv_func_remove_dir_works=yes], [gl_cv_func_remove_dir_works=no],
  28          [case $host_os in
  29             mingw*) gl_cv_func_remove_dir_works="guessing no";;
  30             *) gl_cv_func_remove_dir_works="guessing yes";;
  31           esac])
  32        rm -rf conftest.dir])
  33     case $gl_cv_func_remove_dir_works in
  34       *no*) REPLACE_REMOVE=1;;
  35     esac
  36   fi
  37 ])