m4/spawn_h.m4

   1 # spawn_h.m4 serial 13
   2 dnl Copyright (C) 2008-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl Written by Bruno Haible.
   8
   9 AC_DEFUN([gl_SPAWN_H],
  10 [
  11   dnl Use AC_REQUIRE here, so that the default behavior below is expanded
  12   dnl once only, before all statements that occur in other macros.
  13   AC_REQUIRE([gl_SPAWN_H_DEFAULTS])
  14
  15   dnl <spawn.h> is always overridden, because of GNULIB_POSIXCHECK.
  16   gl_CHECK_NEXT_HEADERS([spawn.h])
  17
  18   if test $ac_cv_header_spawn_h = yes; then
  19     HAVE_SPAWN_H=1
  20     AC_CHECK_TYPES([posix_spawnattr_t], [], [HAVE_POSIX_SPAWNATTR_T=0], [[
  21 #include <spawn.h>
  22       ]])
  23     AC_CHECK_TYPES([posix_spawn_file_actions_t], [],
  24       [HAVE_POSIX_SPAWN_FILE_ACTIONS_T=0], [[
  25 #include <spawn.h>
  26       ]])
  27   else
  28     HAVE_SPAWN_H=0
  29     HAVE_POSIX_SPAWNATTR_T=0
  30     HAVE_POSIX_SPAWN_FILE_ACTIONS_T=0
  31   fi
  32   AC_SUBST([HAVE_SPAWN_H])
  33
  34   AC_REQUIRE([gl_HAVE_POSIX_SPAWN])
  35
  36   AC_REQUIRE([AC_C_RESTRICT])
  37
  38   dnl Check for declarations of anything we want to poison if the
  39   dnl corresponding gnulib module is not in use.
  40   gl_WARN_ON_USE_PREPARE([[#include <spawn.h>
  41     ]], [posix_spawn posix_spawnp posix_spawnattr_init posix_spawnattr_destroy
  42     posix_spawnattr_getsigdefault posix_spawnattr_setsigdefault
  43     posix_spawnattr_getsigmask posix_spawnattr_setsigmask
  44     posix_spawnattr_getflags posix_spawnattr_setflags
  45     posix_spawnattr_getpgroup posix_spawnattr_setpgroup
  46     posix_spawnattr_getschedpolicy posix_spawnattr_setschedpolicy
  47     posix_spawnattr_getschedparam posix_spawnattr_setschedparam
  48     posix_spawn_file_actions_init posix_spawn_file_actions_destroy
  49     posix_spawn_file_actions_addopen posix_spawn_file_actions_addclose
  50     posix_spawn_file_actions_adddup2])
  51 ])
  52
  53 dnl Checks whether the system has the functions posix_spawn.
  54 dnl Sets ac_cv_func_posix_spawn and HAVE_POSIX_SPAWN.
  55 AC_DEFUN([gl_HAVE_POSIX_SPAWN],
  56 [
  57   dnl Use AC_REQUIRE here, so that the default behavior below is expanded
  58   dnl once only, before all statements that occur in other macros.
  59   AC_REQUIRE([gl_SPAWN_H_DEFAULTS])
  60
  61   AC_CHECK_FUNCS_ONCE([posix_spawn])
  62   if test $ac_cv_func_posix_spawn != yes; then
  63     HAVE_POSIX_SPAWN=0
  64   fi
  65 ])
  66
  67 AC_DEFUN([gl_SPAWN_MODULE_INDICATOR],
  68 [
  69   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  70   AC_REQUIRE([gl_SPAWN_H_DEFAULTS])
  71   gl_MODULE_INDICATOR_SET_VARIABLE([$1])
  72   dnl Define it also as a C macro, for the benefit of the unit tests.
  73   gl_MODULE_INDICATOR_FOR_TESTS([$1])
  74 ])
  75
  76 AC_DEFUN([gl_SPAWN_H_DEFAULTS],
  77 [
  78   GNULIB_POSIX_SPAWN=0;                       AC_SUBST([GNULIB_POSIX_SPAWN])
  79   GNULIB_POSIX_SPAWNP=0;                      AC_SUBST([GNULIB_POSIX_SPAWNP])
  80   GNULIB_POSIX_SPAWN_FILE_ACTIONS_INIT=0;     AC_SUBST([GNULIB_POSIX_SPAWN_FILE_ACTIONS_INIT])
  81   GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDCLOSE=0; AC_SUBST([GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDCLOSE])
  82   GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDDUP2=0;  AC_SUBST([GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDDUP2])
  83   GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDOPEN=0;  AC_SUBST([GNULIB_POSIX_SPAWN_FILE_ACTIONS_ADDOPEN])
  84   GNULIB_POSIX_SPAWN_FILE_ACTIONS_DESTROY=0;  AC_SUBST([GNULIB_POSIX_SPAWN_FILE_ACTIONS_DESTROY])
  85   GNULIB_POSIX_SPAWNATTR_INIT=0;              AC_SUBST([GNULIB_POSIX_SPAWNATTR_INIT])
  86   GNULIB_POSIX_SPAWNATTR_GETFLAGS=0;          AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETFLAGS])
  87   GNULIB_POSIX_SPAWNATTR_SETFLAGS=0;          AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETFLAGS])
  88   GNULIB_POSIX_SPAWNATTR_GETPGROUP=0;         AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETPGROUP])
  89   GNULIB_POSIX_SPAWNATTR_SETPGROUP=0;         AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETPGROUP])
  90   GNULIB_POSIX_SPAWNATTR_GETSCHEDPARAM=0;     AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETSCHEDPARAM])
  91   GNULIB_POSIX_SPAWNATTR_SETSCHEDPARAM=0;     AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETSCHEDPARAM])
  92   GNULIB_POSIX_SPAWNATTR_GETSCHEDPOLICY=0;    AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETSCHEDPOLICY])
  93   GNULIB_POSIX_SPAWNATTR_SETSCHEDPOLICY=0;    AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETSCHEDPOLICY])
  94   GNULIB_POSIX_SPAWNATTR_GETSIGDEFAULT=0;     AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETSIGDEFAULT])
  95   GNULIB_POSIX_SPAWNATTR_SETSIGDEFAULT=0;     AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETSIGDEFAULT])
  96   GNULIB_POSIX_SPAWNATTR_GETSIGMASK=0;        AC_SUBST([GNULIB_POSIX_SPAWNATTR_GETSIGMASK])
  97   GNULIB_POSIX_SPAWNATTR_SETSIGMASK=0;        AC_SUBST([GNULIB_POSIX_SPAWNATTR_SETSIGMASK])
  98   GNULIB_POSIX_SPAWNATTR_DESTROY=0;           AC_SUBST([GNULIB_POSIX_SPAWNATTR_DESTROY])
  99   dnl Assume proper GNU behavior unless another module says otherwise.
 100   HAVE_POSIX_SPAWN=1;        AC_SUBST([HAVE_POSIX_SPAWN])
 101   HAVE_POSIX_SPAWNATTR_T=1;  AC_SUBST([HAVE_POSIX_SPAWNATTR_T])
 102   HAVE_POSIX_SPAWN_FILE_ACTIONS_T=1;
 103                              AC_SUBST([HAVE_POSIX_SPAWN_FILE_ACTIONS_T])
 104   REPLACE_POSIX_SPAWN=0;     AC_SUBST([REPLACE_POSIX_SPAWN])
 105 ])