m4/sigaction.m4

   1 # sigaction.m4 serial 3
   2 dnl Copyright (C) 2008 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 # Determine if sigaction interface is present.
   8 AC_DEFUN([gl_SIGACTION],
   9 [
  10   AC_REQUIRE([gl_SIGNAL_H_DEFAULTS])
  11   AC_REPLACE_FUNCS([sigaction])
  12   if test $ac_cv_func_sigaction = no ; then
  13     HAVE_SIGACTION=0
  14     AC_SUBST([HAVE_SIGACTION])
  15     gl_PREREQ_SIGACTION
  16   fi
  17 ])
  18
  19 # Prerequisites of the part of lib/signal.in.h and of lib/sigaction.c.
  20 AC_DEFUN([gl_PREREQ_SIGACTION],
  21 [
  22   AC_REQUIRE([gl_SIGNAL_H_DEFAULTS])
  23   AC_REQUIRE([AC_C_RESTRICT])
  24   AC_REQUIRE([AC_TYPE_UID_T])
  25   AC_CHECK_FUNCS_ONCE([sigaltstack siginterrupt])
  26   AC_CHECK_TYPES([siginfo_t], [], [], [[
  27 #include <signal.h>
  28   ]])
  29   if test $ac_cv_type_siginfo_t = no; then
  30     HAVE_SIGINFO_T=0
  31     AC_SUBST([HAVE_SIGINFO_T])
  32   fi
  33 ])
  34
  35 # Prerequisites of lib/sig-handler.h.
  36 AC_DEFUN([gl_PREREQ_SIG_HANDLER_H],
  37 [
  38   AC_REQUIRE([AC_C_INLINE])
  39   :
  40 ])