m4/snprintf-posix.m4

   1 # snprintf-posix.m4 serial 1
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_SNPRINTF_POSIX],
   8 [
   9   AC_REQUIRE([gl_EOVERFLOW])
  10   AC_REQUIRE([gl_PRINTF_SIZES_C99])
  11   AC_REQUIRE([gl_PRINTF_DIRECTIVE_A])
  12   AC_REQUIRE([gl_PRINTF_DIRECTIVE_N])
  13   AC_REQUIRE([gl_PRINTF_POSITIONS])
  14   gl_cv_func_snprintf_posix=no
  15   AC_CHECK_FUNCS([snprintf])
  16   if test $ac_cv_func_snprintf = yes; then
  17     gl_SNPRINTF_TRUNCATION_C99
  18     gl_SNPRINTF_RETVAL_C99
  19     gl_SNPRINTF_DIRECTIVE_N
  20     if expr "$gl_cv_func_printf_sizes_c99" : ".*yes" > /dev/null \
  21        && expr "$gl_cv_func_printf_directive_a" : ".*yes" > /dev/null \
  22        && expr "$gl_cv_func_printf_directive_n" : ".*yes" > /dev/null \
  23        && expr "$gl_cv_func_printf_positions" : ".*yes" > /dev/null \
  24        && expr "$gl_cv_func_snprintf_truncation_c99" : ".*yes" > /dev/null \
  25        && expr "$gl_cv_func_snprintf_retval_c99" : ".*yes" > /dev/null \
  26        && expr "$gl_cv_func_snprintf_directive_n" : ".*yes" > /dev/null; then
  27       # snprintf exists and is already POSIX compliant.
  28       gl_cv_func_snprintf_posix=yes
  29     fi
  30   fi
  31   if test $gl_cv_func_snprintf_posix = no; then
  32     if ! expr "$gl_cv_func_printf_directive_a" : ".*yes" > /dev/null; then
  33       AC_DEFINE([NEED_PRINTF_DIRECTIVE_A], 1,
  34         [Define if the vasnprintf implementation needs special code for
  35          the 'a' and 'A' directives.])
  36     fi
  37     gl_REPLACE_VASNPRINTF
  38     gl_REPLACE_SNPRINTF
  39   fi
  40 ])