m4/stdint.m4

   1 # stdint.m4 serial 15
   2 dnl Copyright (C) 2001-2002, 2004-2006 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Paul Eggert and Bruno Haible.
   8 dnl Test whether <stdint.h> is supported or must be substituted.
   9
  10 AC_DEFUN([gl_STDINT_H],
  11 [
  12   AC_PREREQ(2.59)dnl
  13
  14   dnl Check for long long int.
  15   AC_REQUIRE([AC_TYPE_LONG_LONG_INT])
  16   if test $ac_cv_type_long_long_int = yes; then
  17     HAVE_LONG_LONG_INT=1
  18   else
  19     HAVE_LONG_LONG_INT=0
  20   fi
  21   AC_SUBST([HAVE_LONG_LONG_INT])
  22
  23   dnl Check for <wchar.h>.
  24   AC_CHECK_HEADERS_ONCE([wchar.h])
  25   if test $ac_cv_header_wchar_h = yes; then
  26     HAVE_WCHAR_H=1
  27   else
  28     HAVE_WCHAR_H=0
  29   fi
  30   AC_SUBST([HAVE_WCHAR_H])
  31
  32   dnl Check for <inttypes.h>.
  33   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_inttypes_h.
  34   if test $ac_cv_header_inttypes_h = yes; then
  35     HAVE_INTTYPES_H=1
  36   else
  37     HAVE_INTTYPES_H=0
  38   fi
  39   AC_SUBST([HAVE_INTTYPES_H])
  40
  41   dnl Check for <sys/types.h>.
  42   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_sys_types_h.
  43   if test $ac_cv_header_sys_types_h = yes; then
  44     HAVE_SYS_TYPES_H=1
  45   else
  46     HAVE_SYS_TYPES_H=0
  47   fi
  48   AC_SUBST([HAVE_SYS_TYPES_H])
  49
  50   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_stdint_h.
  51   if test $ac_cv_header_stdint_h = yes; then
  52     gl_ABSOLUTE_HEADER([stdint.h])
  53     ABSOLUTE_STDINT_H=\"$gl_cv_absolute_stdint_h\"
  54     HAVE_STDINT_H=1
  55   else
  56     ABSOLUTE_STDINT_H=\"no/such/file/stdint.h\"
  57     HAVE_STDINT_H=0
  58   fi
  59   AC_SUBST([ABSOLUTE_STDINT_H])
  60   AC_SUBST([HAVE_STDINT_H])
  61
  62   dnl Now see whether we need a substitute <stdint.h>.  Use
  63   dnl ABSOLUTE_STDINT_H, not <stdint.h>, so that it also works during
  64   dnl a "config.status --recheck" if a stdint.h has been
  65   dnl created in the build directory.
  66   if test $ac_cv_header_stdint_h = yes; then
  67     AC_CACHE_CHECK([whether stdint.h conforms to C99],
  68       [gl_cv_header_working_stdint_h],
  69       [gl_cv_header_working_stdint_h=no
  70        AC_COMPILE_IFELSE([
  71          AC_LANG_PROGRAM([[
  72 #include <stddef.h>
  73 #define __STDC_LIMIT_MACROS 1 /* to make it work also in C++ mode */
  74 #include ABSOLUTE_STDINT_H
  75 #ifdef INT8_MAX
  76 int8_t a1 = INT8_MAX;
  77 #endif
  78 #ifdef INT16_MAX
  79 int16_t a2 = INT16_MAX;
  80 #endif
  81 #ifdef INT32_MAX
  82 int32_t a3 = INT32_MAX;
  83 #endif
  84 #ifdef INT64_MAX
  85 int64_t a4 = INT64_MAX;
  86 #endif
  87 #ifdef UINT8_MAX
  88 uint8_t b1 = UINT8_MAX;
  89 #else
  90 typedef int b1[(unsigned char) -1 != 255 ? 1 : -1];
  91 #endif
  92 #ifdef UINT16_MAX
  93 uint16_t b2 = UINT16_MAX;
  94 #endif
  95 #ifdef UINT32_MAX
  96 uint32_t b3 = UINT32_MAX;
  97 #endif
  98 #ifdef UINT64_MAX
  99 uint64_t b4 = UINT64_MAX;
 100 #endif
 101 int_least8_t c1 = INT8_C (0x7f);
 102 int_least16_t c2 = INT16_C (0x7fff);
 103 int_least32_t c3 = INT32_C (0x7fffffff);
 104 int_least64_t c4 = INT64_C (0x7fffffffffffffff);
 105 uint_least8_t d1 = UINT8_C (0xff);
 106 uint_least16_t d2 = UINT16_C (0xffff);
 107 uint_least32_t d3 = UINT32_C (0xffffffff);
 108 uint_least64_t d4 = UINT64_C (0xffffffffffffffff);
 109 int_fast8_t e1 = INT_FAST8_MAX;
 110 int_fast16_t e2 = INT_FAST16_MAX;
 111 int_fast32_t e3 = INT_FAST32_MAX;
 112 int_fast64_t e4 = INT_FAST64_MAX;
 113 uint_fast8_t f1 = UINT_FAST8_MAX;
 114 uint_fast16_t f2 = UINT_FAST16_MAX;
 115 uint_fast32_t f3 = UINT_FAST32_MAX;
 116 uint_fast64_t f4 = UINT_FAST64_MAX;
 117 #ifdef INTPTR_MAX
 118 intptr_t g = INTPTR_MAX;
 119 #endif
 120 #ifdef UINTPTR_MAX
 121 uintptr_t h = UINTPTR_MAX;
 122 #endif
 123 intmax_t i = INTMAX_MAX;
 124 uintmax_t j = UINTMAX_MAX;
 125 struct s {
 126   int check_PTRDIFF: PTRDIFF_MIN < 0 && 0 < PTRDIFF_MAX ? 1 : -1;
 127   int check_SIG_ATOMIC: SIG_ATOMIC_MIN <= 0 && 0 < SIG_ATOMIC_MAX ? 1 : -1;
 128   int check_SIZE: 0 < SIZE_MAX ? 1 : -1;
 129   int check_WCHAR: WCHAR_MIN <= 0 && 0 < WCHAR_MAX ? 1 : -1;
 130   int check_WINT: WINT_MIN <= 0 && 0 < WINT_MAX ? 1 : -1;
 131
 132   /* Detect bugs in glibc 2.4 and Solaris 10 stdint.h, among others.  */
 133   int check_UINT8_C:
 134         (-1 < UINT8_C (0)) == (-1 < (uint_least8_t) 0) ? 1 : -1;
 135   int check_UINT16_C:
 136         (-1 < UINT16_C (0)) == (-1 < (uint_least16_t) 0) ? 1 : -1;
 137
 138   /* Detect bugs in OpenBSD 3.9 stdint.h.  */
 139 #ifdef UINT8_MAX
 140   int check_uint8: (uint8_t) -1 == UINT8_MAX ? 1 : -1;
 141 #endif
 142 #ifdef UINT16_MAX
 143   int check_uint16: (uint16_t) -1 == UINT16_MAX ? 1 : -1;
 144 #endif
 145 #ifdef UINT32_MAX
 146   int check_uint32: (uint32_t) -1 == UINT32_MAX ? 1 : -1;
 147 #endif
 148 #ifdef UINT64_MAX
 149   int check_uint64: (uint64_t) -1 == UINT64_MAX ? 1 : -1;
 150 #endif
 151   int check_uint_least8: (uint_least8_t) -1 == UINT_LEAST8_MAX ? 1 : -1;
 152   int check_uint_least16: (uint_least16_t) -1 == UINT_LEAST16_MAX ? 1 : -1;
 153   int check_uint_least32: (uint_least32_t) -1 == UINT_LEAST32_MAX ? 1 : -1;
 154   int check_uint_least64: (uint_least64_t) -1 == UINT_LEAST64_MAX ? 1 : -1;
 155   int check_uint_fast8: (uint_fast8_t) -1 == UINT_FAST8_MAX ? 1 : -1;
 156   int check_uint_fast16: (uint_fast16_t) -1 == UINT_FAST16_MAX ? 1 : -1;
 157   int check_uint_fast32: (uint_fast32_t) -1 == UINT_FAST32_MAX ? 1 : -1;
 158   int check_uint_fast64: (uint_fast64_t) -1 == UINT_FAST64_MAX ? 1 : -1;
 159   int check_uintptr: (uintptr_t) -1 == UINTPTR_MAX ? 1 : -1;
 160   int check_uintmax: (uintmax_t) -1 == UINTMAX_MAX ? 1 : -1;
 161   int check_size: (size_t) -1 == SIZE_MAX ? 1 : -1;
 162 };
 163          ]])],
 164          [gl_cv_header_working_stdint_h=yes])])
 165   fi
 166   if test "$gl_cv_header_working_stdint_h" != yes; then
 167
 168     dnl Check for <sys/inttypes.h>, and for
 169     dnl <sys/bitypes.h> (used in Linux libc4 >= 4.6.7 and libc5).
 170     AC_CHECK_HEADERS([sys/inttypes.h sys/bitypes.h])
 171     if test $ac_cv_header_sys_inttypes_h = yes; then
 172       HAVE_SYS_INTTYPES_H=1
 173     else
 174       HAVE_SYS_INTTYPES_H=0
 175     fi
 176     AC_SUBST([HAVE_SYS_INTTYPES_H])
 177     if test $ac_cv_header_sys_bitypes_h = yes; then
 178       HAVE_SYS_BITYPES_H=1
 179     else
 180       HAVE_SYS_BITYPES_H=0
 181     fi
 182     AC_SUBST([HAVE_SYS_BITYPES_H])
 183
 184     gl_STDINT_TYPE_PROPERTIES
 185     STDINT_H=stdint.h
 186   fi
 187   AC_SUBST(STDINT_H)
 188 ])
 189
 190 dnl gl_STDINT_BITSIZEOF(TYPES, INCLUDES)
 191 dnl Determine the size of each of the given types in bits.
 192 AC_DEFUN([gl_STDINT_BITSIZEOF],
 193 [
 194   dnl Use a shell loop, to avoid bloating configure, and
 195   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 196   dnl   config.h.in,
 197   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 198   AC_FOREACH([gltype], [$1],
 199     [AH_TEMPLATE([BITSIZEOF_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 200        [Define to the number of bits in type ']gltype['.])])
 201   for gltype in $1 ; do
 202     AC_CACHE_CHECK([for bit size of $gltype], [gl_cv_bitsizeof_${gltype}],
 203       [_AC_COMPUTE_INT([sizeof ($gltype) * CHAR_BIT], result,
 204          [$2
 205 #include <limits.h>], [result=unknown])
 206        eval gl_cv_bitsizeof_${gltype}=\$result
 207       ])
 208     eval result=\$gl_cv_bitsizeof_${gltype}
 209     if test $result = unknown; then
 210       dnl Use a nonempty default, because some compilers, such as IRIX 5 cc,
 211       dnl do a syntax check even on unused #if conditions and give an error
 212       dnl on valid C code like this:
 213       dnl   #if 0
 214       dnl   # if  > 32
 215       dnl   # endif
 216       dnl   #endif
 217       result=0
 218     fi
 219     GLTYPE=`echo "$gltype" | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 220     AC_DEFINE_UNQUOTED([BITSIZEOF_${GLTYPE}], [$result])
 221     eval BITSIZEOF_${GLTYPE}=\$result
 222   done
 223   AC_FOREACH([gltype], [$1],
 224     [AC_SUBST([BITSIZEOF_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 225 ])
 226
 227 dnl gl_CHECK_TYPES_SIGNED(TYPES, INCLUDES)
 228 dnl Determine the signedness of each of the given types.
 229 dnl Define HAVE_SIGNED_TYPE if type is signed.
 230 AC_DEFUN([gl_CHECK_TYPES_SIGNED],
 231 [
 232   dnl Use a shell loop, to avoid bloating configure, and
 233   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 234   dnl   config.h.in,
 235   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 236   AC_FOREACH([gltype], [$1],
 237     [AH_TEMPLATE([HAVE_SIGNED_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 238        [Define to 1 if ']gltype[' is a signed integer type.])])
 239   for gltype in $1 ; do
 240     AC_CACHE_CHECK([whether $gltype is signed], [gl_cv_type_${gltype}_signed],
 241       [AC_COMPILE_IFELSE(
 242          [AC_LANG_PROGRAM([$2[
 243             int verify[2 * (($gltype) -1 < ($gltype) 0) - 1];]])],
 244          result=yes, result=no)
 245        eval gl_cv_type_${gltype}_signed=\$result
 246       ])
 247     eval result=\$gl_cv_type_${gltype}_signed
 248     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 249     if test "$result" = yes; then
 250       AC_DEFINE_UNQUOTED([HAVE_SIGNED_${GLTYPE}], 1)
 251       eval HAVE_SIGNED_${GLTYPE}=1
 252     else
 253       eval HAVE_SIGNED_${GLTYPE}=0
 254     fi
 255   done
 256   AC_FOREACH([gltype], [$1],
 257     [AC_SUBST([HAVE_SIGNED_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 258 ])
 259
 260 dnl gl_INTEGER_TYPE_SUFFIX(TYPES, INCLUDES)
 261 dnl Determine the suffix to use for integer constants of the given types.
 262 dnl Define t_SUFFIX for each such type.
 263 AC_DEFUN([gl_INTEGER_TYPE_SUFFIX],
 264 [
 265   dnl Use a shell loop, to avoid bloating configure, and
 266   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 267   dnl   config.h.in,
 268   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 269   AC_FOREACH([gltype], [$1],
 270     [AH_TEMPLATE(translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX],
 271        [Define to l, ll, u, ul, ull, etc., as suitable for
 272         constants of type ']gltype['.])])
 273   for gltype in $1 ; do
 274     AC_CACHE_CHECK([for $gltype integer literal suffix],
 275       [gl_cv_type_${gltype}_suffix],
 276       [eval gl_cv_type_${gltype}_suffix=no
 277        eval result=\$gl_cv_type_${gltype}_signed
 278        if test "$result" = yes; then
 279          glsufu=
 280        else
 281          glsufu=u
 282        fi
 283        for glsuf in "$glsufu" ${glsufu}l ${glsufu}ll ${glsufu}i64; do
 284          case $glsuf in
 285            '')  gltype1='int';;
 286            l)   gltype1='long int';;
 287            ll)  gltype1='long long int';;
 288            i64) gltype1='__int64';;
 289            u)   gltype1='unsigned int';;
 290            ul)  gltype1='unsigned long int';;
 291            ull) gltype1='unsigned long long int';;
 292            ui64)gltype1='unsigned __int64';;
 293          esac
 294          AC_COMPILE_IFELSE(
 295            [AC_LANG_PROGRAM([$2
 296               extern $gltype foo;
 297               extern $gltype1 foo;])],
 298            [eval gl_cv_type_${gltype}_suffix=\$glsuf])
 299          eval test \"\$gl_cv_type_${gltype}_suffix\" != no && break
 300        done])
 301     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 302     eval result=\$gl_cv_type_${gltype}_suffix
 303     test "$result" = no && result=
 304     eval ${GLTYPE}_SUFFIX=\$result
 305     AC_DEFINE_UNQUOTED([${GLTYPE}_SUFFIX], $result)
 306   done
 307   AC_FOREACH([gltype], [$1],
 308     [AC_SUBST(translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX])])
 309 ])
 310
 311 dnl gl_STDINT_INCLUDES
 312 AC_DEFUN([gl_STDINT_INCLUDES],
 313 [[
 314   #include <stddef.h>
 315   #include <signal.h>
 316   #if HAVE_WCHAR_H
 317     /* BSD/OS 4.1 has a bug: <stdio.h> and <time.h> must be included before
 318        <wchar.h>.  */
 319   # include <stdio.h>
 320   # include <time.h>
 321   # include <wchar.h>
 322   #endif
 323 ]])
 324
 325 dnl gl_STDINT_TYPE_PROPERTIES
 326 dnl Compute HAVE_SIGNED_t, BITSIZEOF_t and t_SUFFIX, for all the types t
 327 dnl of interest to stdint_.h.
 328 AC_DEFUN([gl_STDINT_TYPE_PROPERTIES],
 329 [
 330   gl_STDINT_BITSIZEOF([ptrdiff_t sig_atomic_t size_t wchar_t wint_t],
 331     [gl_STDINT_INCLUDES])
 332   gl_CHECK_TYPES_SIGNED([sig_atomic_t wchar_t wint_t],
 333     [gl_STDINT_INCLUDES])
 334   gl_cv_type_ptrdiff_t_signed=yes
 335   gl_cv_type_size_t_signed=no
 336   gl_INTEGER_TYPE_SUFFIX([ptrdiff_t sig_atomic_t size_t wchar_t wint_t],
 337     [gl_STDINT_INCLUDES])
 338 ])