m4/spawn_h.m4

   1 # spawn_h.m4 serial 6
   2 dnl Copyright (C) 2008-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl Written by Bruno Haible.
   8
   9 AC_DEFUN([gl_SPAWN_H],
  10 [
  11   dnl Use AC_REQUIRE here, so that the default behavior below is expanded
  12   dnl once only, before all statements that occur in other macros.
  13   AC_REQUIRE([gl_SPAWN_H_DEFAULTS])
  14
  15   dnl <spawn.h> is always overridden, because of GNULIB_POSIXCHECK.
  16   gl_CHECK_NEXT_HEADERS([spawn.h])
  17
  18   AC_CHECK_HEADERS_ONCE([spawn.h])
  19   if test $ac_cv_header_spawn_h = yes; then
  20     HAVE_SPAWN_H=1
  21     AC_CHECK_TYPES([posix_spawnattr_t], [], [HAVE_POSIX_SPAWNATTR_T=0], [[
  22 #include <spawn.h>
  23       ]])
  24     AC_CHECK_TYPES([posix_spawn_file_actions_t], [],
  25       [HAVE_POSIX_SPAWN_FILE_ACTIONS_T=0], [[
  26 #include <spawn.h>
  27       ]])
  28   else
  29     HAVE_SPAWN_H=0
  30     HAVE_POSIX_SPAWNATTR_T=0
  31     HAVE_POSIX_SPAWN_FILE_ACTIONS_T=0
  32     gl_REPLACE_SPAWN_H
  33   fi
  34   AC_SUBST([HAVE_SPAWN_H])
  35
  36   AC_REQUIRE([AC_C_RESTRICT])
  37
  38   dnl Check for declarations of anything we want to poison if the
  39   dnl corresponding gnulib module is not in use.
  40   gl_WARN_ON_USE_PREPARE([[#include <spawn.h>
  41     ]], [posix_spawn posix_spawnp posix_spawnattr_init posix_spawnattr_destroy
  42     posix_spawnattr_getsigdefault posix_spawnattr_setsigdefault
  43     posix_spawnattr_getsigmask posix_spawnattr_setsigmask
  44     posix_spawnattr_getflags posix_spawnattr_setflags
  45     posix_spawnattr_getpgroup posix_spawnattr_setpgroup
  46     posix_spawnattr_getschedpolicy posix_spawnattr_setschedpolicy
  47     posix_spawnattr_getschedparam posix_spawnattr_setschedparam
  48     posix_spawn_file_actions_init posix_spawn_file_actions_destroy
  49     posix_spawn_file_actions_addopen posix_spawn_file_actions_addclose
  50     posix_spawwn_file_actions_adddup2])
  51 ])
  52
  53 dnl Unconditionally enables the replacement of <spawn.h>.
  54 AC_DEFUN([gl_REPLACE_SPAWN_H],
  55 [
  56   dnl This is a no-op, because <spawn.h> is always overridden.
  57   :
  58 ])
  59
  60 AC_DEFUN([gl_SPAWN_MODULE_INDICATOR],
  61 [
  62   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  63   AC_REQUIRE([gl_SPAWN_H_DEFAULTS])
  64   GNULIB_[]m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=1
  65 ])
  66
  67 AC_DEFUN([gl_SPAWN_H_DEFAULTS],
  68 [
  69   GNULIB_POSIX_SPAWN=0;                       AC_SUBST([GNULIB_POSIX_SPAWN])
  70   GNULIB_POSIX_SPAWNP=0;                      AC_SUBST([GNULIB_POSIX_SPAWNP])
  71   GNULIB_POSIX_SPAWN_FILE_ACTIONS_INIT=0;     AC_SUBST([GNULIB_POSIX_SPAWN_FILE_ACTIONS_INIT])
  72   GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDCLOSE=0; AC_SUBST([GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDCLOSE])
  73   GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDDUP2=0;  AC_SUBST([GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDDUP2])
  74   GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDOPEN=0;  AC_SUBST([GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDOPEN])
  75   GNULIB_POSIX_SPAWN_FILE_ACTIONS_DESTROY=0;  AC_SUBST([GNULIB_POSIX_SPAWN_FILE_ACTIONS_DESTROY])
  76   GNULIB_POSIX_SPAWNATTR_INIT=0;              AC_SUBST([GNULIB_POSIX_SPAWNATTR_INIT])
  77   GNULIB_POSIX_SPAWNATTR_GETFLAGS=0;          AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETFLAGS])
  78   GNULIB_POSIX_SPAWNATTR_SETFLAGS=0;          AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETFLAGS])
  79   GNULIB_POSIX_SPAWNATTR_GETPGROUP=0;         AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETPGROUP])
  80   GNULIB_POSIX_SPAWNATTR_SETPGROUP=0;         AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETPGROUP])
  81   GNULIB_POSIX_SPAWNATTR_GETSCHEDPARAM=0;     AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETSCHEDPARAM])
  82   GNULIB_POSIX_SPAWNATTR_SETSCHEDPARAM=0;     AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETSCHEDPARAM])
  83   GNULIB_POSIX_SPAWNATTR_GETSCHEDPOLICY=0;    AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETSCHEDPOLICY])
  84   GNULIB_POSIX_SPAWNATTR_SETSCHEDPOLICY=0;    AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETSCHEDPOLICY])
  85   GNULIB_POSIX_SPAWNATTR_GETSIGDEFAULT=0;     AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETSIGDEFAULT])
  86   GNULIB_POSIX_SPAWNATTR_SETSIGDEFAULT=0;     AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETSIGDEFAULT])
  87   GNULIB_POSIX_SPAWNATTR_GETSIGMASK=0;        AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETSIGMASK])
  88   GNULIB_POSIX_SPAWNATTR_SETSIGMASK=0;        AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETSIGMASK])
  89   GNULIB_POSIX_SPAWNATTR_DESTROY=0;           AC_SUBST([GNULIB_POSIX_SPAWNATTR_DESTROY])
  90   dnl Assume proper GNU behavior unless another module says otherwise.
  91   HAVE_POSIX_SPAWN=1;        AC_SUBST([HAVE_POSIX_SPAWN])
  92   HAVE_POSIX_SPAWNATTR_T=1;  AC_SUBST([HAVE_POSIX_SPAWNATTR_T])
  93   HAVE_POSIX_SPAWN_FILE_ACTIONS_T=1;
  94                              AC_SUBST([HAVE_POSIX_SPAWN_FILE_ACTIONS_T])
  95   REPLACE_POSIX_SPAWN=0;     AC_SUBST([REPLACE_POSIX_SPAWN])
  96 ])