m4/round.m4

   1 # round.m4 serial 12
   2 dnl Copyright (C) 2007, 2009-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_ROUND],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_round_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   dnl Persuade glibc <math.h> to declare round().
  12   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  13   AC_CHECK_DECLS([round], , , [#include <math.h>])
  14   if test "$ac_cv_have_decl_round" = yes; then
  15     gl_CHECK_MATH_LIB([ROUND_LIBM], [x = round (x);])
  16     if test "$ROUND_LIBM" != missing; then
  17       dnl Test whether round() produces correct results. On NetBSD 3.0, for
  18       dnl x = 1/2 - 2^-54, the system's round() returns a wrong result.
  19       AC_REQUIRE([AC_PROG_CC])
  20       AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  21       AC_CACHE_CHECK([whether round works], [gl_cv_func_round_works],
  22         [
  23           save_LIBS="$LIBS"
  24           LIBS="$LIBS $ROUND_LIBM"
  25           AC_RUN_IFELSE([AC_LANG_SOURCE([[
  26 #include <float.h>
  27 #include <math.h>
  28 int main()
  29 {
  30   /* 2^DBL_MANT_DIG.  */
  31   static const double TWO_MANT_DIG =
  32     /* Assume DBL_MANT_DIG <= 5 * 31.
  33        Use the identity
  34        n = floor(n/5) + floor((n+1)/5) + ... + floor((n+4)/5).  */
  35     (double) (1U << (DBL_MANT_DIG / 5))
  36     * (double) (1U << ((DBL_MANT_DIG + 1) / 5))
  37     * (double) (1U << ((DBL_MANT_DIG + 2) / 5))
  38     * (double) (1U << ((DBL_MANT_DIG + 3) / 5))
  39     * (double) (1U << ((DBL_MANT_DIG + 4) / 5));
  40   volatile double x = 0.5 - 0.5 / TWO_MANT_DIG;
  41   exit (x < 0.5 && round (x) != 0.0);
  42 }]])], [gl_cv_func_round_works=yes], [gl_cv_func_round_works=no],
  43           [case "$host_os" in
  44              netbsd* | aix*) gl_cv_func_round_works="guessing no";;
  45              *)              gl_cv_func_round_works="guessing yes";;
  46            esac
  47           ])
  48           LIBS="$save_LIBS"
  49         ])
  50       case "$gl_cv_func_round_works" in
  51         *no) ROUND_LIBM=missing ;;
  52       esac
  53     fi
  54     if test "$ROUND_LIBM" = missing; then
  55       REPLACE_ROUND=1
  56     fi
  57     m4_ifdef([gl_FUNC_ROUND_IEEE], [
  58       if test $gl_round_required = ieee && test $REPLACE_ROUND = 0; then
  59         AC_CACHE_CHECK([whether round works according to ISO C 99 with IEC 60559],
  60           [gl_cv_func_round_ieee],
  61           [
  62             save_LIBS="$LIBS"
  63             LIBS="$LIBS $ROUND_LIBM"
  64             AC_RUN_IFELSE(
  65               [AC_LANG_SOURCE([[
  66 #ifndef __NO_MATH_INLINES
  67 # define __NO_MATH_INLINES 1 /* for glibc */
  68 #endif
  69 #include <math.h>
  70 ]gl_DOUBLE_MINUS_ZERO_CODE[
  71 ]gl_DOUBLE_SIGNBIT_CODE[
  72 static double dummy (double f) { return 0; }
  73 int main (int argc, char *argv[])
  74 {
  75   double (*my_round) (double) = argc ? round : dummy;
  76   /* Test whether round (-0.0) is -0.0.  */
  77   if (signbitd (minus_zerod) && !signbitd (my_round (minus_zerod)))
  78     return 1;
  79   return 0;
  80 }
  81               ]])],
  82               [gl_cv_func_round_ieee=yes],
  83               [gl_cv_func_round_ieee=no],
  84               [gl_cv_func_round_ieee="guessing no"])
  85             LIBS="$save_LIBS"
  86           ])
  87         case "$gl_cv_func_round_ieee" in
  88           *yes) ;;
  89           *) REPLACE_ROUND=1 ;;
  90         esac
  91       fi
  92     ])
  93   else
  94     HAVE_DECL_ROUND=0
  95   fi
  96   if test $HAVE_DECL_ROUND = 0 || test $REPLACE_ROUND = 1; then
  97     dnl Find libraries needed to link lib/round.c.
  98     gl_FUNC_FLOOR_LIBS
  99     gl_FUNC_CEIL_LIBS
 100     ROUND_LIBM=
 101     dnl Append $FLOOR_LIBM to ROUND_LIBM, avoiding gratuitous duplicates.
 102     case " $ROUND_LIBM " in
 103       *" $FLOOR_LIBM "*) ;;
 104       *) ROUND_LIBM="$ROUND_LIBM $FLOOR_LIBM" ;;
 105     esac
 106     dnl Append $CEIL_LIBM to ROUND_LIBM, avoiding gratuitous duplicates.
 107     case " $ROUND_LIBM " in
 108       *" $CEIL_LIBM "*) ;;
 109       *) ROUND_LIBM="$ROUND_LIBM $CEIL_LIBM" ;;
 110     esac
 111   fi
 112   AC_SUBST([ROUND_LIBM])
 113 ])