m4/sqrtl.m4

   1 # sqrtl.m4 serial 7
   2 dnl Copyright (C) 2010-2012 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_SQRTL],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
  11
  12   dnl Persuade glibc <math.h> to declare sqrtl().
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14
  15   SQRTL_LIBM=
  16   AC_CACHE_CHECK([whether sqrtl() can be used without linking with libm],
  17     [gl_cv_func_sqrtl_no_libm],
  18     [
  19       AC_LINK_IFELSE(
  20         [AC_LANG_PROGRAM(
  21            [[#ifndef __NO_MATH_INLINES
  22              # define __NO_MATH_INLINES 1 /* for glibc */
  23              #endif
  24              #include <math.h>
  25              long double (*funcptr) (long double) = sqrtl;
  26              long double x;]],
  27            [[return funcptr (x) > 0.4
  28                     || sqrtl (x) > 0.4;]])],
  29         [gl_cv_func_sqrtl_no_libm=yes],
  30         [gl_cv_func_sqrtl_no_libm=no])
  31     ])
  32   if test $gl_cv_func_sqrtl_no_libm = no; then
  33     AC_CACHE_CHECK([whether sqrtl() can be used with libm],
  34       [gl_cv_func_sqrtl_in_libm],
  35       [
  36         save_LIBS="$LIBS"
  37         LIBS="$LIBS -lm"
  38         AC_LINK_IFELSE(
  39           [AC_LANG_PROGRAM(
  40              [[#ifndef __NO_MATH_INLINES
  41                # define __NO_MATH_INLINES 1 /* for glibc */
  42                #endif
  43                #include <math.h>
  44                long double (*funcptr) (long double) = sqrtl;
  45                long double x;]],
  46              [[return funcptr (x) > 0.4
  47                       || sqrtl (x) > 0.4;]])],
  48           [gl_cv_func_sqrtl_in_libm=yes],
  49           [gl_cv_func_sqrtl_in_libm=no])
  50         LIBS="$save_LIBS"
  51       ])
  52     if test $gl_cv_func_sqrtl_in_libm = yes; then
  53       SQRTL_LIBM=-lm
  54     fi
  55   fi
  56   if test $gl_cv_func_sqrtl_no_libm = yes \
  57      || test $gl_cv_func_sqrtl_in_libm = yes; then
  58     dnl Also check whether it's declared.
  59     dnl MacOS X 10.3 has sqrtl() in libc but doesn't declare it in <math.h>.
  60     AC_CHECK_DECL([sqrtl], , [HAVE_DECL_SQRTL=0], [[#include <math.h>]])
  61   else
  62     HAVE_DECL_SQRTL=0
  63     HAVE_SQRTL=0
  64     dnl Find libraries needed to link lib/sqrtl.c.
  65     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
  66       AC_REQUIRE([gl_FUNC_SQRT])
  67       SQRTL_LIBM="$SQRT_LIBM"
  68     else
  69       AC_REQUIRE([gl_FUNC_ISNANL])
  70       AC_REQUIRE([gl_FUNC_FREXPL])
  71       AC_REQUIRE([gl_FUNC_LDEXPL])
  72       AC_REQUIRE([gl_FUNC_SQRT])
  73       dnl Append $ISNANL_LIBM to SQRTL_LIBM, avoiding gratuitous duplicates.
  74       case " $SQRTL_LIBM " in
  75         *" $ISNANL_LIBM "*) ;;
  76         *) SQRTL_LIBM="$SQRTL_LIBM $ISNANL_LIBM" ;;
  77       esac
  78       dnl Append $FREXPL_LIBM to SQRTL_LIBM, avoiding gratuitous duplicates.
  79       case " $SQRTL_LIBM " in
  80         *" $FREXPL_LIBM "*) ;;
  81         *) SQRTL_LIBM="$SQRTL_LIBM $FREXPL_LIBM" ;;
  82       esac
  83       dnl Append $LDEXPL_LIBM to SQRTL_LIBM, avoiding gratuitous duplicates.
  84       case " $SQRTL_LIBM " in
  85         *" $LDEXPL_LIBM "*) ;;
  86         *) SQRTL_LIBM="$SQRTL_LIBM $LDEXPL_LIBM" ;;
  87       esac
  88       dnl Append $SQRT_LIBM to SQRTL_LIBM, avoiding gratuitous duplicates.
  89       case " $SQRTL_LIBM " in
  90         *" $SQRT_LIBM "*) ;;
  91         *) SQRTL_LIBM="$SQRTL_LIBM $SQRT_LIBM" ;;
  92       esac
  93     fi
  94   fi
  95   AC_SUBST([SQRTL_LIBM])
  96 ])