m4/stat.m4

   1 #serial 3
   2
   3 dnl From Jim Meyering.
   4 dnl Determine whether stat has the bug that it succeeds when given the
   5 dnl zero-length file name argument.  The stat from SunOS4.1.4 and the Hurd
   6 dnl (as of 1998-11-01) do this.
   7 dnl
   8 dnl If it does, then define HAVE_STAT_EMPTY_STRING_BUG and arrange to
   9 dnl compile the wrapper function.
  10 dnl
  11
  12 AC_DEFUN(jm_FUNC_STAT,
  13 [
  14  AC_CACHE_CHECK([whether stat accepts an empty string],
  15   jm_cv_func_stat_empty_string_bug,
  16   [AC_TRY_RUN([
  17 #   include <sys/types.h>
  18 #   include <sys/stat.h>
  19
  20     int
  21     main ()
  22     {
  23       struct stat sbuf;
  24       exit (stat ("", &sbuf) ? 1 : 0);
  25     }
  26           ],
  27          jm_cv_func_stat_empty_string_bug=yes,
  28          jm_cv_func_stat_empty_string_bug=no,
  29          dnl When crosscompiling, assume stat is broken.
  30          jm_cv_func_stat_empty_string_bug=yes)
  31   ])
  32   if test $jm_cv_func_stat_empty_string_bug = yes; then
  33     LIBOBJS="$LIBOBJS stat.$ac_objext"
  34     AC_DEFINE_UNQUOTED(HAVE_STAT_EMPTY_STRING_BUG, 1,
  35 [Define if stat has the bug that it succeeds when given the zero-length
  36    file name argument.  The stat from SunOS4.1.4 and the Hurd as of 1998-11-01)
  37    do this. ])
  38   fi
  39 ])