m4/sqrtl.m4

   1 # sqrtl.m4 serial 4
   2 dnl Copyright (C) 2010-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_SQRTL],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   dnl Persuade glibc <math.h> to declare sqrtl().
  11   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  12
  13   SQRTL_LIBM=
  14   AC_CACHE_CHECK([whether sqrtl() can be used without linking with libm],
  15     [gl_cv_func_sqrtl_no_libm],
  16     [
  17       AC_LINK_IFELSE(
  18         [AC_LANG_PROGRAM(
  19            [[#ifndef __NO_MATH_INLINES
  20              # define __NO_MATH_INLINES 1 /* for glibc */
  21              #endif
  22              #include <math.h>
  23              long double x;]],
  24            [[return sqrtl (x) > 0.4;]])],
  25         [gl_cv_func_sqrtl_no_libm=yes],
  26         [gl_cv_func_sqrtl_no_libm=no])
  27     ])
  28   if test $gl_cv_func_sqrtl_no_libm = no; then
  29     AC_CACHE_CHECK([whether sqrtl() can be used with libm],
  30       [gl_cv_func_sqrtl_in_libm],
  31       [
  32         save_LIBS="$LIBS"
  33         LIBS="$LIBS -lm"
  34         AC_LINK_IFELSE(
  35           [AC_LANG_PROGRAM(
  36              [[#ifndef __NO_MATH_INLINES
  37                # define __NO_MATH_INLINES 1 /* for glibc */
  38                #endif
  39                #include <math.h>
  40                long double x;]],
  41              [[return sqrtl (x) > 0.4;]])],
  42           [gl_cv_func_sqrtl_in_libm=yes],
  43           [gl_cv_func_sqrtl_in_libm=no])
  44         LIBS="$save_LIBS"
  45       ])
  46     if test $gl_cv_func_sqrtl_in_libm = yes; then
  47       SQRTL_LIBM=-lm
  48     fi
  49   fi
  50   if test $gl_cv_func_sqrtl_no_libm = yes \
  51      || test $gl_cv_func_sqrtl_in_libm = yes; then
  52     dnl Also check whether it's declared.
  53     dnl MacOS X 10.3 has sqrtl() in libc but doesn't declare it in <math.h>.
  54     AC_CHECK_DECL([sqrtl], , [HAVE_DECL_SQRTL=0], [#include <math.h>])
  55   else
  56     HAVE_DECL_SQRTL=0
  57     HAVE_SQRTL=0
  58     dnl Find libraries needed to link lib/sqrtl.c.
  59     AC_REQUIRE([gl_FUNC_ISNANL])
  60     AC_REQUIRE([gl_FUNC_FREXPL])
  61     AC_REQUIRE([gl_FUNC_LDEXPL])
  62     AC_REQUIRE([gl_FUNC_SQRT])
  63     dnl Append $ISNANL_LIBM to SQRTL_LIBM, avoiding gratuitous duplicates.
  64     case " $SQRTL_LIBM " in
  65       *" $ISNANL_LIBM "*) ;;
  66       *) SQRTL_LIBM="$SQRTL_LIBM $ISNANL_LIBM" ;;
  67     esac
  68     dnl Append $FREXPL_LIBM to SQRTL_LIBM, avoiding gratuitous duplicates.
  69     case " $SQRTL_LIBM " in
  70       *" $FREXPL_LIBM "*) ;;
  71       *) SQRTL_LIBM="$SQRTL_LIBM $FREXPL_LIBM" ;;
  72     esac
  73     dnl Append $LDEXPL_LIBM to SQRTL_LIBM, avoiding gratuitous duplicates.
  74     case " $SQRTL_LIBM " in
  75       *" $LDEXPL_LIBM "*) ;;
  76       *) SQRTL_LIBM="$SQRTL_LIBM $LDEXPL_LIBM" ;;
  77     esac
  78     dnl Append $SQRT_LIBM to SQRTL_LIBM, avoiding gratuitous duplicates.
  79     case " $SQRTL_LIBM " in
  80       *" $SQRT_LIBM "*) ;;
  81       *) SQRTL_LIBM="$SQRTL_LIBM $SQRT_LIBM" ;;
  82     esac
  83   fi
  84   AC_SUBST([SQRTL_LIBM])
  85 ])