m4/roundf.m4

   1 # roundf.m4 serial 2
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_ROUNDF],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   dnl Persuade glibc <math.h> to declare roundf().
  11   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  12   AC_CHECK_DECLS([roundf], , , [#include <math.h>])
  13   if test "$ac_cv_have_decl_roundf" = yes; then
  14     gl_CHECK_MATH_LIB([ROUNDF_LIBM], [x = roundf (x);])
  15   else
  16     AC_CHECK_DECLS([ceilf, floorf], , , [#include <math.h>])
  17     if test "$ac_cv_have_decl_floorf" = yes &&
  18        test "$ac_cv_have_decl_ceilf" = yes; then
  19       gl_CHECK_MATH_LIB([ROUNDF_LIBM], [x = floorf (x) + ceilf (x);])
  20     else
  21       ROUNDF_LIBM=
  22     fi
  23     HAVE_DECL_ROUNDF=0
  24     AC_LIBOBJ([roundf])
  25   fi
  26   AC_SUBST([HAVE_DECL_ROUNDF])
  27   AC_SUBST([ROUNDF_LIBM])
  28 ])