m4/stdint.m4

   1 # stdint.m4 serial 5
   2 dnl Copyright (C) 2001-2002, 2004-2005 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Bruno Haible.
   8 dnl Test whether <stdint.h> is supported or must be substituted.
   9
  10 AC_DEFUN([gl_STDINT_H],
  11 [dnl Check for <inttypes.h>.
  12 AC_REQUIRE([gt_HEADER_INTTYPES_H])
  13 dnl Check for <sys/inttypes.h>.
  14 AC_CHECK_HEADERS([sys/inttypes.h])
  15 dnl Check for <sys/bitypes.h> (used in Linux libc4 >= 4.6.7 and libc5).
  16 AC_CHECK_HEADERS([sys/bitypes.h])
  17
  18 AC_MSG_CHECKING([for stdint.h])
  19 AC_CACHE_VAL(gl_cv_header_stdint_h, [
  20   AC_TRY_COMPILE([#include <stdint.h>], [],
  21     gl_cv_header_stdint_h=yes, gl_cv_header_stdint_h=no)])
  22 AC_MSG_RESULT([$gl_cv_header_stdint_h])
  23 if test $gl_cv_header_stdint_h = yes; then
  24   AC_DEFINE(HAVE_STDINT_H, 1,
  25             [Define if you have a working <stdint.h> header file.])
  26   STDINT_H=''
  27 else
  28   STDINT_H='stdint.h'
  29
  30   dnl Is long == int64_t ?
  31   AC_CACHE_CHECK([whether 'long' is 64 bit wide], gl_cv_long_bitsize_64, [
  32     AC_TRY_COMPILE([
  33 #define POW63  ((((((long) 1 << 15) << 15) << 15) << 15) << 3)
  34 #define POW64  ((((((long) 1 << 15) << 15) << 15) << 15) << 4)
  35 typedef int array [2 * (POW63 != 0 && POW64 == 0) - 1];
  36 ], , gl_cv_long_bitsize_64=yes, gl_cv_long_bitsize_64=no)])
  37   if test $gl_cv_long_bitsize_64 = yes; then
  38     HAVE_LONG_64BIT=1
  39   else
  40     HAVE_LONG_64BIT=0
  41   fi
  42   AC_SUBST(HAVE_LONG_64BIT)
  43
  44   dnl Is long long == int64_t ?
  45   AC_CACHE_CHECK([whether 'long long' is 64 bit wide], gl_cv_longlong_bitsize_64, [
  46     AC_TRY_COMPILE([
  47 #define POW63  ((((((long long) 1 << 15) << 15) << 15) << 15) << 3)
  48 #define POW64  ((((((long long) 1 << 15) << 15) << 15) << 15) << 4)
  49 typedef int array [2 * (POW63 != 0 && POW64 == 0) - 1];
  50 ], , gl_cv_longlong_bitsize_64=yes, gl_cv_longlong_bitsize_64=no)])
  51   if test $gl_cv_longlong_bitsize_64 = yes; then
  52     HAVE_LONG_LONG_64BIT=1
  53   else
  54     HAVE_LONG_LONG_64BIT=0
  55   fi
  56   AC_SUBST(HAVE_LONG_LONG_64BIT)
  57
  58 fi
  59 AC_SUBST(STDINT_H)
  60 ])