m4/stat.m4

   1 # serial 6
   2
   3 # Copyright (C) 2009, 2010 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; the Free Software Foundation
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 AC_DEFUN([gl_FUNC_STAT],
  10 [
  11   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  12   AC_REQUIRE([gl_AC_DOS])
  13   AC_REQUIRE([gl_SYS_STAT_H_DEFAULTS])
  14   AC_CHECK_FUNCS_ONCE([lstat])
  15   dnl mingw is the only known platform where stat(".") and stat("./") differ
  16   AC_CACHE_CHECK([whether stat handles trailing slashes on directories],
  17       [gl_cv_func_stat_dir_slash],
  18       [AC_RUN_IFELSE(
  19          [AC_LANG_PROGRAM(
  20            [[#include <sys/stat.h>
  21 ]], [[struct stat st; return stat (".", &st) != stat ("./", &st);]])],
  22          [gl_cv_func_stat_dir_slash=yes], [gl_cv_func_stat_dir_slash=no],
  23          [case $host_os in
  24             mingw*) gl_cv_func_stat_dir_slash="guessing no";;
  25             *) gl_cv_func_stat_dir_slash="guessing yes";;
  26           esac])])
  27   dnl AIX 7.1, Solaris 9 mistakenly succeed on stat("file/")
  28   dnl FreeBSD 7.2 mistakenly succeeds on stat("link-to-file/")
  29   AC_CACHE_CHECK([whether stat handles trailing slashes on files],
  30       [gl_cv_func_stat_file_slash],
  31       [touch conftest.tmp
  32        # Assume that if we have lstat, we can also check symlinks.
  33        if test $ac_cv_func_lstat = yes; then
  34          ln -s conftest.tmp conftest.lnk
  35        fi
  36        AC_RUN_IFELSE(
  37          [AC_LANG_PROGRAM(
  38            [[#include <sys/stat.h>
  39 ]], [[int result = 0;
  40       struct stat st;
  41       if (!stat ("conftest.tmp/", &st))
  42         result |= 1;
  43 #if HAVE_LSTAT
  44       if (!stat ("conftest.lnk/", &st))
  45         result |= 2;
  46 #endif
  47       return result;
  48            ]])],
  49          [gl_cv_func_stat_file_slash=yes], [gl_cv_func_stat_file_slash=no],
  50          [gl_cv_func_stat_file_slash="guessing no"])
  51        rm -f conftest.tmp conftest.lnk])
  52   case $gl_cv_func_stat_dir_slash in
  53     *no) REPLACE_STAT=1
  54       AC_DEFINE([REPLACE_FUNC_STAT_DIR], [1], [Define to 1 if stat needs
  55         help when passed a directory name with a trailing slash]);;
  56   esac
  57   case $gl_cv_func_stat_file_slash in
  58     *no) REPLACE_STAT=1
  59       AC_DEFINE([REPLACE_FUNC_STAT_FILE], [1], [Define to 1 if stat needs
  60         help when passed a file name with a trailing slash]);;
  61   esac
  62   if test $REPLACE_STAT = 1; then
  63     AC_LIBOBJ([stat])
  64     dnl Prerequisites of lib/stat.c.
  65     AC_REQUIRE([AC_C_INLINE])
  66   fi
  67 ])