m4/sqrtl.m4

   1 # sqrtl.m4 serial 2
   2 dnl Copyright (C) 2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_SQRTL],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   dnl Persuade glibc <math.h> to declare sqrtl().
  11   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  12
  13   SQRTL_LIBM=
  14   AC_CACHE_CHECK([whether sqrtl() can be used without linking with libm],
  15     [gl_cv_func_sqrtl_no_libm],
  16     [
  17       AC_TRY_LINK([#ifndef __NO_MATH_INLINES
  18                    # define __NO_MATH_INLINES 1 /* for glibc */
  19                    #endif
  20                    #include <math.h>
  21                    long double x;],
  22                   [return sqrtl (x) > 0.4;],
  23         [gl_cv_func_sqrtl_no_libm=yes],
  24         [gl_cv_func_sqrtl_no_libm=no])
  25     ])
  26   if test $gl_cv_func_sqrtl_no_libm = no; then
  27     AC_CACHE_CHECK([whether sqrtl() can be used with libm],
  28       [gl_cv_func_sqrtl_in_libm],
  29       [
  30         save_LIBS="$LIBS"
  31         LIBS="$LIBS -lm"
  32         AC_TRY_LINK([#ifndef __NO_MATH_INLINES
  33                      # define __NO_MATH_INLINES 1 /* for glibc */
  34                      #endif
  35                      #include <math.h>
  36                      long double x;],
  37                     [return sqrtl (x) > 0.4;],
  38           [gl_cv_func_sqrtl_in_libm=yes],
  39           [gl_cv_func_sqrtl_in_libm=no])
  40         LIBS="$save_LIBS"
  41       ])
  42     if test $gl_cv_func_sqrtl_in_libm = yes; then
  43       SQRTL_LIBM=-lm
  44     fi
  45   fi
  46   if test $gl_cv_func_sqrtl_no_libm = yes \
  47      || test $gl_cv_func_sqrtl_in_libm = yes; then
  48     dnl Also check whether it's declared.
  49     dnl MacOS X 10.3 has sqrtl() in libc but doesn't declare it in <math.h>.
  50     AC_CHECK_DECL([sqrtl], , [HAVE_DECL_SQRTL=0], [#include <math.h>])
  51   else
  52     HAVE_DECL_SQRTL=0
  53     HAVE_SQRTL=0
  54     AC_LIBOBJ([sqrtl])
  55     AC_REQUIRE([gl_FUNC_ISNANL])
  56     AC_REQUIRE([gl_FUNC_FREXPL])
  57     AC_REQUIRE([gl_FUNC_LDEXPL])
  58     AC_REQUIRE([gl_FUNC_SQRT])
  59     dnl Append $ISNANL_LIBM to SQRTL_LIBM, avoiding gratuitous duplicates.
  60     case " $SQRTL_LIBM " in
  61       *" $ISNANL_LIBM "*) ;;
  62       *) SQRTL_LIBM="$SQRTL_LIBM $ISNANL_LIBM" ;;
  63     esac
  64     dnl Append $FREXPL_LIBM to SQRTL_LIBM, avoiding gratuitous duplicates.
  65     case " $SQRTL_LIBM " in
  66       *" $FREXPL_LIBM "*) ;;
  67       *) SQRTL_LIBM="$SQRTL_LIBM $FREXPL_LIBM" ;;
  68     esac
  69     dnl Append $LDEXPL_LIBM to SQRTL_LIBM, avoiding gratuitous duplicates.
  70     case " $SQRTL_LIBM " in
  71       *" $LDEXPL_LIBM "*) ;;
  72       *) SQRTL_LIBM="$SQRTL_LIBM $LDEXPL_LIBM" ;;
  73     esac
  74     dnl Append $SQRT_LIBM to SQRTL_LIBM, avoiding gratuitous duplicates.
  75     case " $SQRTL_LIBM " in
  76       *" $SQRT_LIBM "*) ;;
  77       *) SQRTL_LIBM="$SQRTL_LIBM $SQRT_LIBM" ;;
  78     esac
  79   fi
  80   AC_SUBST([SQRTL_LIBM])
  81 ])