m4/signbit.m4

   1 # signbit.m4 serial 3
   2 dnl Copyright (C) 2007-2008 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_SIGNBIT],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   AC_CACHE_CHECK([for signbit macro], [gl_cv_func_signbit],
  11     [
  12       AC_TRY_RUN([
  13 #include <math.h>
  14 /* If signbit is defined as a function, don't use it, since calling it for
  15    'float' or 'long double' arguments would involve conversions.
  16    If signbit is not declared at all but exists as a library function, don't
  17    use it, since the prototype may not match.
  18    If signbit is not declared at all but exists as a compiler built-in, don't
  19    use it, since it's preferable to use __builtin_signbit* (no warnings,
  20    no conversions).  */
  21 #ifndef signbit
  22 # error "signbit should be a macro"
  23 #endif
  24 #include <string.h>
  25 ]gl_SIGNBIT_TEST_PROGRAM
  26 , [gl_cv_func_signbit=yes], [gl_cv_func_signbit=no],
  27         [gl_cv_func_signbit="guessing no"])
  28     ])
  29   dnl GCC 4.0 and newer provides three built-ins for signbit.
  30   dnl They can be used without warnings, also in C++, regardless of <math.h>.
  31   dnl But they may expand to calls to functions, which may or may not be in
  32   dnl libc.
  33   AC_CACHE_CHECK([for signbit compiler built-ins], [gl_cv_func_signbit_gcc],
  34     [
  35       AC_TRY_RUN([
  36 #if __GNUC__ >= 4
  37 # define signbit(x) \
  38    (sizeof (x) == sizeof (long double) ? __builtin_signbitl (x) : \
  39     sizeof (x) == sizeof (double) ? __builtin_signbit (x) : \
  40     __builtin_signbitf (x))
  41 #else
  42 # error "signbit should be three compiler built-ins"
  43 #endif
  44 #include <string.h>
  45 ]gl_SIGNBIT_TEST_PROGRAM
  46 , [gl_cv_func_signbit_gcc=yes], [gl_cv_func_signbit_gcc=no],
  47         [gl_cv_func_signbit_gcc="guessing no"])
  48     ])
  49   dnl Use the compiler built-ins whenever possible, because they are more
  50   dnl efficient than the system library functions (if they exist).
  51   if test "$gl_cv_func_signbit_gcc" = yes; then
  52     REPLACE_SIGNBIT_USING_GCC=1
  53   else
  54     if test "$gl_cv_func_signbit" != yes; then
  55       REPLACE_SIGNBIT=1
  56       AC_LIBOBJ([signbitf])
  57       AC_LIBOBJ([signbitd])
  58       AC_LIBOBJ([signbitl])
  59       gl_FLOAT_SIGN_LOCATION
  60       gl_DOUBLE_SIGN_LOCATION
  61       gl_LONG_DOUBLE_SIGN_LOCATION
  62       if test "$gl_cv_cc_float_signbit" = unknown; then
  63         dnl Test whether copysignf() is declared.
  64         AC_CHECK_DECLS([copysignf], , , [#include <math.h>])
  65         if test "$ac_cv_have_decl_copysignf" = yes; then
  66           dnl Test whether copysignf() can be used without libm.
  67           AC_CACHE_CHECK([whether copysignf can be used without linking with libm],
  68             [gl_cv_func_copysignf_no_libm],
  69             [
  70               AC_TRY_LINK([#include <math.h>
  71                            float x, y;],
  72                           [return copysignf (x, y) < 0;],
  73                 [gl_cv_func_copysignf_no_libm=yes],
  74                 [gl_cv_func_copysignf_no_libm=no])
  75             ])
  76           if test $gl_cv_func_copysignf_no_libm = yes; then
  77             AC_DEFINE([HAVE_COPYSIGNF_IN_LIBC], 1,
  78               [Define if the copysignf function is declared in <math.h> and available in libc.])
  79           fi
  80         fi
  81       fi
  82       if test "$gl_cv_cc_double_signbit" = unknown; then
  83         dnl Test whether copysign() is declared.
  84         AC_CHECK_DECLS([copysign], , , [#include <math.h>])
  85         if test "$ac_cv_have_decl_copysign" = yes; then
  86           dnl Test whether copysign() can be used without libm.
  87           AC_CACHE_CHECK([whether copysign can be used without linking with libm],
  88             [gl_cv_func_copysign_no_libm],
  89             [
  90               AC_TRY_LINK([#include <math.h>
  91                            double x, y;],
  92                           [return copysign (x, y) < 0;],
  93                 [gl_cv_func_copysign_no_libm=yes],
  94                 [gl_cv_func_copysign_no_libm=no])
  95             ])
  96           if test $gl_cv_func_copysign_no_libm = yes; then
  97             AC_DEFINE([HAVE_COPYSIGN_IN_LIBC], 1,
  98               [Define if the copysign function is declared in <math.h> and available in libc.])
  99           fi
 100         fi
 101       fi
 102       if test "$gl_cv_cc_long_double_signbit" = unknown; then
 103         dnl Test whether copysignl() is declared.
 104         AC_CHECK_DECLS([copysignl], , , [#include <math.h>])
 105         if test "$ac_cv_have_decl_copysignl" = yes; then
 106           dnl Test whether copysignl() can be used without libm.
 107           AC_CACHE_CHECK([whether copysignl can be used without linking with libm],
 108             [gl_cv_func_copysignl_no_libm],
 109             [
 110               AC_TRY_LINK([#include <math.h>
 111                            long double x, y;],
 112                           [return copysignl (x, y) < 0;],
 113                 [gl_cv_func_copysignl_no_libm=yes],
 114                 [gl_cv_func_copysignl_no_libm=no])
 115             ])
 116           if test $gl_cv_func_copysignl_no_libm = yes; then
 117             AC_DEFINE([HAVE_COPYSIGNL_IN_LIBC], 1,
 118               [Define if the copysignl function is declared in <math.h> and available in libc.])
 119           fi
 120         fi
 121       fi
 122     fi
 123   fi
 124 ])
 125
 126 AC_DEFUN([gl_SIGNBIT_TEST_PROGRAM], [
 127 /* HP cc on HP-UX 10.20 has a bug with the constant expression -0.0.
 128    So we use -p0f instead.  */
 129 float p0f = 0.0f;
 130 float m0f = -p0f;
 131 double p0d = 0.0;
 132 double m0d = -p0d;
 133 long double p0l = 0.0L;
 134 long double m0l = -p0l;
 135 int main ()
 136 {
 137   {
 138     float plus_inf = 1.0f / p0f;
 139     float minus_inf = -1.0f / p0f;
 140     if (!(!signbit (255.0f)
 141           && signbit (-255.0f)
 142           && !signbit (p0f)
 143           && (memcmp (&m0f, &p0f, sizeof (float)) == 0 || signbit (m0f))
 144           && !signbit (plus_inf)
 145           && signbit (minus_inf)))
 146       return 1;
 147   }
 148   {
 149     double plus_inf = 1.0 / p0d;
 150     double minus_inf = -1.0 / p0d;
 151     if (!(!signbit (255.0)
 152           && signbit (-255.0)
 153           && !signbit (p0d)
 154           && (memcmp (&m0d, &p0d, sizeof (double)) == 0 || signbit (m0d))
 155           && !signbit (plus_inf)
 156           && signbit (minus_inf)))
 157       return 1;
 158   }
 159   {
 160     long double plus_inf = 1.0L / p0l;
 161     long double minus_inf = -1.0L / p0l;
 162     if (!(!signbit (255.0L)
 163           && signbit (-255.0L)
 164           && !signbit (p0l)
 165           && (memcmp (&m0l, &p0l, sizeof (long double)) == 0 || signbit (m0l))
 166           && !signbit (plus_inf)
 167           && signbit (minus_inf)))
 168       return 1;
 169   }
 170   return 0;
 171 }
 172 ])
 173
 174 AC_DEFUN([gl_FLOAT_SIGN_LOCATION],
 175 [
 176   gl_FLOATTYPE_SIGN_LOCATION([float], [gl_cv_cc_float_signbit], [f], [FLT])
 177 ])
 178
 179 AC_DEFUN([gl_DOUBLE_SIGN_LOCATION],
 180 [
 181   gl_FLOATTYPE_SIGN_LOCATION([double], [gl_cv_cc_double_signbit], [], [DBL])
 182 ])
 183
 184 AC_DEFUN([gl_LONG_DOUBLE_SIGN_LOCATION],
 185 [
 186   gl_FLOATTYPE_SIGN_LOCATION([long double], [gl_cv_cc_long_double_signbit], [L], [LDBL])
 187 ])
 188
 189 AC_DEFUN([gl_FLOATTYPE_SIGN_LOCATION],
 190 [
 191   AC_CACHE_CHECK([where to find the sign bit in a '$1'],
 192     [$2],
 193     [
 194       AC_TRY_RUN([
 195 #include <stddef.h>
 196 #include <stdio.h>
 197 #define NWORDS \
 198   ((sizeof ($1) + sizeof (unsigned int) - 1) / sizeof (unsigned int))
 199 typedef union { $1 value; unsigned int word[NWORDS]; }
 200         memory_float;
 201 static memory_float plus = { 1.0$3 };
 202 static memory_float minus = { -1.0$3 };
 203 int main ()
 204 {
 205   size_t j, k, i;
 206   unsigned int m;
 207   FILE *fp = fopen ("conftest.out", "w");
 208   if (fp == NULL)
 209     return 1;
 210   /* Find the different bit.  */
 211   k = 0; m = 0;
 212   for (j = 0; j < NWORDS; j++)
 213     {
 214       unsigned int x = plus.word[j] ^ minus.word[j];
 215       if ((x & (x - 1)) || (x && m))
 216         {
 217           /* More than one bit difference.  */
 218           fprintf (fp, "unknown");
 219           return 1;
 220         }
 221       if (x)
 222         {
 223           k = j;
 224           m = x;
 225         }
 226     }
 227   if (m == 0)
 228     {
 229       /* No difference.  */
 230       fprintf (fp, "unknown");
 231       return 1;
 232     }
 233   /* Now m = plus.word[k] ^ ~minus.word[k].  */
 234   if (plus.word[k] & ~minus.word[k])
 235     {
 236       /* Oh? The sign bit is set in the positive and cleared in the negative
 237          numbers?  */
 238       fprintf (fp, "unknown");
 239       return 1;
 240     }
 241   for (i = 0; ; i++)
 242     if ((m >> i) & 1)
 243       break;
 244   fprintf (fp, "word %d bit %d", (int) k, (int) i);
 245   return (fclose (fp) != 0);
 246 }
 247         ],
 248         [$2=`cat conftest.out`],
 249         [$2="unknown"],
 250         [
 251           dnl When cross-compiling, we don't know. It depends on the
 252           dnl ABI and compiler version. There are too many cases.
 253           $2="unknown"
 254         ])
 255       rm -f conftest.out
 256     ])
 257   case "$]$2[" in
 258     word*bit*)
 259       word=`echo "$]$2[" | sed -e 's/word //' -e 's/ bit.*//'`
 260       bit=`echo "$]$2[" | sed -e 's/word.*bit //'`
 261       AC_DEFINE_UNQUOTED([$4][_SIGNBIT_WORD], [$word],
 262         [Define as the word index where to find the sign of '$1'.])
 263       AC_DEFINE_UNQUOTED([$4][_SIGNBIT_BIT], [$bit],
 264         [Define as the bit index in the word where to find the sign of '$1'.])
 265       ;;
 266   esac
 267 ])