m4/rmdir.m4

   1 # rmdir.m4 serial 9
   2 dnl Copyright (C) 2002, 2005, 2009-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_RMDIR],
   8 [
   9   AC_REQUIRE([gl_AC_DOS])
  10   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  11   dnl Detect cygwin 1.5.x bug.
  12   AC_CACHE_CHECK([whether rmdir works], [gl_cv_func_rmdir_works],
  13     [mkdir conftest.dir
  14      touch conftest.file
  15      AC_RUN_IFELSE(
  16        [AC_LANG_PROGRAM(
  17          [[#include <stdio.h>
  18            #include <errno.h>
  19            #include <unistd.h>
  20 ]], [[int result = 0;
  21       if (!rmdir ("conftest.file/"))
  22         result |= 1;
  23       else if (errno != ENOTDIR)
  24         result |= 2;
  25       if (!rmdir ("conftest.dir/./"))
  26         result |= 4;
  27       return result;
  28     ]])],
  29        [gl_cv_func_rmdir_works=yes], [gl_cv_func_rmdir_works=no],
  30        [gl_cv_func_rmdir_works="guessing no"])
  31      rm -rf conftest.dir conftest.file])
  32   if test x"$gl_cv_func_rmdir_works" != xyes; then
  33     REPLACE_RMDIR=1
  34     AC_LIBOBJ([rmdir])
  35   fi
  36 ])