m4/snprintf-posix.m4

   1 # snprintf-posix.m4 serial 8
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_SNPRINTF_POSIX],
   8 [
   9   AC_REQUIRE([gl_EOVERFLOW])
  10   AC_REQUIRE([gl_PRINTF_SIZES_C99])
  11   AC_REQUIRE([gl_PRINTF_LONG_DOUBLE])
  12   AC_REQUIRE([gl_PRINTF_INFINITE])
  13   AC_REQUIRE([gl_PRINTF_INFINITE_LONG_DOUBLE])
  14   AC_REQUIRE([gl_PRINTF_DIRECTIVE_A])
  15   AC_REQUIRE([gl_PRINTF_DIRECTIVE_F])
  16   AC_REQUIRE([gl_PRINTF_DIRECTIVE_N])
  17   AC_REQUIRE([gl_PRINTF_POSITIONS])
  18   AC_REQUIRE([gl_PRINTF_FLAG_GROUPING])
  19   AC_REQUIRE([gl_PRINTF_FLAG_ZERO])
  20   gl_cv_func_snprintf_posix=no
  21   AC_CHECK_FUNCS([snprintf])
  22   if test $ac_cv_func_snprintf = yes; then
  23     gl_SNPRINTF_TRUNCATION_C99
  24     gl_SNPRINTF_RETVAL_C99
  25     gl_SNPRINTF_DIRECTIVE_N
  26     gl_VSNPRINTF_ZEROSIZE_C99
  27     case "$gl_cv_func_printf_sizes_c99" in
  28       *yes)
  29         case "$gl_cv_func_printf_long_double" in
  30           *yes)
  31             case "$gl_cv_func_printf_infinite" in
  32               *yes)
  33                 case "$gl_cv_func_printf_infinite_long_double" in
  34                   *yes)
  35                     case "$gl_cv_func_printf_directive_a" in
  36                       *yes)
  37                         case "$gl_cv_func_printf_directive_f" in
  38                           *yes)
  39                             case "$gl_cv_func_printf_directive_n" in
  40                               *yes)
  41                                 case "$gl_cv_func_printf_positions" in
  42                                   *yes)
  43                                     case "$gl_cv_func_printf_flag_grouping" in
  44                                       *yes)
  45                                         case "$gl_cv_func_printf_flag_zero" in
  46                                           *yes)
  47                                             case "$gl_cv_func_snprintf_truncation_c99" in
  48                                               *yes)
  49                                                 case "$gl_cv_func_snprintf_retval_c99" in
  50                                                   *yes)
  51                                                     case "$gl_cv_func_snprintf_directive_n" in
  52                                                       *yes)
  53                                                         case "$gl_cv_func_vsnprintf_zerosize_c99" in
  54                                                           *yes)
  55                                                             # snprintf exists and is
  56                                                             # already POSIX compliant.
  57                                                             gl_cv_func_snprintf_posix=yes
  58                                                             ;;
  59                                                         esac
  60                                                         ;;
  61                                                     esac
  62                                                     ;;
  63                                                 esac
  64                                                 ;;
  65                                             esac
  66                                             ;;
  67                                         esac
  68                                         ;;
  69                                     esac
  70                                     ;;
  71                                 esac
  72                                 ;;
  73                             esac
  74                             ;;
  75                         esac
  76                         ;;
  77                     esac
  78                     ;;
  79                 esac
  80                 ;;
  81             esac
  82             ;;
  83         esac
  84         ;;
  85     esac
  86   fi
  87   if test $gl_cv_func_snprintf_posix = no; then
  88     gl_PREREQ_VASNPRINTF_LONG_DOUBLE
  89     gl_PREREQ_VASNPRINTF_INFINITE_DOUBLE
  90     gl_PREREQ_VASNPRINTF_INFINITE_LONG_DOUBLE
  91     gl_PREREQ_VASNPRINTF_DIRECTIVE_A
  92     gl_PREREQ_VASNPRINTF_DIRECTIVE_F
  93     gl_PREREQ_VASNPRINTF_FLAG_GROUPING
  94     gl_PREREQ_VASNPRINTF_FLAG_ZERO
  95     gl_REPLACE_VASNPRINTF
  96     gl_REPLACE_SNPRINTF
  97   fi
  98 ])