m4/stdbool.m4

   1 # Check for stdbool.h that conforms to C99.
   2
   3 # Copyright (C) 2002-2003 Free Software Foundation, Inc.
   4
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2, or (at your option)
   8 # any later version.
   9
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  18 # 02111-1307, USA.
  19
  20 # Prepare for substituting <stdbool.h> if it is not supported.
  21
  22 AC_DEFUN([AM_STDBOOL_H],
  23 [
  24   AC_REQUIRE([AC_HEADER_STDBOOL])
  25
  26   # Define two additional variables used in the Makefile substitution.
  27
  28   if test "$ac_cv_header_stdbool_h" = yes; then
  29     STDBOOL_H=''
  30   else
  31     STDBOOL_H='stdbool.h'
  32   fi
  33   AC_SUBST([STDBOOL_H])
  34
  35   if test "$ac_cv_type__Bool" = yes; then
  36     HAVE__BOOL=1
  37   else
  38     HAVE__BOOL=0
  39   fi
  40   AC_SUBST([HAVE__BOOL])
  41 ])
  42
  43 # This macro is only needed in autoconf <= 2.54.  Newer versions of autoconf
  44 # have this macro built-in.
  45
  46 AC_DEFUN([AC_HEADER_STDBOOL],
  47   [AC_CACHE_CHECK([for stdbool.h that conforms to C99],
  48      [ac_cv_header_stdbool_h],
  49      [AC_TRY_COMPILE(
  50         [
  51           #include <stdbool.h>
  52           #ifndef bool
  53            "error: bool is not defined"
  54           #endif
  55           #ifndef false
  56            "error: false is not defined"
  57           #endif
  58           #if false
  59            "error: false is not 0"
  60           #endif
  61           #ifndef true
  62            "error: false is not defined"
  63           #endif
  64           #if true != 1
  65            "error: true is not 1"
  66           #endif
  67           #ifndef __bool_true_false_are_defined
  68            "error: __bool_true_false_are_defined is not defined"
  69           #endif
  70
  71           struct s { _Bool s: 1; _Bool t; } s;
  72
  73           char a[true == 1 ? 1 : -1];
  74           char b[false == 0 ? 1 : -1];
  75           char c[__bool_true_false_are_defined == 1 ? 1 : -1];
  76           char d[(bool) -0.5 == true ? 1 : -1];
  77           bool e = &s;
  78           char f[(_Bool) -0.0 == false ? 1 : -1];
  79           char g[true];
  80           char h[sizeof (_Bool)];
  81           char i[sizeof s.t];
  82         ],
  83         [ return !a + !b + !c + !d + !e + !f + !g + !h + !i; ],
  84         [ac_cv_header_stdbool_h=yes],
  85         [ac_cv_header_stdbool_h=no])])
  86    AC_CHECK_TYPES([_Bool])
  87    if test $ac_cv_header_stdbool_h = yes; then
  88      AC_DEFINE(HAVE_STDBOOL_H, 1, [Define to 1 if stdbool.h conforms to C99.])
  89    fi])